Include information on an entity of a drawing in autocad

[Edmar Cristiano]

Hi Guys,


I'm having trouble include information on an entity of a drawing in AutoCAD.




I have a dictionary of an entity ...

((-1 . <Entity name: 7ffffa49c40>) (0 . "LWPOLYLINE") (330 . <Entity name: 7ffffa3b9f0>) (5 . "110CC") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "0") (100 . "AcDbPolyline") (90 . 4) (70 . 0) (43 . 0.0) (38 . 0.0) (39 . 0.0) (10 -112.829 648.874) (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (10 25.6359 648.874) (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (10 197.659 497.202) (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (10 1395.96 497.202) (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (210 0.0 0.0 1.0))

I would like to include some information, (88. "LAND")




I was reading over some functions such as "DICTADD" but i did not ...


Has anyone done this??

thank you!!!

Edmar Cristiano dos Santos
http://www.augi.com/profile/ed_cristian/
edamicus@gmail.com

[pbejse]

Are you wanting to add "information" on individual entities? I suggest you use Extended Entity Data (XData) rather than dictionaries.

Read about it at
http://www.afralisp.net/autolisp/tut...ata-part-1.php
http://www.afralisp.net/autolisp/tut...d-xrecords.php

For the meantime here's an example for you:

(defun c:OXDSample (/ Add_XData Read_XData obj OData ofd)
;;;	Xdata Function by  ASMI		;;;
(defun  Add_XData (Ent                  ; - Entity Ename 
                App                     ; - Application name
                dList                   ; - XData list (list(cons group data)...)
                )
    (regapp App)
    (entmod
      (append
        (entget Ent)
        (list (list -3 (append (list App) dList)))
        )
      )
    )
  (defun  Read_XData (Ent               ; - Entity Ename 
                 apName                 ; - Application name
                 /
                 xEnt
                 )
    (setq  xEnt (entget Ent (list apName))
      xEnt (vl-remove
             apName
             (cadar
               (vl-remove-if
                 (function (lambda (a) (/= -3 (car a))))
                 xEnt
                 )
               )
             )
      )                                 ; end setq
    )
  (while (setq obj (car (entsel "\nSelect object :")))
    (if (setq OData (Read_XData obj "Edmar Cristiano Data"))
      (print (Read_XData obj "Edmar Cristiano Data"))
      (progn
        (setq dat (getstring "\nEnter Data: "))
        (Add_XData
          obj
          "Edmar Cristiano Data"
          (list (cons 1000 dat))
          )
        )
      )
    )
  (princ)
  )

HTH

[BlackBox]

Couple of things, if I may....

First, including your personal email address in your signature block is a great way of making spammer friends.

Second, to your question, if XData does not offer you the desired outcome, and you use either Map 3D, or Civil 3D, you may want to consider adding Object Data (OD) instead.

If you go the LISP route, look into the ADE_* functions found under Data Extension Functions, Function Catalog here:

(vl-load-com)

(defun c:MapLisp (/ file)
  (if (setq file
             (findfile
               (strcat
                 (vl-registry-read
                   (strcat "HKEY_LOCAL_MACHINE\\"
                           (if vlax-user-product-key                    ; If 2013
                             (vlax-user-product-key)                    ; Use 2013 function
                             (vlax-product-key)                         ; Use legacy function
                           )
                   )
                   "ACADLOCATION"
                 )
                 "\\Help\\acmaplisp.chm"
               )
             )
      )
    (help file)
    (prompt "\n** File not found ** ")
  )
  (princ)
)

If you decide to go the .NET API route instead, you may find this thread to be helpful; specifically posts #14, and #16.

HTH

[Edmar Cristiano]

Very good!!

I Will give a try.

Thanks

[BlackBox]

Very good!!

I Will give a try.

Thanks

You're welcome; I'm happy to help.