change block elevation to match attribute value

[SurveyorHead]

Hi everyone,
I am new to programming Lisp, so I was wandering if someone could help me with a routine that
changes block elevation to match an attribute value of its own.

to be more specific:
I have a block named "SH" representing a point, with attributes A1 (for point number) and A2 (for elevation)
Its original elevation is 0, and the desirable elevation is the value saved in attribute A2.

thank you in advance!
vassilis

[Stadtler]

plenty of Lisp examples to look at - here is a link to one which you may find interesting

http://forums.augi.com/showthread.ph...bute+elevation

[SurveyorHead]

thanks a lot
my apologies though, I didn't notice there were already the same threads
I used this one, and helped me fine
http://forums.augi.com/showthread.php?t=4362
thanks again!

[peter]

(defun C:SH1 (/
             entSelection
             intCount
             objAttribute
             objSelection
             ssSelections
             strTextstring
            )
 (if (setq ssSelections (ssget (list (cons 2 "SH"))))
  (repeat (setq intCount (sslength ssSelections))
   (setq intCount     (1- intCount)
         entSelection (ssname ssSelections intCount)
         objSelection (vlax-ename->vla-object entSelection)
   )
   (foreach objAttribute (vlax-invoke objSelection "getattributes")
    (if (= (vla-get-tagstring objAttribute) "A2")
     (if (/= (setq strTextstring (vla-get-textstring objAttribute)) "")
      (progn
       (setq lstInsertion (vlax-get objSelection  "insertionpoint")
             lstInsertion (list (car lstInsertion)
                                (cadr lstInsertion)
                                (atof strTextString)
                          )
       )
       (vlax-put objSelection "insertionpoint" lstInsertion)       
      )
     )
    )
   )
  )
 )
)
(vl-load-com)

Additional Filtering of Attributes

(defun C:SH1 (/
             entSelection
             intCount
             objAttribute
             objSelection
             ssSelections
             strTextstring
            )
 (if (setq ssSelections (ssget (list (cons 2 "SH"))))
  (repeat (setq intCount (sslength ssSelections))
   (setq intCount     (1- intCount)
         entSelection (ssname ssSelections intCount)
         objSelection (vlax-ename->vla-object entSelection)
   )
   (foreach objAttribute (vlax-invoke objSelection "getattributes")
    (if (= (vla-get-tagstring objAttribute) "A2")
     (if (/= (setq strTextstring (strcase (vla-get-textstring objAttribute))) "")
      (progn
         
       (if (vl-string-search "BC " strTextString)
        (setq strTextString (vl-string-subst "" "BC " strTextString))
       )

       (setq lstInsertion (vlax-get objSelection  "insertionpoint")
             lstInsertion (list (car lstInsertion)
                                (cadr lstInsertion)
                                (atof strTextString)
                          )
       )
       (vlax-put objSelection "insertionpoint" lstInsertion)       
      )
     )
    )
   )
  )
 )
)
(vl-load-com)

[SurveyorHead]

@ peter
it is working nice too!
thank you very much sir

[David Prontnicki]

(defun C:SH1 (/
             entSelection
             intCount
             objAttribute
             objSelection
             ssSelections
             strTextstring
            )
 (if (setq ssSelections (ssget (list (cons 2 "SH"))))
  (repeat (setq intCount (sslength ssSelections))
   (setq intCount     (1- intCount)
         entSelection (ssname ssSelections intCount)
         objSelection (vlax-ename->vla-object entSelection)
   )
   (foreach objAttribute (vlax-invoke objSelection "getattributes")
    (if (= (vla-get-tagstring objAttribute) "A2")
     (if (/= (setq strTextstring (vla-get-textstring objAttribute)) "")
      (progn
       (setq lstInsertion (vlax-get objSelection  "insertionpoint")
             lstInsertion (list (car lstInsertion)
                                (cadr lstInsertion)
                                (atof strTextString)
                          )
       )
       (vlax-put objSelection "insertionpoint" lstInsertion)       
      )
     )
    )
   )
  )
 )
)
(vl-load-com)

Peter,

This is great code and works perfect. I have a quick question. The block I'm using is a TC BC block that was created years ago. The block does not separate out the BC from the attribute. The users have been typing "BC 53.56". Is there a way to have the LISP ignore the "BC" and the space and then read the attribute. I know the correct way is to create the block with them as separate entities but they have been using this for years and exists in many drawing.

Thank you in advance,
Dave

[peter]

See additional code above for BC prefix exclusion.

Peter