Obtaining Anno Scale of a saved view

[newfoundfreedom]

Hello All,
I need a little help. I am working on a routine and it would be really helpful if I could programatically obtain the annotation scale within a saved view. I am able to grab the view object, but was surprised that I was not able to discern the annotation scale associated with the view once I analyzed the object data.

any ideas?
thanks in advance for any help offered.

[BlackBox]

HI am able to grab the view object, but was surprised that I was not able to discern the annotation scale associated with the view once I analyzed the object data.

Do you mean a ViewPort Entity (that resides within PaperSpace), or a View Object (as in an Item of the Views Collection of the ActiveDocument Object)?

[newfoundfreedom]

Do you mean a ViewPort Entity (that resides within PaperSpace), or a View Object (as in an Item of the Views Collection of the ActiveDocument Object)?

Hey RenderMan - the later. I've created a series of modelspace views (View Objects not Viewports) that I need to be able to analyze and pull the Annotation Scale that they were saved with. If you go to the View Dialogue Box and click the view in Model Space you can see the Annotation View that was saved with that view - but it is greyed out. Obviously that information is saved within the View definition - I just cant seem to get to it.

[newfoundfreedom]

To further clarify - I'm not attempting to alter the Annotation Scale saved as part of the View Object Definition. Just need to pull the information to drive a different portion of my routine.

Thanks

[BlackBox]

Back when 2009 was new, I recall having an issue where there’s a one-way relationship with a named View, where the Annotation scale was saved to the View. When the View was restored, the Drawing Scale (Land Desktop) was made to be the same as the Annotation Scale, yet when manually setting the Drawing Scale, the Annotation was not changed… The source of much frustration for me.

In any event, given that a quick vlax-Dump-Object of a View Object doesn’t reveal the associated Annotation scale, perhaps digging through the View table record (DXF) will shed more light on what you’re after…? Not everything is exposed to Visual LISP unfortunately.

Worst case, you hop into Visual Studio, and code yourself a .NET LispFunction Method that will allow LISP to do this for you.

Good luck!

[newfoundfreedom]

haha - oh is "hopping" into Visual Studio and coding some .NET that easy for you? Unfortunately my skill set has not quite reached such epic proportions.

Actually, I began with the DXF records which lead me to try grabbing it through the Object Model. It would appear that what you are saying is that I am out-o-luck.

Thanks RenderMan

[irneb]

Not entirely necessary to use .Net for this. The AnnoScale is saved as an extension dictionary to the view object. The VL stuff only gets you so far (Adesk "decided" to stop updating the ActiveX library some time back). For the rest you need to look into the raw DXF data. E.g. this would extract the anno scale's name from the view name:

(vl-load-com)
(defun GetViewAnnoScale  (ViewName / view xDict annoScale)
  (if (not (vl-catch-all-error-p
             (setq view (vl-catch-all-apply
                          'vla-Item
                          (list (vla-get-Views (vla-get-ActiveDocument (vlax-get-acad-object))) ViewName)))))
   (if (and (eq (vla-get-HasExtensionDictionary view) :vlax-true)
            (setq xDict (vla-GetExtensionDictionary view))
            (not (vl-catch-all-error-p (setq annoScale (vl-catch-all-apply 'vla-Item (list xDict "ADSK_XREC_VTR_ANNOSCALE_DATA"))))))
     (cdr (assoc 300 (entget (cdr (assoc 340 (entget (vlax-vla-object->ename annoScale))))))))))

[irneb]

Or if you prefer the fully AutoLisp (no vl-stuff involved at all):

(defun GetViewAnnoScale2 (ViewName / view xDict annoScale)
  (if (and (setq view (tblobjname "VIEW" ViewName))
           (setq xDict (cdr (assoc 360 (entget view))))
           (setq annoScale (dictsearch xDict "ADSK_XREC_VTR_ANNOSCALE_DATA")))
    (cdr (assoc 300 (entget (cdr (assoc 340 annoScale)))))))

[BlackBox]

Irneb, my bru - You always come through!

Thanks for clarifying the issue of where that data is stored (in DXF - I thought that's where it would be!), but I enjoyed doing the little .NET ditty, as I've really been trying to self-teach, so opportunities like this just help me learn, as well as help others.

One of these days, I'll cross the pond and we'll dop a few, for now... Cheers!

[newfoundfreedom]

Wow - okay so there was a way to extract this through just LISP. Thanks for the tip. I am completely unfamiliar with the dictsearch function. I was just looking at the output of a (tblnext "view" viewname) and had not seen the DXF 360 group code listed. I will do some further research now that I see your code, but how did you know about the 360 group code?

By the way RenderMan - I never got back to you as I got totally caught up a few days ago. But your .NET function has worked beautifully - and I currently have my routine loading and calling it. Thank you for both writing it and the added support in all the help info you put in this post.