baby steps in lisp/script attribute visibilty

[maomuchmar]

have a very specific function
on our drawings we have multiple blocks with standard attribute definitions
information is displayed for internal and client use
when construction is finished we send a pdf copy of our documents to our clients

what we want to do is search through all our drawings find the same attributes in each block and make them invisible before pdf creation

not being a programmer i see the steps as follows

scan all blocks
find attribute x
turn x off

i can batch scripts or lisp files so the routine only needs to work for an open drawing

any ideas to help me on my way

[DI Dad]

I could see two ways to do this (though neither require any programming): 1) Put the attributes on their own layer or 2) Make the blocks dynamic with a visibility component (though this could be tedious if you have a large number in each drawing).

[GHarvey]

You might be able to use a variation of the following:

;; ATTVIS LOCATES ALL BLOCK REFERENCES IN THE ACTIVE LAYOUT WHICH CONTAIN AN
;; ATTRIBUTE REFERENCE WITH A PARTICULAR TAG (T_G) STRING, AND SETS SAID
;; ATTRIBUTE REFERENCES TO EITHER INVISIBLE (YN = NIL) OR VISIBLE (YN /= NIL)
;; -> T_G CAN ALSO BE A LIST OF TAG STRINGS
(defun attvis (t_g yn / ACTBLK N-ATTLST N-ATTS TG-LST)
  (vl-load-com)
  (setq actblk (vlax-get-property
		 (vlax-get-property
		   (vlax-get-property
		     (vlax-get-acad-object)
		     'activedocument
		     ); vlax-get-property
		   'activelayout
		   ); vlax-get-property
		 'block
		 ); vlax-get-property
	tg-lst (cond ((= 'STR (type t_g)) (list (strcase t_g))); single string
		     ((and (listp t_g)
			   (< 0 (length t_g))
			   (not (vl-member-if-not
				  '(lambda (a)
				     (= 'STR (type a))
				     ); lambda
				  t_g
				  ); vl-member-if-not
				); not
			   ); and
		      (mapcar 'strcase t_g)
		      ); list of strings
		     (t nil)
		     ); cond
	); setq
  (if tg-lst
    (progn
      (vlax-for n actblk
	(if
	  (and
	    (= "AcDbBlockReference" (vlax-get-property n 'objectname))
	    (= 'safearray (type (setq n-atts (vlax-variant-value (vla-getattributes n)))))
	    (< 0 (vlax-safearray-get-u-bound n-atts 1))
	    (< 0 (length (setq n-attlst (vlax-safearray->list n-atts))))
	    ); and
	  (foreach x n-attlst
	    (if (member (strcase (vlax-get-property x 'tagstring)) tg-lst)
	      (vlax-put-property x 'visible (if yn :vlax-true :vlax-false))
	  ); if
	); foreach
      ); if
    ); vlax-for
      ); progn
    (prompt "\nInvalid Data ")
    ); if
  (princ)
  ); defun

[maomuchmar]

the dynamic block thing is not going to work quite simply we have at least 10,000 blocks we use and anything up to 400 blocks on certain drawings the man hours involved in setting up that system is frightening

good idea though keep posting messages

[maomuchmar]

ill try this later today im under pressure to get something sorted today i will post my results later