Test for Existing Vis State

[stusic]

Can someone help me create a test to see if a vis state exists in a particular block? I'm not even sure where to begin on this one. I think I get how to do it, but I'm not sure how to put it together. I know I'll need to use the getdynamicblockproperties function, get the visibility property ("Visibility1"), get a list of allowedvalues, then match my variable against this list, returning true/false. Most of the examples I've seen use variants, which I'm not familiar with, and are put together in such a way I don't get. sadpandaface

[stusic]

I think I found what I needed from (where else) Lee Mac's subroutines. Just got to form it into a test.

[BlackBox]

You'll need to test if the desired Visibility State is contained within the DynamicBlockReferenceProperty Object's AllowedValues.

Cheers

[peter]

My First Thought is to get the allowed values of all dynamic properties on a block

Syntax

(DynamicPropertyAllowedValues (car (entsel "\nSelect Block: ")) "*")

(defun DynamicPropertyAllowedValues (objBlock strWCName / lstAllowedValues lstReturn strProperty strWCName)
 (if (= (type objBlock) 'ENAME)
  (setq objBlock (vlax-ename->vla-object objBlock))
 )
 (foreach objProperty (vlax-invoke objBlock "getdynamicblockproperties")
  (if (wcmatch (setq strProperty (vla-get-propertyname objProperty)) strWCName)
   (if (setq lstAllowedValues (vlax-get objProperty "AllowedValues"))
    (setq lstReturn (cons (cons strProperty lstAllowedValues) lstReturn))
   )
  )
 )
 lstReturn
)

[stusic]

Naturally, Your code is much more robust than mine. With error-trapping and such. I don't error trap because I'm the kind of guy that lives life on the edge. And I never really got around to figuring out how...

I found Lee's sub and didn't want to reinvent the wheel (not really, I just couldn't quite figure out what was going on), so I used it and came up with this:

;; "mod" is the visibility state I want, "osdynprop" is a list of vis states Lee's subroutine returns

(and	(setq osdynprop (LM:getdynpropallowedvalues tmp "Visibility1"))
	(/= (member mod osdynprop) nil))

This will only work for a minute though. I'll need to do this again, but use a wcmatch against the list...

[stusic]

...
  (if (wcmatch (setq strProperty (vla-get-propertyname objProperty)) strWCName)
...

I see you happen to use the wcmatch...

[bhull1985403354]

(member mod (car osdynprop))

Try that already?

[peter]

Although I learn from others code, I always prefer to write it from scratch.

The function returns a list of sublists that match the two fields and can handle reals and integer allowed values too.

(dynamicpropertyisallowed objBlock "Vis*" "MyAllowedValue*")

(defun DynamicPropertyIsAllowed (objBlock strWCPropertyName WCAllowedValue / 
                                 blnReturn lstSublist strProperty objProperty lstReturn)
 (foreach objProperty (vlax-invoke objBlock "getdynamicblockproperties")
  (if (wcmatch (strcase (setq strProperty (vla-get-propertyname objProperty))) (strcase strWCPropertyName))
   (if (setq lstAllowedValues (vlax-get objProperty "AllowedValues"))
    (progn
     (setq lstSublist nil)
     (foreach AllowedValue lstAllowedValues
      (if (or (and (= (type AllowedValue) 'REAL)
                   (equal AllowedValue WCAllowedValue 0.0001)
              )
              (and (= (type AllowedValue) 'INT)
                   (= AllowedValue WCAllowedValue)     
              )
              (and (= (type AllowedValue) 'STR)
                   (wcmatch (strcase AllowedValue) (strcase WCAllowedValue))
              ) 
          )
       (setq lstSublist (cons AllowedValue lstSublist))
      )
     )
     (if lstSublist
      (setq lstReturn (cons (cons strProperty (reverse lstSublist)) lstReturn))
     )     
    )
   )
  )
 )
 lstReturn
)

[stusic]

Mad skillz. I'm getting to the point where I can look at some code and figure out what's going on, but how you create it is still beyond me.

[BlackBox]

... how you create it is still beyond me.

'[Developer's] Guide to the Universe' essentials....

A good vocabulary of keywords/functions ("Babel Fish"), knowing where to look when you cannot possibly remember it all ("Apropos," etc.), make sure you've fueled up your Improbability Drive (aka paid your internet invoice, so you can jump on Al Gore's Interwebs), and always, I mean always bring your towel (to wipe away your tears when you have to resort to using the online help)!

... Don't Panic.