Block at Layout

[eblanco_74]

How can I find out which layout is a block inserted. I've already made a list of all my layouts and also the name of the specific block I want the data from. Can anybody help me!

[BlackBox]

How can I find out which layout is a block inserted.

Consider the TBLSEARCH function if querying the active document.

I've already made a list of all my layouts and also the name of the specific block I want the data from.

How did you accomplish that exactly?

It's a lot easier to help when you post your code... Stab in the dark (supports OBDX):

(vl-load-com)

(defun _FindBlock (doc blockName / layoutName layouts)
  ;; Example: (_FindBlock acdoc "foo")
  (setq blockName (strcase blockName))
  (vlax-for layout (vla-get-layouts acdoc)
    (vlax-for x (vla-get-block layout)
      (if
        (and
          (= "AcDbBlockReference" (vla-get-objectname x))
          (= blockName (strcase (vla-get-name x)))
          (not (vl-position
                 (setq layoutName (vla-get-name layout))
                 layouts
               )
          )
        )
        (setq layouts (cons layoutName layouts))
      )
    )
  )
  layouts
)

HTH

[Tharwat]

Another way and should obtain the Dynamic Block names as well

(defun _FindBlockLocation (Blockname / ly lst)
  ;;    Tharwat 11.July.2014    ;;
  (vlax-for x (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
    (if (eq (vla-get-isLayout x) :vlax-true)
      (vlax-for o x
        (if
          (and
            (eq (vla-get-objectname o) "AcDbBlockReference")
            (eq (strcase (vla-get-effectivename o)) (strcase BlockName))
            (not (member (setq ly (vla-get-name (vla-get-layout x))) lst))
          )
           (setq lst (cons ly lst))
        )
      )
    )
  )
  (reverse lst)
)(vl-load-com)

[BlackBox]

Another way and should obtain the Dynamic Block names as well

... And removes ObjectDBX support for batch operations.

[Tharwat]

... And removes ObjectDBX support for batch operations.

Cheers

[eblanco_74]

BlackBox/Tharwat:

Thanks a lot for your fast response. I really appreciate and it helped me a lot. I should had post the code but I was working on it (and still am) and does not had nothing concrete by the time but your codes "showed me the light" and here's what I've done. At the end what I need it's a list of attributes from a block (a title block) that's inserted on each layouts and the layout name itself. Any suggestions will be appreciated

Sorry. I did not know how to insert my code other than this...

(defun c:sds_index ()
  (setq	accdoc	   (vla-get-activedocument (vlax-get-acad-object))
	blks	   (vla-get-blocks accdoc)
	lst-att-ly '()
	) ;_ end of setq
  (vlax-for x blks
    (if	(and
	  (= (vla-get-isLayout x) :vlax-true)
	  (/= (vla-get-name x) "*Model_Space")
	  ) ;_ end of and
      (vlax-for	o x
	(if
	  (and
	    (= (vla-get-objectname o) "AcDbBlockReference")
	    (= (strcase (vla-get-effectivename o)) "SDS_FDS-TITLE_BLK")
	    ) ;_ end of and
	   (setq lst-att-ly
		  (cons
		    (cons
		      (vla-get-taborder (setq lay-obj (vla-get-layout x)))
		      (cons (vla-get-name lay-obj) (index-get_att o "DSCP"))
		      ) ;_ end of cons
		    lst-att-ly
		    ) ;_ end of cons
		 ) ;_ end of setq
	   ) ;_ end of if
	) ;_ end of vlax-for
      ) ;_ end of if
    ) ;_ end of vlax-for
  (setq lst-att-ly (vl-sort lst-att-ly (function (lambda (e1 e2) (< (car e1) (car e2))))))
  ) ;_ end of defun

(defun index-get_att (blk tag /)
  (setq	atts (vlax-invoke blk "getattributes")
	ct-a (length atts)
	ct   0
	) ;_ end of setq
  (while (> ct-a ct)
    (setq att	 (nth ct atts)
	  nm-att (vla-get-tagstring att)
	  ) ;_ end of setq
    (if	(= nm-att tag)
      (progn
	(setq value (vla-get-textstring att)
	      ct    ct-a
	      ) ;_ end of setq
	) ;_ end of progn
      (setq ct (1+ ct))
      ) ;_ end of if
    ) ;_ end of while
  value
  ) ;_ end of defun

[Tharwat]

Try this ..

(defun c:Test (/ atts lst ok ly l)
  ;;    Tharwat 15.July.2014    ;;
  (vlax-for x (vla-get-blocks
                (vla-get-activedocument (vlax-get-acad-object))
              )
    (if (and (eq (vla-get-isLayout x) :vlax-true)
             (not
               (eq (setq ly (vla-get-name (vla-get-layout x))) "Model")
             )
        )
      (progn
        (setq lst nil)
        (vlax-for o x
          (if
            (and
              (eq (vla-get-objectname o) "AcDbBlockReference")
              (eq (strcase (vla-get-effectivename o))
                  "SDS_FDS-TITLE_BLK"
              )
              (setq atts (vlax-invoke o 'GetAttributes))
            )
             (foreach e atts
               (if (eq (strcase (vla-get-tagstring e)) "DSCP")
                 (setq lst (cons (vla-get-textstring e) lst))
               )
             )
          )
        )
        (if lst
          (setq l (cons (list ly lst) l)
          )
        )
      )
    )
  )
  (if l
    (progn
      (foreach it l
        (print it)
      )
      (textscr)
    )
  )
  (princ)
)
(vl-load-com)