LEADER. LISP

[Scooby]

Hey, guys.
I'd like to put prefix in this routine. Anybody Could help me please?
e.g. BLS 1, BLS 2 ...

(defun C:ld  (/ num osm pt)
  (setq osm (getvar "osmode"))
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)
  (setq num (getint "\nEnter an initial number: "))
  (while
    (setq pt (getpoint
         "\nSpecify leader start point: (or hit ENTER to Exit) "))
     (command "._leader" pt pause "" (itoa num) "")
     (setq num (1+ num)))
  (setvar "cmdecho" 1)
  (setvar "osmode" osm)
  (princ)
  )
(princ "\nStart command with LD")
(princ)

Kind Regards

[Tharwat]

Take a look at the adds of this line to yours .

 (command "._leader" pt pause "" (strcat "Example :" (itoa num)) "")

[Scooby]

Does anyone have a leader lisp that will automatically increment numbers they would be willing to share?

Best
Regards

[Tharwat]

Does anyone have a leader lisp that will automatically increment numbers they would be willing to share?

Best
Regards

But your first code do incrementing the number that being inserted by the user , Isn't it ?

[Scooby]

Yes, but I wanna to put a particular code as a prefix and increment numbers.
e.g If put BLD as prefix and start the increment number in 2, the result is BLD 2, BLD 3 ...
But if I want to use BLS as a prefix??

Any ideas??
Thanks

[Tharwat]

My first reply does what you want , did you check it out ?
Just change the word example : to the one you want

[Scooby]

It's works!
I though that had other way or other lisp.
Because I have one lisp and I'd like this will be like that.
e.g. Command: NUM

Type prefix: <>: BLD

Type suffix: <>: 1

Enter start number <1>:

Thanks.

[Scooby]

It's works!
I though that had other way or other lisp.
e.g.
Command: ld
Type prefix: <>: BLD

Type suffix: <>: 1

Enter start number <1>:

Thanks.

[Tharwat]

Things like this .. .. ?

(defun C:ld (/ osm pt prf suf)
  (vl-load-com)
  (defun *error* (msg)
    (if	osm
      (progn (setvar "osmode" osm) (setvar "cmdecho" 1))
    )
    (or	(wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
	(princ (strcat "\n** Error: " msg " **"))
    )
    (princ)
  )
  (if (not num)
    (setq num 1)
  )
  (setq osm (getvar "osmode"))
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)
  (if (and (/= (setq prf (getstring t "\n Type prefix : ")) "")
	   (/= (setq suf (getstring t "\n Type suffix : ")) "")
	   (setq num (cond ((getint (strcat "\n Enter an initial number < "
					    (itoa num)
					    " > : "
				    )
			    )
			   )
			   (t num)
		     )
	   )
      )
    (while
      (setq
	pt (getpoint
	     "\nSpecify leader start point: (or hit ENTER to Exit) :"
	   )
      )
       (command	"._leader" "_non"
		pt
		pause
		""
		(strcat prf " " (itoa num) " " suf)
		""
       )
       (setq num (1+ num))
    )
  )
  (setvar "cmdecho" 1)
  (setvar "osmode" osm)
  (princ)
)
(princ "\nStart command with LD")
(princ)

[Tom Beauford]

The Express Tool TCOUNT does that and more. Give it a start number and increment with options to prefix, suffix, overwrite, or find&replace. It even has sorting options.