Element counting in a list

[RabbitM]

I have a list (setq list ("A" "A" "B" "B" "B" "C" etc..))
I need to have a way to return a count of the elements, maybe a dotted pair ("A" . 2) ("B" . 3) ("C" . 1). I have figured out how to make the first dotted pair i.e. ("A" . 1), but I dunno how to change the 1 to a 2 or any other succesive number.

There might be another way to get these counts, but I can't seem to get anywhere in getting it.

Thanks, Rabbit

[T.Willey]

Here is a freebie.

(defun ListCount ( lst / tlst rlst )
    
    (foreach i lst
        (setq rlst
            (if (setq tlst (assoc i rlst))
                (subst (cons i (1+ (cdr tlst))) tlst rlst)
                (cons (cons i 1) rlst)
            )
        )
    )
)

Command: (listcount '("A" "A" "B" "B" "B" "C"))
(("C" . 1) ("B" . 3) ("A" . 2))

Welcome to AUGI!

[RabbitM]

Welp, I had gotten to that point before, although yours is waaaaay more graceful. My problem is if I want to increase the count by 1 "A", ("A" . 2) to ("A" . 3) . How would I go about just changing the number? SUBST?

Or, would I have to get all the info from the returned list and then add 1 to the number I need and then use your code to recreate the list.

Thanks again, Rabbit

[T.Willey]

The code I posted will do what you want. Try to understand what is happening.

[Kerry Brown]

Tims code does exactly what you asked for.

If you want to add to the list manually, try something like this perhaps ...

(defun kdub-IncrementConsValue (ConsList Key Value / v)
  (if (setq v (assoc Key ConsList))
    (subst (cons Key (+ Value (cdr v))) v ConsList)
    (cons (cons Key Value) ConsList)  
  ) 
)

(setq Counted_List '(("C" . 1) ("B" . 3) ("A" . 2)))

(setq New_List (kdub-IncrementConsValue Counted_List "A" 5))

(kdub-IncrementConsValue New_List "NEW" 55)

returns


(("C" . 1) ("B" . 3) ("A" . 2))
(("C" . 1) ("B" . 3) ("A" . 7))
(("NEW" . 55) ("C" . 1) ("B" . 3) ("A" . 7))

[BlackBox]

Hope you don't mind... Here's a minor adaptation on Buzzard's code:

(defun ListCount  (lst / tlst rlst)
  (vl-load-com)
  (foreach i  lst
    (setq rlst
           (if (setq tlst (assoc i rlst))
             (subst (cons i (1+ (cdr tlst))) tlst rlst)
             (cons (cons i 1) rlst)
             )
          )
    )
  (vl-sort
    rlst
    '(lambda (x y)
       (< (car x) (car y))))  
)

Results:

_$ (setq lst (list  "A" "A" "B" "B" "B" "C"))
("A" "A" "B" "B" "B" "C")
_$ (ListCount lst)
(("A" . 2) ("B" . 3) ("C" . 1))
_$

[RabbitM]

Your right, Tim's code does so it. But for the life of me, I couldn't get it to work as you have shown. I think I'm at the point to where I've got to toatly clear my mind of everything I've been trying and focus on the solutions you guys gave me so that I can understand how it all works.

I appreciate all the help everyone has given me.

Rabbit

Tims code does exactly what you asked for.

If you want to add to the list manually, try something like this perhaps ...

(defun kdub-IncrementConsValue (ConsList Key Value / v)
  (if (setq v (assoc Key ConsList))
    (subst (cons Key (+ Value (cdr v))) v ConsList)
    (cons (cons Key Value) ConsList)  
  ) 
)

(setq Counted_List '(("C" . 1) ("B" . 3) ("A" . 2)))

(setq New_List (kdub-IncrementConsValue Counted_List "A" 5))

(kdub-IncrementConsValue New_List "NEW" 55)

returns


(("C" . 1) ("B" . 3) ("A" . 2))
(("C" . 1) ("B" . 3) ("A" . 7))
(("NEW" . 55) ("C" . 1) ("B" . 3) ("A" . 7))

[rmoore]

I think what Rabbitm_69 is looking for is supplying a list like:

("A" "A" "B" "B" "B" "C")

And receiving a list like:

( ("A" . 1) ("A" . 2) ("B" . 1) ("B" . 2) ("B" . 3) ("C" .1))

[BlackBox]

I think what Rabbitm_69 is looking for is supplying a list like:

("A" "A" "B" "B" "B" "C")

And receiving a list like:

( ("A" . 1) ("A" . 2) ("B" . 1) ("B" . 2) ("B" . 3) ("C" .1))

... What purpose does that result serve?

[dgorsman]

Ordinal count of each unque item the list i.e. third "A", first "C", and so on?