Coding help.

Hello everyone,

I need some help to get this code to work.

I am looking for it to allow me to select a layer and then make it nonplot.

After I run it, I get this in the command line "Pick the layer to make nonprint: ; error: too many arguments" and the layer that I have pick has not be set to nonplot.

Code:

---

(DEFUN C:NP ()(SETVAR "CMDECHO" 0)
        (setq ent_name (car (entsel "\nPick the layer to make nonprint: ")))
    (setq ent_list (entget ent_name))   
    (setq l_name (cdr (assoc 8 ent_list))) 
    (setvar "-LAYER" "PLOT" "N" l_name) 
        (SETVAR "CMDECHO" 1)(princ))

---

Thanks.

Just replace this part ...

Code:

---

(command "-LAYER" "PLOT" "N" l_name "")

---

and it is better to localize variables like this ...

Code:

---

(DEFUN C:NP (/ ent_name ent_list l_name)

---

Thank for the help and the localize variables reminder.

I did have the "" in the code before I posted it and it still didn't work.

KC

... Building on Tharwat's post:

Code:

---

(defun c:FOO ( / eName layerName oldCmdecho)
  (if (and (setq eName (car (entsel "\nSelect layer to make \"No Plot\": ")))
          (setq layerName (cdr (assoc 8 (entget eName)))))
    (progn
      (setq oldCmdecho (getvar 'cmdecho))
      (setvar 'cmdecho 0)
      (command "._-layer" "plot" "n" layerName "")
      (setvar 'cmdecho oldCmdecho)
      (princ layerName))
    (prompt "\n** Nothing selected ** "))
  (princ))

---

RenderMan,

Thank you, it works great.

KC

Quote:

---

Originally Posted by cadd4la

RenderMan,

Thank you, it works great.

---

You're welcome. :beer: