Setting the ACAD environment variable on launch

[jpcadconsulting347236]

Hey gang,

I am trying to set the search paths on launch by adding the following line to acad.doc

(setenv "ACAD" "\\\\ny-fs01\\cad_common$\\autocad 2014\\hatches;\\\\ny-fs01\\cad_common$\\autocad 2014\\lisp;\\\\ny-fs01\\cad_common$\\autocad 2014\\drawings;%RoamableRootFolder%\\support;\\\\ny-fs01\\cad_common$\\autocad 2014\\support\\en-us;\\\\ny-fs01\\cad_common$\\autocad 2014\\fonts;%InstallFolder%\\help;%InstallFolder%\\express;\\\\ny-fs01\\cad_common$\\autocad 2014\\support\\color;%InstallFolder%\\aca;c:\\programdata\\autodesk\\applicationplugins\\autodesk appmanager.bundle\\contents\\resources;c:\\programdata\\autodesk\\applicationplugins\\autodesk appmanager.bundle\\contents\\windows\\2014;c:\\programdata\\autodesk\\applicationplugins\\autodesk importskp.bundle\\contents\\resources;%InstallFolder%\\bin\\fdo;")

It works fine except for the paths with either %RoamableRootFolder% or %InstallFolder%. Its not enumerating those paths in the config dialog box:

paths.png

Any advice?

Thanks,

-JP

[BlackBox]

FWIW - You can also modify the SupportPath Property of the PreferencesFiles Object.



%RoamableRootPrefix% -

(getvar 'roamablerootprefix)

%InstallFolder% -

(vl-load-com)

(vl-registry-read
  (strcat "HKEY_LOCAL_MACHINE\\"
	  (if vlax-user-product-key					; If 2013+
	    (vlax-user-product-key)					; Use 2013+ function
	    (vlax-product-key)						; Use legacy function
	  )
  )
  "ACADLOCATION"
)

HTH

[jpcadconsulting347236]

Thanks Blackbox,

Issuing that code at the command line returns the correct path for my RoamableRootFolder.

Beyond that, I'm a little out of my depth on this one. I assume its not as simple as adding the code (getvar 'roamablerootprefix) ahead of my code...

[jpcadconsulting347236]

I've had some success. I can get this to work:

(setenv "ACAD"(strcat (getvar 'RoamableRootPrefix) "Support\\")

However, I need to add other paths of course, and some of them need to be above this path... Which is not working. So, now its a syntax issue.

Any help is appreciated.

I'd love to modify the SupportPath Property of the PreferencesFiles Object... but that is right over my head.

[BlackBox]

Inspired by this, here's a quick excerpt from an old Civil 3D Acad.lsp file you can cull:

(vl-load-com)
;;;--------------------------------------------------------------------;
(defun c:AcadLsp (/ *error*)

  (defun *error* (msg)
    (and cmdecho (setvar 'cmdecho cmdecho))
    (cond ((not msg))							; Normal exit
	  ((member msg '("Function cancelled" "quit / exit abort")))	; <esc> or (quit)
	  ((princ (strcat "\n** Error: " msg " ** ")))			; Fatal error, display it
    )
    (princ)
  )

  ((lambda
     (user cmdecho arxList arxFiles netFiles / oFiles acadLoc)
      (setvar 'cmdecho 0)
      (terpri)

      ;; Load arx utilities
      (foreach x arxFiles
	(if (and (findfile x)
		 (not (vl-position (vl-filename-base x) arxList))
	    )
	  (vl-catch-all-apply 'arxload (list x))
	)
      )

      ;; Load net utilities
      (foreach dll netFiles
	(if (findfile dll)
	  (progn
	    (terpri)
	    (command "netload" dll)
	  )
	)
      )

      ;; Profile information
      (setq oFiles (vla-get-files
		     (vla-get-preferences (vlax-get-acad-object))
		   )
      )

      (setq acadloc
	     (vl-registry-read
	       (strcat "HKEY_LOCAL_MACHINE\\"
		       (if vlax-user-product-key			; If 2013+
			 (vlax-user-product-key)			; Use 2013+ function
			 (vlax-product-key)				; Use legacy function
		       )
	       )
	       "ACADLOCATION"
	     )
      )

      (vla-put-SupportPath
	oFiles
	(vl-string-right-trim
	  ";"
	  (apply
	    'strcat
	    (mapcar
	      '(lambda (x) (strcat x ";"))
	      (list
		;;<-- set custom enterprise path(s) here

		;;<-- set custom user path(s) here

		(strcat (getvar 'roamablerootprefix) "support;")
		(strcat acadloc "\\civil")
		(strcat acadloc "\\express")
		(strcat acadloc "\\fdo\\bin")
		(strcat acadloc "\\fonts")
		(strcat acadloc "\\help")
		(strcat acadloc "\\support")
		(strcat acadloc "\\support\\color")
		
		;;<-- set additional default path(s) here

	      )
	    )
	  )
	)
      )

      (*error* nil)
   )
    (getvar 'loginname)							; User
    (getvar 'cmdecho)
    (arx)								; arxList
    '(									; arxFiles
      ;;<-- your .arx assemblies here
     )
    '(									; netFiles
      ;;<-- your .net assemblies here
     )
  )
)
;;;--------------------------------------------------------------------;
(c:AcadLsp)
(prompt "\n... Acad.lsp for Civil 3D 20XX loaded. ")
(princ)

HTH

[BlackBox]

;;; ...

      ;; Load arx utilities
      (foreach x arxFiles
	(if (and (findfile x)
		 (not (vl-position (vl-filename-base x) arxList))
	    )
	  (vl-catch-all-apply 'arxload (list x))
	)
      )

      ;; Load net utilities
      (foreach dll netFiles
	(if (findfile dll)
	  (progn
	    (terpri)
	    (command "netload" dll)
	  )
	)
      )

;;; ...

In 2012+, these two functions can be removed, and instead use the newer Autoloader Mechanism to manage such plug-ins... Autoloader can also handle LISP, CUIx, etc. but I still use Acad.lsp and AcadDoc.lsp for now.

[spoilers removed]

[rkmcswain]

I am trying to set the search paths on launch by adding the following line to acad.doc

I think you may mean "acad.lsp", not "acad.doc" (or "acaddoc.lsp"?, since there is no "acad.doc")

Anyway, this may be worth a read also.

[jpcadconsulting347236]

I did. Good eye.

Our IT swapped servers w/o telling me so I was kind of preoccupied...

Thanks!!!

[jpcadconsulting347236]

Boom! Working like a charm.

Thanks very much gang!!!