Sum of Dynamic Block Properties

[peter_zwiers350396]

Hi guys,

im new here so dont be to hard on me my lisp skills are minimal so.
Currently im working with a routine that returns the amount and property value of a certain block.

This is the situation:

Im having 1 block called "Mesh panels H1900"
This block has an dynamic property called "Width" and at the moment this is what the routine returns:

There are 1 instances of "Mesh panels H1900" with property "Width" set to 1198.
There are 2 instances of "Mesh panels H1900" with property "Width" set to 1298.
There are 59 instances of "Mesh panels H1900" with property "Width" set to 1498.
There are 8 instances of "Mesh panels H1900" with property "Width" set to 398.
There are 1 instances of "Mesh panels H1900" with property "Width" set to 498.
There are 1 instances of "Mesh panels H1900" with property "Width" set to 698.
There are 1 instances of "Mesh panels H1900" with property "Width" set to 798.
There are 1 instances of "Mesh panels H1900" with property "Width" set to 898.

Now the thing i want is the Total width of All the mesh panels, could you guys help me with that ?

;;;effname = name of block to count
;;;property = name of dynamic property to count
(vl-load-com)
(defun db_counts(effname property / sset proplist cnt en props old
		)
  
  (setq sset(ssdblk effname))
  (if(not sset)
    (alert(strcat "No Dynamic Blocks with effective name:  " effname))
    (progn;else
      (setq proplist(list)
	    cnt 0
      )
      (repeat(sslength sset)
	(setq en(ssname sset cnt)
	      cnt(1+ cnt)
	)
	(setq props(vlax-safearray->list(variant-value
		(vla-getdynamicblockproperties(vlax-ename->vla-object en))))
	)
	(foreach n props
	  (if(= (strcase(vla-get-propertyname n)) (strcase property))
	    (cond
              ((=(variant-type(vla-get-value n))2)
		(setq proplist(cons(itoa(variant-value(vla-get-value n)))proplist))
	      )
	      ((<(variant-type(vla-get-value n))8)
	        (setq proplist(cons(rtos(variant-value(vla-get-value n)))proplist))
	      )
	      (T (setq proplist(cons(variant-value(vla-get-value n))proplist)))
	    );cond
	  );if
	);foreach
	(setq proplist(vl-sort proplist '<))
      );repeat
      (setq cnt 0)
      (setq old nil)
      (foreach n proplist
	(setq cnt(-(length proplist)(length(setq proplist(vl-remove n proplist)))))
	(if(/= old n)
	  (princ(strcat"\nThere are " (itoa cnt) " instances of \"" effname
	 	       "\" with property \"" property "\" set to " n "."
	        )
	  )
	)
	(setq old n)
      );foreach
    );progn
  );if
  (setq sset nil)
  (princ)
);defun
(princ "\n(DB_COUNTS \"EFFNAME\" \"PROPERTY\")")

[pbejse]

Now the thing i want is the Total width of All the mesh panels, could you guys help me with that ?

BTW. Welcome peter zwiers

;;;effname = name of block to count
;;;property = name of dynamic property to count
(vl-load-com)
(defun db_counts(effname property / tw sset proplist cnt en props old
		)
  
  (setq sset(ssdblk effname))
  (if(not sset)
    (alert(strcat "No Dynamic Blocks with effective name:  " effname))
    (progn;else
      (setq proplist(list)
	    cnt 0
      )
      (repeat(sslength sset)
	(setq en(ssname sset cnt)
	      cnt(1+ cnt)
	)
	(setq props(vlax-safearray->list(variant-value
		(vla-getdynamicblockproperties(vlax-ename->vla-object en))))
	)
	(foreach n props
	  (if(= (strcase(vla-get-propertyname n)) (strcase property))
	    (cond
              ((=(variant-type(vla-get-value n))2)
		(setq proplist(cons(itoa(variant-value(vla-get-value n)))proplist))
	      )
	      ((<(variant-type(vla-get-value n))8)
	        (setq proplist(cons(rtos(variant-value(vla-get-value n)))proplist))
	      )
	      (T (setq proplist(cons(variant-value(vla-get-value n))proplist)))
	    );cond
	  );if
	);foreach
	(setq proplist(vl-sort proplist '<))
      );repeat
      (setq cnt 0)
      (setq old nil)
;;;;			      
      (Setq tw (mapcar 'distof proplist))
;;;;			      
      (foreach n proplist
	(setq cnt(-(length proplist)(length(setq proplist(vl-remove n proplist)))))
	(if(/= old n)
	  (princ(strcat"\nThere are " (itoa cnt) " instances of \"" effname
	 	       "\" with property \"" property "\" set to " n "."
	        )
	  )
	)
	(setq old n)
      );foreach
;;;;			
     (if tw (princ (Strcat "\nTotal Width: " (rtos (apply '+ tw)))))
;;;;			
    );progn
  );if
  ;;; (setq sset nil)
  (princ)
);defun

(princ "\n(DB_COUNTS \"EFFNAME\" \"PROPERTY\")")

HTH

[Norton_cad]

A non-lisp routine solution, would be to use tables to extract the dynamic block properties. Also the table would automatically update, as changes are made in the drawing.

[peter]

I just tried to see if I could cut the amount of code

(defun C:SumWidth (/ intCount objSelection ssSelections sngTotal sngWidth)
 (vl-load-com)
 (setq sngTotal 0.0)
 (if (setq ssSelections (ssget (list (cons 0 "insert"))))
  (repeat (setq intCount (sslength ssSelections))
   (setq intCount     (1- intCount)
         objSelection (vlax-ename->vla-object 
                       (ssname ssSelections intCount))
   
   )
   (and (setq sngWidth (cadr (assoc "Width" (getdynamics objSelection))))
        (setq sngTotal (+ sngTotal sngWidth)) 
   )
  )
 )
 sngTotal
)

(defun GetDynamics (objSelection )                
 (mapcar '(lambda (x)(list (vla-get-propertyname X)
                           (variant-value (vla-get-value X)))) 
          (vlax-invoke objSelection "GetDynamicBlockProperties"))
)

[pbejse]

Another

(Defun c:sumw ( / ss e d db lst)
  	(if (setq ss (ssget (list (cons 0 "insert"))))
	(repeat (sslength ss)
        		(setq e (vlax-ename->vla-object (ssname ss 0)))
			(if (and  (eq (vla-get-IsDynamicBlock e) :vlax-true)
                (setq db (Car (vl-remove-if-not (function (lambda (x)
								(eq "Width" (vla-get-propertyname X))))                                                    
        				(vlax-invoke e "GetDynamicBlockProperties")))))
            	  		(if (Setq d (assoc (setq bn (vla-get-effectivename e)) lst))
                          (setq lst (subst (list bn (+ (vlax-get db 'Value)(cadr d))) d lst))
                          (setq lst (cons (list bn (vlax-get db 'Value)) lst))
                        ))
        	(ssdel (ssname ss 0) ss)
        )
        )
  (foreach itm lst
        (print itm))
  (princ)
  )

[peter_zwiers350396]

Awesome! it works like a charm, Thanks for the support

[pbejse]

Awesome! it works like a charm, Thanks for the support

We are glad to be of service peter_zwiers. Hope you learn something from the snippets.

Keep on coding.