Correct me ! Query

[sanrajbhar677632]

hello all,

Can you please guide me in this code. i write few codes to place block at point entity.

as i used "entsel ". it only allow to pick points not crossed window selection. below is my code. please dont give me link to download another lisp. i just write it using help file of AutoCAD. i want to know how can i do it in my lisp. there are several option on net to do so. but please guide me on this code.
keep in mind i am not expert in lisp

 
(defun c:bh1()
(setvar "OSMODE" 8)
(setq a (entsel "pick object"))
(setq b (cadr a))
(command "-insert" "BH" b "" "" "" "" "" "")
)

[Tharwat]

Something like this ..... ?

(defun c:TesT (/ ent)
  ;; Tharwat 12. Oct. 2011 ;;
  (if (and (setq ent (entsel "\n Select an entity :"))
           (member (cdr (assoc 0 (entget (car ent))))
                   '("LWPOLYLINE" "POLYLINE"   "LINE"
                     "SPLINE"     "XLINE"      "CIRCLE"
                     "ARC"
                    )
           )
           (tblsearch "BLOCK" "BH")
      )
    (entmakex
      (list '(0 . "INSERT")
            (cons 2 "BH")
            (cons 10
                  (vlax-curve-getclosestpointto (car ent) (cadr ent))
            )
            '(41 . 1.)
            '(42 . 1.)
            '(43 . 1.)
            '(50 . 0.)
      )
    )
    (princ)
  )
  (princ)
)

Tharwat

[Lee Mac]

If I have correctly understood your intentions, I think this would be suitable:

(defun c:test ( / *error* block i sel vars vals )
    
    (defun *error* ( msg )
        (if vals (mapcar 'setvar vars vals))
        (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
            (princ (strcat "\nError: " msg))
        )
        (princ)
    )

    (while
        (not
            (or
                (eq "" (setq block (getstring t "\nSpecify Block to Insert: ")))
                (tblsearch "BLOCK" block)
                (setq block (findfile (strcat block ".dwg")))
            )
        )
        (princ "\nBlock not found.")
    )

    (if
        (and
            (/= "" block)
            (setq sel (ssget '((0 . "POINT"))))
        )
        (progn
            (setq vars '("CMDECHO" "OSMODE" "ATTREQ")
                  vals  (mapcar 'getvar vars)
            )
            (mapcar 'setvar vars '(0 0 0))
            (repeat (setq i (sslength sel))
                (command "_.-insert" block "_S" 1.0 "_R" 0.0
                    (trans (cdr (assoc 10 (entget (ssname sel (setq i (1- i)))))) 0 1)
                )
            )
            (mapcar 'setvar vars vals)
        )
    )
    (princ)
)

Ask if you need any part of the code explained.

[sanrajbhar677632]

hey i used this code in my drawings. Can you make me explain it to me?

If I have correctly understood your intentions, I think this would be suitable:

(defun c:test ( / *error* block i sel vars vals )
 
    (defun *error* ( msg )
        (if vals (mapcar 'setvar vars vals))
        (if (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
            (princ (strcat "\nError: " msg))
        )
        (princ)
    )
 
    (while
        (not
            (or
                (eq "" (setq block (getstring t "\nSpecify Block to Insert: ")))
                (tblsearch "BLOCK" block)
                (setq block (findfile (strcat block ".dwg")))
            )
        )
        (princ "\nBlock not found.")
    )
 
    (if
        (and
            (/= "" block)
            (setq sel (ssget '((0 . "POINT"))))
        )
        (progn
            (setq vars '("CMDECHO" "OSMODE" "ATTREQ")
                  vals  (mapcar 'getvar vars)
            )
            (mapcar 'setvar vars '(0 0 0))
            (repeat (setq i (sslength sel))
                (command "_.-insert" block "_S" 1.0 "_R" 0.0
                    (trans (cdr (assoc 10 (entget (ssname sel (setq i (1- i)))))) 0 1)
                )
            )
            (mapcar 'setvar vars vals)
        )
    )
    (princ)
)

Ask if you need any part of the code explained.

[Lee Mac]

Can you make me explain it to me?

Which part do you not understand?