Text Override in Dimension

[Tharwat]

What about something like this ...
Dialog box idea by Mr gile ..

(defun c:Test (/ tmp file dcl_id name ss i vl)
  (vl-load-com)
  ;; create and open a temporay file
  ;; by gile  Modified by Tharwat to suit the needs of this routine
  (setq tmp  (vl-filename-mktemp "tmp.dcl")
        file (open tmp "w")
  )
  ;; write the DCL file
  (write-line
    "testDialog:dialog{
      label = \"Dimensiontext Test\";
      initial_focus = \"name\";
      :text{
        label = \"Enter Override Text:\";
      }
      :edit_box{
        key = \"name\";
        width = 32;
        allow_accept = true;
      }
      ok_cancel;
    }"
    file
  )
  ;; close the file
  (close file)
  ;; load and show the dialog
  (setq dcl_id (load_dialog tmp))
  (if (not (new_dialog "testDialog" dcl_id))
    (exit)
  )
  (action_tile
    "accept"
    "(setq name (get_tile \"name\")) (setq case (get_tile \"case\"))(done_dialog)"
  )
  (start_dialog)
  (unload_dialog dcl_id)
  ;; delete the file
  (vl-file-delete tmp)
  ;; show the result
  (if (setq ss (ssget "_:L" '((0 . "*DIMENSION"))))
    (repeat
      (setq i (sslength ss))
       (setq vl (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
       (vla-put-textoverride vl name)
    )
    (princ "\n No Dimensions found !! ...")
  )
  (princ)
)

Tharwat

[Lee Mac]

Try pressing 'Cancel' on the dialog

[Tharwat]

Try pressing 'Cancel' on the dialog

Waww That would throw an active X server error , and even if I used your error sub-routine it won't interfere to stop that disaster .

I tried to to include the dialog within the *and* function , but it's been giving me an error also .

What's your suggestion ?

Thanks

[Lee Mac]

I tried to to include the dialog within the *and* function , but it's been giving me an error also .

What's your suggestion ?

In my opinion, you need to have an understanding of the function of every part of the code before you can begin to modify it. Guessing without a proper understanding of what the code is doing is certain to tie you in knots.

I will post an example in a bit.

[Lee Mac]

A quick example:

(defun c:test ( / *error* e file i id over ss tmp )

  (defun *error* ( msg )
    (if (< 0 id) (setq id (unload_dialog id)))
    (if (and tmp (findfile tmp)) (vl-file-delete tmp))
    (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
        (princ (strcat "\n** Error: " msg " **")))
    (princ)
  )
  
  (cond
    ( (not (setq ss (ssget "_:L" '((0 . "*DIMENSION")))))
      (princ "\n*Cancel*")
    )
    (
      (not
        (and (setq file (open (setq tmp (vl-filename-mktemp nil nil ".dcl")) "w"))
          (progn
            (foreach x
             '(
                "test : dialog { label = \"Dimension Override\"; spacer;"
                "  initial_focus = \"text\";"
                "  :text { label = \"Enter Override Text:\"; }"
                "  :edit_box { key = \"text\"; width = 32; allow_accept = true; }"
                "  spacer; ok_cancel;"
                "}"
              )
              (write-line x file)
            )
            (setq file (close file)) (< 0 (setq id (load_dialog tmp)))
          )
          (new_dialog "test" id)
        )
      )
      (princ "\n--> Error Loading Dialog.")
    )
    (t
      (setq over "")
      (action_tile "text" "(setq over $value)")
      (if (= 1 (start_dialog))
        (repeat (setq i (sslength ss))
          (setq e (entget (ssname ss (setq i (1- i)))))
          (entmod (subst (cons 1 over) (assoc 1 e) e))
        )
        (princ "\n*Cancel*")
      )
    )
  )
  (if (< 0 id) (setq id (unload_dialog id)))
  (if (and tmp (findfile tmp)) (vl-file-delete tmp))
  (princ)
)

[Tharwat]

A very nice work in sequence Lee , thanks for your notes .
What is the difference between these codes in your opinion ? Because I see you always prefer using *and* function which I sometimes have doubts about it .

you used the following in the error trap sub-routine.

    (if (and tmp (findfile tmp)) (vl-file-delete tmp))

Is it wrong to make it this way .

 (if tmp 
(progn
(findfile tmp)(vl-file-delete tmp)))

Appreciated lot .

Tharwat

[Lee Mac]

I think you need to spend some time reading the help documentation on the 'AND' function to have a better understanding of its functionality.

In my code:

(if ; If the following test expression returns a non-nil value
  (and 
    tmp            ; 'tmp' variable has a non-nil value 
    (findfile tmp) ; The file with filename tmp can be found
  )
  (vl-file-delete tmp) ; Then delete the file
)

In your modification, you now have a redundant expression, and the extra check for the existence of the file is no longer present:

(if tmp ; If 'tmp' variable has a non-nil value 
  (progn
    (findfile tmp) ; This is redundant since its result isn't used in any way
    (vl-file-delete tmp) ; delete the file
  )
)

[Tom Beauford]

'and' tests every item in order if it recieves a nil responce it stops and returns nil, otherwise returns T.

'or' tests every item in order if it recieves a T responce it stops and returns T, otherwise returns nil. As an example I use it as an autoloader for lisp files, if the function name exists it stops and doesn't reload the routine: (or C:ContourAnnotate (load "ContourAnnotate.lsp"))

Two of my favorite functions like 'progn' on steroids.

[marko_ribar]

Fantastic observation, Tom...

Notice that if you use (or) in combination with (if), syntax should be just opposite :
(if (or c:test) () (load "test.lsp")), for when (or) check if c:test is T it stops returns T and continues to first condition witch is here () nothing, otherwise if c:test is nil it stops returns nil and because of that nil it processes else condition witch is here (load "test.lsp")

(if (and c:test) () (load "test.lsp")) does the same as (or) variariant
but it would be the different if you used :
(and c:test (load "test.lsp")), then after first T (and) function wouldn't stop, it would continue and error would occur - twice loading, and if first is nil it stops returns nil and nothing would be continued with processing...

but (not) is just opposite than (or) and (and) in combination with (if)... It checks single item and if it is T it stops and returns nil, otherwise if nil it stops and returns T...

(if (not c:test) (load "test.lsp")) would work - here is else condition sufficient
but
(not c:test (load "test.lsp")) also wouldn't work - this would lead to error of too many arguments

M.R.

[BlackBox]

Rubik's Cube for LISP

Legend: IF, AND (white), OR, REAL, STRING, INTEGER (yellow)



LoL