Marking Edited TEXT/MTEXT Entities

[relysoft]

Our Drafting Supervisor has asked me to provide a method to visually identify all text and multiline text that is edited by changing the font and color. I have existing LISP code to handle this for TEXT entities, but am struggling to come up with a way to do this for MTEXT entities. I would like to continue to use the supplied "internal" editor for the actual MTEXT editing, then somehow automatically choose the just modified text to change the font and color.

Any suggestions?

Thanks,
Bob

[kennet.sjoberg]

Hi Bob, why not just include MTEXT in Your lisp ?

It is much more easy to help if You show Your code.
Otherwise the dxf code for both (0 . TEXT) and (0 . MTEXT) is
(62 . xx ) for main color and ( 7 . xx ) for main font.
If You change color and font partly inside the MTEXT You will have problem.

: ) Happy Computing !

kennet

[stig.madsen]

Bob,
Just out of curiosity, wouldn't it be easier - and more in line with a standard convention - to mark edited text with a box? Possibly on a layer of its own. As Kennet is hinting at, visually changing MTEXT that may have been formatted is not a simple task. At least not if the changes later need to be reverted.

[peter]

This is a good time to use a reactor routine. In this case two reactors are required. The first is an acdb reactor and the second is a command ended reactor. The acdb reactor catches the modification event and makes a list of entities changed in the command and the command ended reactor changes the list of entities to be color 1 for example. You may find the actual creation of the entity will cause the entities to change but you can modifiy this routine to allow for not changing them upon creation.

Peter Jamtgaard

(defun evtObjectModified (objReactor lstObjectModified / objModified)
 (setq objModified (vlax-ename->vla-object (cadr lstObjectModified)))
 (if (and (wcmatch (vla-get-objectname objModified) "AcDbMText,AcDbText")
		  (not blnRerun))
  (setq lstObjectsModified (cons objModified lstObjectsModified)))
 (princ)
)
(defun evtCommandEnded (evtCall lstCallback / objModified)
 (if lstObjectsModified
  (progn   
   (setq blnRerun 'T)
   (foreach objModified lstObjectsModified
	(vla-put-color objModified 1))   
   (setq blnRerun		   nil
		 lstObjectsModified nil)))
 (princ)
)
(setq rxnObjectModified (vlr-acdb-reactor nil   '((:vlr-objectModified . evtObjectModified )))
	  rxnCommandEnded   (vlr-editor-reactor nil '((:vlr-commandended   . evtCommandEnded))))

[relysoft]

Peter,

You have identified what it is that I am trying to accomplish. I understand event driven programming having spent several years developing software using the Windows SDK. But, my knowledge of ACAD reactors is not much more than knowing they exist.

I'll take a shot at using your sample code to do what I need to do. It will be next week before I can try it. Any suggestions on how to learn more about reactors?

Thanks to everyone that has responded.

Happy Thanksgiving,
Bob

[Glenn Pope]

A good place to learn about reactors is Afralisp. Check out the lisp Tutorials, under Visual Lisp Tutorials.

[relysoft]

Peter ...

I finally got some time to work on this. I modifed your sample code to select TEXT and MTEXT entities for modification. Here is my expanded version of you r orginal exmple:

(defun evtObjectModified (objReactor lstObjectModified / objModified)
 (setq objModified (vlax-ename->vla-object (cadr lstObjectModified)))
 (if (and (wcmatch (vla-get-objectname objModified) "AcDbMText,AcDbText")
		  (not blnRerun))
  (setq lstObjectsModified (cons objModified lstObjectsModified)))
 (princ)
)
(defun evtCommandEnded (evtCall lstCallback / objModified)
 (if (and lstobjectsmodified (or (= (car lstCallback) "DDEDIT")
                                 (= (car lstCallback) "MTEDIT")))
  (progn   
   (setq blnRerun 'T)
   (foreach objModified lstObjectsModified
	(vla-put-color objModified 4)
        (vla-put-PlotStyleName objModified "HEAVY")
        (vla-put-StyleName objModified "20DEG")
   )  
  )
 )
 (setq blnRerun nil)
 (setq lstObjectsModified nil)
 (princ)
)
(setq rxnObjectModified (vlr-acdb-reactor nil   '((:vlr-objectModified . evtObjectModified )))
	  rxnCommandEnded   (vlr-editor-reactor nil '((:vlr-commandended   . evtCommandEnded))))

This works just fine. However, when an "UNDO" command is exited to undo the modifications I get a bunch of copies of the following message:


"Automation Error. Description was not provided."

There appears to be possibly one such message for each entity in the drawing. (Not sure of this, but the number increases with the number of entities.)

The UNDO works just fine and a REDO works as well. Can you tell me what this message is trying to tell me and ho w to prevent it or suppress it.

Thanks,
Bob