Freeze/Thaw layer with specified text in layer name

[Arterius]

Hi all,

can you help me with something?
I would like to have a shortcut for freeze and thaw (toggle) all layers with specified text in layer name.
For example I have a few layers:
D_400$0$Structure-wall
D_400$0$Structure-wall-under
D_500$0$Structure-columns
D_500$0$Structure-columns-under
etc.

Is there a possibility to have toggle between showing and hidding all layers with "Structure" inside?

Thanks in advance.
Artur

[BlackBox]

Hi all,

can you help me with something?
I would like to have a shortcut for freeze and thaw (toggle) all layers with specified text in layer name.
For example I have a few layers:
D_400$0$Structure-wall
D_400$0$Structure-wall-under
D_500$0$Structure-columns
D_500$0$Structure-columns-under
etc.

Is there a possibility to have toggle between showing and hidding all layers with "Structure" inside?

Thanks in advance.
Artur

Consider the -LAYER Command:

(defun c:MyLayFrz () (command "._-layer" "_f" pause "") (princ))

(defun c:MyLayThw () (command "._-layer" "_t" pause "") (princ))

... When prompted for layer name(s), simply enter *structure*, and all matching layers will be acted upon accordingly.

[Arterius]

Thanks BlackBox,

I didn't know that asteriskes can bring so much good

Thanks for help!

[BlackBox]

Thanks BlackBox,

I didn't know that asteriskes can bring so much good

Thanks for help!

You're welcome, Arterius; I'm happy to help.

For reference, you find the WCMATCH function to be of particular interest now.

Cheers

[Arterius]

Thanks.

BlackBox, is it possible to make it work like a toggle?
When I type "MyLayFrz" layer go freeze, when type it again it thaw?

[Frank Dux]

(defun c:MyLayFrz (/ e cmdecho)
  (setq cmdecho (getvar 'cmdecho))
  (setvar 'cmdecho 0)
  (tblnext "layer" T)
  (while (setq e (tblnext "layer"))
    (if (wcmatch (strcase (cdr (assoc 2 e))) "*STRUCTURE*")
      (if (= (cdr (assoc 70 e)) 0)
	(command "._-layer" "_f" (cdr (assoc 2 e)) "")
	(command "._-layer" "_t" (cdr (assoc 2 e)) "")
      )
    )
  )
  (setvar 'cmdecho cmdecho)
  (princ)
)

[BlackBox]

BlackBox, is it possible to make it work like a toggle?
When I type "MyLayFrz" layer go freeze, when type it again it thaw?

(defun c:MyLayFrz (/ layers)
  (if *MyLayFrz*
    (setq *MyLayFrz* (command "._-layer" "_t" *MyLayFrz* ""))
    (if
      (setq layers
	     (getstring
	       T
	       "\nEnter name list of layer(s) to freeze: "
	     )
      )
       (command "._-layer" "_f" (setq *MyLayFrz* layers) "")
    )
  )
  (princ)
)

[BlackBox]

(defun c:MyLayFrz (/ e cmdecho)
  (setq cmdecho (getvar 'cmdecho))
  (setvar 'cmdecho 0)
  (tblnext "layer" T)
  (while (setq e (tblnext "layer"))
    (if (wcmatch (strcase (cdr (assoc 2 e))) "*STRUCTURE*")
      (if (= (cdr (assoc 70 e)) 0)
	(command "._-layer" "_f" (cdr (assoc 2 e)) "")
	(command "._-layer" "_t" (cdr (assoc 2 e)) "")
      )
    )
  )
  (setvar 'cmdecho cmdecho)
  (princ)
)

Just some observations on your code logic, if I may....

If you're going to change user setting(s), then it is prudent to include error handling in order to restore one's settings, even on failure.

There's no need to iterate the LayerTable, as the -LAYER Command support WCMATCH functionality; as coded you iterate the LayerTable, and for each-and-every-single LayerTableRecord that WCMATCHes "*STRUCTURE*" you call the -LAYER Command separately... If 100 LayerTableRecords match, then you've effectively called the Command 100 separate times, which is not very efficient as you could instead simply supply "*STRUCTURE*" to the -LAYER Command once, and yield the same result.

Here's a quick example, with a drawing that has 100 LayerTableRecords that include "*STRUCTURE*" in the name, bench-marking your approach, an approach that iterates the LayerTable to build a list of strings and then only calls the -LAYER Command once vs. what I've posed here using WCMATCH from the outset:

Sub-functions tested:

(vl-load-com)

(defun fdux:FreezeStructureLayers (/ e layerName)
  (tblnext "layer" T)
  (while (setq e (tblnext "layer"))
    (if (wcmatch (strcase (setq layerName (cdr (assoc 2 e)))) "*STRUCTURE*")
      (command "._-layer" "_f" layerName "")
    )
  )
  (princ)
)

(defun fdux:FreezeStructureLayers2 (/ e layerName layersToFreeze)
  (tblnext "layer" T)
  (while (setq e (tblnext "layer"))
    (if (wcmatch (strcase (setq layerName (cdr (assoc 2 e)))) "*STRUCTURE*")
      (setq layersToFreeze (cons layerName layersToFreeze))
    )
  )
  (if layersToFreeze
    (command
      "._-layer"
      "_f"
      (vl-string-right-trim
	","
	(apply
	  'strcat
	  (mapcar (function (lambda (x) (strcat x ","))) layersToFreeze)
	)
      )
      ""
    )
  )
  (princ)
)

(defun bbox:FreezeStructureLayers (/ layers)
  (command "._-layer" "_f" "*structure*" "")
  (princ)
)

Results from console, performing each sub-function 10 times only:

_$ (bench '(fdux:FreezeStructureLayers fdux:FreezeStructureLayers2 bbox:FreezeStructureLayers) '() 10)

FDUX:FREEZESTRUCTURELAYERS
Elapsed: 1498
Average: 149.8000

FDUX:FREEZESTRUCTURELAYERS2
Elapsed: 141
Average: 14.1000

BBOX:FREEZESTRUCTURELAYERS
Elapsed: 16
Average: 1.6000
; 5 forms loaded from #<editor "<Untitled-0> loading...">
_$

Lastly, you're checking each matching layer's current state, which allows for user to freeze all using this routine, then modify some of them before attempting to toggle, which potentially results in a mixed state where some "*STRUCTURE*" layers are thawed, and some are frozen.

Cheers

[Frank Dux]

Thanks BlackBox ... after four years I am only now starting to get comfortable with AutoLisp and even at that I am still meandering at a basic level (I haven't even started with ActiveX/Visual Lisp yet). I like your code snippet, simple and to the point. I will probably end up copying your style in fact. I'll give due credit if I do.

Have a nice weekend.

FD

[BlackBox]

Thanks BlackBox ... after four years I am only now starting to get comfortable with AutoLisp and even at that I am still meandering at a basic level (I haven't even started with ActiveX/Visual Lisp yet). I like your code snippet, simple and to the point. I will probably end up copying your style in fact. I'll give due credit if I do.

Have a nice weekend.

No worries; we all start somewhere... I'm just trying to save you some of the frustrations I've already had to learn the hard way.

If I can get to where I am with development, you'll certainly become more proficient as well... I had a lot of help along the way from others much smarter than I, and often joke about the fact that I didn't even know what a LISP Defun was when I joined AUGI (November 2009). LoL

Cheers