need a little help for AREA TEXT lisp

[yewintnaing434202]

hello Geeks
i have found one useful lisp file for area (pick poly line and place a text on the dwg)
here is a lisp file

(defun drtxt (/ rn tx ls vl lt ht lb hb nr pt)
  (setq tx (strcat "Area: " 
       (rtos (/ (getvar "area") 1000000) 2 2) 
       " m2"
       )         
       rn (getstring "\nRoom Name: ")
  )
  (setq ls (list (cons 1 tx))
      vl (textbox ls)
      vl (cadr vl)
      lt (car vl)
      ht (cadr vl)
      vl (grread T)
      nr (car vl)
      pt (cadr vl)
  )
  (princ "\nInsert Point: ")
  (while (/= nr 3)
    (command "redraw")
    (grdraw pt (setq pt (polar pt 0 lt)) 7)
    (grdraw pt (setq pt (polar pt (* pi 0.5) ht)) 7)
    (grdraw pt (setq pt (polar pt pi lt)) 7)
    (grdraw pt (polar pt (* pi 1.5) ht) 7)
    (setq vl (grread T)
      nr (car vl)
      pt (cadr vl)
    )
    ) ;end while function
  (command "-mtext" pt "w" 0 rn tx "")
  (redraw)
) ; end drtxt function

(defun c:pla ()
  (setvar "cmdecho" 0)
  (while (setq et 
       (car 
             (entsel "\nSelect polyline: ")
         ) ;end car function
     ) ;end setq function
  (command "area" "o" et)
  (drtxt)
  ) ; wnd while funtion

(setvar "cmdecho" 1)
(princ)

) ; end c:pla function

what i want to modify is, just a area without typing a Room Name.
can someone help me edit the original lisp?
i would be very much appreciated, if someone could help me with this.
thanks a lot
YWN

[Tharwat]

Check this out .

(defun drtxt (/ tx ls vl lt ht lb hb nr pt)
  (setq tx (strcat "Area: "
                   (rtos (/ (getvar "area") 1000000) 2 2)
                   " m2"
           )
  )
  (setq ls (list (cons 1 tx))
        vl (textbox ls)
        vl (cadr vl)
        lt (car vl)
        ht (cadr vl)
        vl (grread T)
        nr (car vl)
        pt (cadr vl)
  )
  (princ "\nInsert Point: ")
  (while (/= nr 3)
    (command "redraw")
    (grdraw pt (setq pt (polar pt 0 lt)) 7)
    (grdraw pt (setq pt (polar pt (* pi 0.5) ht)) 7)
    (grdraw pt (setq pt (polar pt pi lt)) 7)
    (grdraw pt (polar pt (* pi 1.5) ht) 7)
    (setq vl (grread T)
          nr (car vl)
          pt (cadr vl)
    )
  )                                     ;end while function
  (command "-mtext" pt "w" 0 tx "")
  (redraw)
)                                       ; end drtxt function

(defun c:pla (/ et)
  (setvar "cmdecho" 0)
  (while (setq et
                (car
                  (entsel "\nSelect polyline: ")
                )                       ;end car function
         )                              ;end setq function
    (command "area" "o" et)
    (drtxt)
  )                                     ; wnd while funtion

  (setvar "cmdecho" 1)
  (princ)

)                                       ; end c:pla function

[ReachAndre]

Blackbox helped me on a similar program.
http://forums.augi.com/showthread.ph...g-of-polylines

[csyoung17770576]

Thanks. it is very helpful, it works very well