Dim Text Above the Dim Line

[Tharwat]

That's correct irne'

My code also would behave as a temporary solution and when any modification would take a place on the dims , they would
go back to their previous shape ( according to dim style settings ) and that's odd isn't it ?

Thanks

[irneb]

My code also would behave as a temporary solution and when any modification would take a place on the dims , they would
go back to their previous shape ( according to dim style settings ) and that's odd isn't it ?

Not exactly "odd" I'd say. The block is simply a temporary thing which is recreated each time a change is made the the Dimension object. So every time a change is made to the dimension the entire block-definition is redone from scratch, thus your changes are deleted.

Actually I've just found another way of doing it ... use the XData for overrides. No need to fiddle with the exact text position, and no need to go into the block's definition. Also no need to even worry about other DimVars / Scaling / UCS / etc.

(defun c:DimTxtMoveUp  (/ en ed)
  (princ)
  (while (setq en (entsel))
    (setq ed (entget (car en)))
    (cond
      ((wcmatch (cdr (assoc 0 ed)) "DIM*")
       (entmod (list (assoc -1 ed)
                     (list -3 (list "ACAD" '(1000 . "DSTYLE") '(1002 . "{") '(1070 . 77) '(1070 . 1) '(1002 . "}"))))))
      (t (princ "\nThat's not a dimension, try again."))))
  (princ))

(defun c:DimTxtMoveDn  (/ en ed)
  (princ)
  (while (setq en (entsel))
    (setq ed (entget (car en)))
    (cond
      ((wcmatch (cdr (assoc 0 ed)) "DIM*")
       (entmod (list (assoc -1 ed)
                     (list -3 (list "ACAD" '(1000 . "DSTYLE") '(1002 . "{") '(1070 . 77) '(1070 . 4) '(1002 . "}"))))))
      (t (princ "\nThat's not a dimension, try again."))))
  (princ))

[BeKirra]

...You're modifying the temporary block of the dim object, as soon as anything changes on that dim (e.g. stretch) these edits are all gone.

Exactly!

And thanks irneb, for your last code. It works perfectly.
But I haven't learned into the "1000", "1002" and "1070" codes yet.
Could you tell me where to find those info in the "HELP"? Thanks again.

Thanks to Tharwat, too.

[irneb]

First look at xdata: http://docs.autodesk.com/ACD/2011/EN...7a53f-7a08.htm

Especially the organization section, but also retrieval & attach. Then you need to add xdata sections for each of the settings you want to override. E.g. to override the text height to 100.0, this is governed by DimTxt, which in turn is saved as code 140 in a DimStyle.

And then to override the arrow size to 100.0, this is DimAsz, which is code 41 of the DimStyle.

So the XData should look something like this:

(-3 ;Start of the XData DXF section
  ("ACAD" ;ACAD registered app section
    (1000 . "DSTYLE") ;DimStyle sub-section
    (1002 . "{") ;Group the next together
    (1070 . 41) ;An integer (16 bit) to reflect the DXF code of the DimAsz override
    (1040 . 100.0) ;A real value for the DimAsz override's value
    (1070 . 140) ;An integer (16 bit) to reflect the DXF code of the DimTxt override
    (1040 . 100.0) ;A real value for the DimTxt override's value
    (1002 . "}") ;End of group
  )
)

Notice the overrides are similar to the DXF codes of the DimStyle itself (this is something for DimStyles though, other stuff may work in other ways). Then in the XData each dxf code is placed in a 1070 (16bit integer) item followed by an item pertinent to the value's type (according to the XData Organization).

[pbejse]

... use the XData for overrides. No need to fiddle with the exact text position, and no need to go into the block's definition. Also no need to even worry about other DimVars / Scaling / UCS / etc.

Very nice!

[BeKirra]

It is great!
Thanks again, irneb.

[irneb]

You're all welcome. And it actually showed me how to do this ... never used xdata overrides before, so this was a learning experience for me as well.

[BeKirra]

You're all welcome. And it actually showed me how to do this ... never used xdata overrides before, so this was a learning experience for me as well.

I always learn something from you with your helps.
Thank you and I am very appreciated.

[BeKirra]

Hi irneb,
In your code, how to add a localised variable "dimTadValue" to the list? eg

'(1070 . DimTadValue)

So it will moves the dimtext up or down when the user changes the value of "DimTadValue".
It doesn't work as it returns an error message:

; error: bad DXF group: (-3 ("ACAD" (1000 . "DSTYLE") (1002 . "{") (1070 . 77)
(1070 DimTadValue) (1002 . "}")))

I have no problem with predefining the "DimTadValue".
Thanks for your help.

[irneb]

If you want to generate a pair from a variable you need to use cons instead of quote ('). Something like this:

(setq DimTadValue 4)
(cons 1070 DimTadValue) ;Returns (1070 . 4)

Using the quote will not evaluate the items in the list into their values. So using the following:

(setq DimTadValue 3)
'(1070 . DimTadValue) ;Returns (1070 . DIMTADVALUE) not (1070 . 3)