Deleting attributes from blocks

[JaCAD]

I'm trying to create a function which will remove all attributes from any block. The attributes need to be removed from all instances of the block.
I wrote my function as below.
It deletes the attributes, but when the Attsync command is called, AutoCAD tells me the following:
"Block table contains no attributed block named SomeBlock2", and the attributes are still displayed.

If, after this function has run, I manually type "ATTSYNC", and select one of the blocks, they will properly clean up the blocks.

Is there any way of properly attsyncing the block after the attributes have been deleted using this method?


(defun DeleteAtts (BName / Binfo En El EnTyp AttSync)

(setq BInfo (tblsearch "BLOCK" BName)
En (cdr (assoc -2 BInfo))
)

(while En
(setq El (entget En)
EnTyp (cdr (Assoc 0 El))
)
(if (= EnTyp "ATTDEF")
(progn
(entdel En)
(setq AttSync T)
);end progn
);end if
(setq En (entnext En))
);end while

(if AttSync
(command "ATTSYNC" "N" Bname)
);end if

(regen)
);end defun

[Tharwat]

Try this .....

(defun c:Test (/ ss i sn x)(vl-load-com)
;;; Tharwat 04. May . 2012 ;;;
  (if (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (repeat (setq i (sslength ss))
      (setq sn (ssname ss (setq i (1- i))))
      (while
        (not
          (eq (cdr (assoc 0 (entget (setq x (entnext sn))))) "SEQEND")
        )
         (if (eq (cdr (assoc 0 (entget x))) "ATTRIB")
           (vla-delete
             (vlax-ename->vla-object (cdr (assoc -1 (entget x))))
           )
         )
      )
    )
    (princ)
  )
  (princ)
)

[Tharwat]

or this would remove all attributes from all your blocks Definitions that are existed within your drawing ..

(defun c:Test nil
  (vl-load-com)
;;; Tharwat 04. May . 2012 ;;;
  (vlax-for x (vla-get-blocks
                (vla-get-activedocument (vlax-get-acad-object))
              )
    (if (and (eq :vlax-false (vla-get-isXref x))
             (eq :vlax-false (vla-get-islayout x))
        )
      (vlax-for ent x
        (if (eq (vla-get-objectname ent) "AcDbAttributeDefinition")
          (vla-delete ent)
        )
      )
    )
  )
  (princ)
)

[JaCAD]

Tharwat,

That's a nice piece of code, and seems to delete all attributes very efficiently. However...
From what I can see, this didn't delete the attributes from blocks that are inserted into model space. The attributes are still visible.
When I run AttSync to attempt to sync them up, I get the following message from AutoCAD:
"This drawing contains no attributed blocks."
Which, to me, proves that your code cleared out all the attributes from the blocks, but I'm still effectively seeing the same end result, the blocks aren't attsynced.

[Tharwat]

Tharwat,

That's a nice piece of code, and seems to delete all attributes very efficiently. However...
From what I can see, this didn't delete the attributes from blocks that are inserted into model space. The attributes are still visible.
When I run AttSync to attempt to sync them up, I get the following message from AutoCAD:
"This drawing contains no attributed blocks."
Which, to me, proves that your code cleared out all the attributes from the blocks, but I'm still effectively seeing the same end result, the blocks aren't attsynced.

So does it mean that you want to delete all attributes for all inserted and block definition from your drawing ?

Tharwat

[JaCAD]

Ideally, given a block name, the function would delete all attributes from the block definition, then attsync the block (or cycle through all inserts of the block) in order to clear up all instances of the block.

I'm trying to build a multi-purpose block-cleaning tool, with a variety of specific tasks. I have most of them figured out, it's just attributes that are messing me up.
The other potential problem is that the block may sometimes be found inserted in another block, and I need to address those situations as well.

[Tharwat]

My first routine would delete all attributes that are existed within the selected attributed block and the second
routine would delete all attributes from all blocks definitions within your current drawing .

[GHarvey]

Actually JaCAD, the only problem I had running your routine related to the

(regen)

right at the end. Possibly you are using a custom lisp function called "regen"? In any case, once I changed that line to

(command "regen")

the Deleteatts function worked well enough. I wonder if there might not have been a block in your drawing named "SomeBlock2" (i.e. the name might not be exactly correct)?

[JaCAD]

(regen) is actually (vla-regen #AcDoc# T), which does work if the document is bound to #AcDoc#. I was only using (regen) as a placeholder. also, "SomeBlock2" is just a place holder. I got the block name using (cdr (assoc 2 (entget (Car (entsel)))))

[GHarvey]

The following is a rather specialized function I wrote some time back to return a list containing all references (vla-objects) to a block, the name of which you supply as an argument.

After using a variation of Tharwat's second posted function to strip the attribute definitions from your block definition, you could use something like this (below) to collect all references to the block (by name). Then, use a variation of Tharwat's first posted function to strip the attribute references from each insert.

;;=============================================================================================
;; BLK-INS-FND RETURNS ALL INSERTIONS OF THE NAMED BLOCK, OTHERWISE NIL
(defun blk-ins-fnd (blk-nm / BLK-INS-LST BLKLST N NM-X SUB-BLKLST SUB-BLKLST-N
                    SUB-LST SUB-LST-LN THE-BLK THE-BLK-LST VL-X X)
  (or blocks (setq blocks (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))))
  (setq blk-nm (strcase blk-nm))
  (if (not
        (vl-catch-all-error-p
          (setq the-blk (vl-catch-all-apply 'vla-item (list blocks blk-nm)))
        ) ; vl-catch-all-error-p
      ) ; not
    (progn
      (setq the-blk-lst     (entget (vlax-vla-object->ename the-blk))
            sub-lst    (member (assoc 102 the-blk-lst) the-blk-lst)
            sub-lst-ln (length sub-lst)
            n          0
      ) ; setq
      (while (< n sub-lst-ln)
        (setq x (nth n sub-lst))
        (cond ((/= 331 (car x)) nil) ; first condition
              ((vl-catch-all-error-p
                 (setq vl-x
                        (vl-catch-all-apply
                          'vlax-ename->vla-object
                          (list (cdr x))
                        ) ; vl-catch-all-apply
                 ) ; setq
               ) ; vl-catch-all-error-p
               nil
              ) ; second condition
              (t (setq blk-ins-lst (append blk-ins-lst (list vl-x)))) ; default condition
        ) ; cond
        (setq n (1+ n))
      ) ; while
      (if (eq (vla-get-isdynamicblock the-blk) ':vlax-true)
        (progn
          (vlax-for blk blocks
            (if (wcmatch (strcase (vla-get-name blk)) "*U#*")
              (progn
                (setq blklst       (entget (vlax-vla-object->ename blk))
                      sub-blklst   (member (assoc 102 blklst) blklst)
                      sub-blklst-n (length sub-blklst)
                      n            0
                ) ; setq
                (while (< n sub-blklst-n)
                  (setq x (nth n sub-blklst))
                  (cond ((/= 331 (car x)) nil) ; first condition
                        ((vl-catch-all-error-p
                           (setq vl-x
                                  (vl-catch-all-apply
                                    'vlax-ename->vla-object
                                    (list (cdr x))
                                  ) ; vl-catch-all-apply
                           ) ; setq
                         ) ; vl-catch-all-error-p
                         nil
                        ) ; second condition
                        ((vl-catch-all-error-p
                           (setq nm-x
                                  (vl-catch-all-apply
                                    'vla-get-effectivename
                                    (list vl-x)
                                  ) ; vl-catch-all-apply
                           ) ; setq
                         ) ; vl-catch-all-error-p
                         nil
                        ) ; third condition
                        ((/= (strcase nm-x) blk-nm)
                         nil
                        ) ; fourth condition
                        (t
                         (setq blk-ins-lst
                                (append blk-ins-lst
                                        (list vl-x)
                                ) ; append
                         ) ; setq
                        ) ; default condition
                  ) ; cond
                  (setq n (1+ n))
                ) ; while
              ) ; progn
            ) ; if
          ) ; vlax-for
        ) ; progn
      ) ; if
    ) ; progn
  ) ; if
  (if (vl-consp blk-ins-lst)
    (setq blk-ins-lst (reverse (vl-remove nil blk-ins-lst)))
  ) ; if
  blk-ins-lst
); defun