how to grab and modify enities within a block

[clintonc]

how do I search thru the parts of a block.

[RobertB]

(entnext) or (vla-Item)

[peter]

Here is a simple example of iterating through a block definition and printing the object names of the objects in the block.

Peter Jamtgaard



(defun C:blky (/ colBlock strBlockName)
(while (not (setq lstSelection (entsel "\nSelect Block :")))
(princ "\nSelect Again: ")
)
(setq strBlockName (cdr (assoc 2 (entget (car lstSelection))))
colBlock (vla-item
(vla-get-blocks
(vla-get-activedocument
(vlax-get-acad-object)
)
)
strBlockName
)
)
(vlax-for objBlock colBlock
(princ "\n")
(princ (vla-get-objectname objBlock))
(princ "\n")
)
)

[stig.madsen]

And in good ol' AutoLISP:


(defun blockWalk (bname / a ent)
(and (setq a 0 ent (cdr (assoc -2 (tblsearch "BLOCK" bname))))
(while ent
(princ (cdr (assoc 0 (entget ent))))
(terpri)
(setq ent (entnext ent) a (1+ a))
)
(princ (strcat (itoa a) " objects in " bname))
)
(princ)
)

The engine is ENTNEXT, as Robert pointed out. It requires some more code if it's not supposed to return subents from subents, though. Peter's example only returns subents within the block.