Add description to an existing block

[avatar]

Hai friends,
Is this possible to add /edit description to an existing block using Autocad command or lisp.

Thanks,
hareesh.mb

[fixo]

Hai friends,
Is this possible to add /edit description to an existing block using Autocad command or lisp.

Thanks,
hareesh.mb

Try this code snippet

  (vl-load-com)
(if
  (setq blk_ent (entsel "\nSelect block: "))
   (progn
     (setq blk_obj (vlax-ename->vla-object (car blk_ent))
    blk_def (vla-item
       (vla-get-blocks
         (vla-get-activedocument
    (vlax-get-acad-object)))
       (vla-get-effectivename blk_obj)
       )
    )
     (vl-catch-all-apply
       (function (lambda ()
     (vla-put-comments
       blk_def
       "Your description should set here"
       )
     )
   )
       )
     )
   )

~'J'~

[alanjt]

Here's one I scratched out for someone a while back.

;;; Edit Block Description
;;; Required Subroutines: AT:GetString
;;; Alan J. Thompson, 10.16.09
(defun c:EBD (/ #Obj #Name #Block #Desc)
  (and
    (setq #Obj (car (entsel "\nSelect block to add description: ")))
    (eq "INSERT" (cdr (assoc 0 (entget #Obj))))
    (if (vlax-property-available-p (setq #OBj (vlax-ename->vla-object #Obj)) 'EffectiveName)
      (setq #Name (vla-get-EffectiveName #Obj))
      (setq #Name (vla-get-Name #OBj))
    ) ;_ if
    (setq #Block (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) #Name))
    (setq #Desc (AT:GetString "Change block description:" (vla-get-comments #Block)))
    (vl-catch-all-apply 'vla-put-comments (list #Block #Desc))
  ) ;_ and
  (princ)
) ;_ defun

You'll need this subroutine:

;;; Getstring Dialog Box
;;; #Title - Title of dialog box
;;; #Default - Default string within edit box
;;; Alan J. Thompson, 08.25.09
(defun AT:GetString
       (#Title #Default / #FileName #FileOpen #DclID #NewString)
  (setq #FileName (vl-filename-mktemp "" "" ".dcl")
        #FileOpen (open #FileName "W")
  ) ;_ setq
  (foreach x '("TempEditBox : dialog {" "key = \"Title\";"
               "label = \"\";" "initial_focus = \"Edit\";" "spacer;"
               ": row {" ": column {" "alignment = centered;"
               "fixed_width = true;" ": text {" "label = \"\";" "}" "}"
               ": edit_box {" "key = \"Edit\";" "allow_accept = true;"
               "edit_width = 40;" "fixed_width = true;" "}" "}"
               "spacer;" ": row {" "fixed_width = true;"
               "alignment = centered;" ": ok_button {" "width = 11;" "}"
               ": cancel_button {" "width = 11;" "}" "}" "}//"
              )
    (write-line x #FileOpen)
  ) ;_ foreach
  (close #FileOpen)
  (setq #DclID (load_dialog #FileName))
  (new_dialog "TempEditBox" #DclID)
  (set_tile "Title" #Title)
  (set_tile "Edit" #Default)
  (action_tile
    "accept"
    "(setq #NewString (get_tile \"Edit\"))(done_dialog)"
  ) ;_ action_tile
  (action_tile "cancel" "(done_dialog)")
  (start_dialog)
  (unload_dialog #DclID)
  (vl-file-delete #FileName)
  #NewString
) ;_ defun

[avatar]

Thank you fixo and alanjt

I am just beginner in lisp so can you arrange this correctly for running.

Thanks,
hareeshmb

[irneb]

If you want fixo's routine, place it in a LSP file (use any text editor, e.g. Notepad) and surround with a defun (give it a name you want as the command and prefix with c: ), e.g:

(defun C:CmdName ()
  ;; Fixo's code here
)

If alan jt's code, save all as is into a LSP file.

In both scenarios the LSP file needs to be loaded. There are several ways of doing this, see here: http://forums.augi.com/showthread.ph...t=loading+lisp

[avatar]

Thank you irneb
Alanjt's code is ok but fixo's code show some error when loading, anyway thanks once again alenjt, fixo, irneb for your great support.

hareesh.mb

[alanjt]

Thank you irneb
Alanjt's code is ok but fixo's code show some error when loading, anyway thanks once again alenjt, fixo, irneb for your great support.

hareesh.mb

As long as you find something that works. That's the important part.