See the top rated post in this thread. Click here

Results 1 to 9 of 9

Thread: Duplicate points

Hybrid View

Previous Post Previous Post   Next Post Next Post
  1. #1
    Woo! Hoo! my 1st post
    Join Date
    2014-07
    Posts
    1
    Login to Give a bone
    0

    Default Duplicate points

    We copied points from one drawing to another...

    Now there are 2 points that occupied the same space. One can be moved and edited. The other one can be selected and list as a cogo point but it not editable...

    How do we get rid of the 2nd point and why did this happen? Usually are told there are duplicate point numbers and given option of Renumber, overwrite, etc...

    Thanks!

    Dave...

  2. #2
    Administrator rkmcswain's Avatar
    Join Date
    2004-09
    Location
    Earth
    Posts
    9,803
    Login to Give a bone
    0

    Default Re: Duplicate points

    Do they have different symbols in the prospector?

    ptlisting.png
    R.K. McSwain | CAD Panacea |

  3. #3
    Administrator BlackBox's Avatar
    Join Date
    2009-11
    Posts
    5,714
    Login to Give a bone
    0

    Default Re: Duplicate points

    Quote Originally Posted by david676884 View Post
    We copied points from one drawing to another...

    Now there are 2 points that occupied the same space. One can be moved and edited. The other one can be selected and list as a cogo point but it not editable...

    How do we get rid of the 2nd point and why did this happen? Usually are told there are duplicate point numbers and given option of Renumber, overwrite, etc...
    FWIW -

    COGO Points can have a different number and occupy the same coordinate.
    "How we think determines what we do, and what we do determines what we get."

    Sincpac C3D ~ Autodesk Exchange Apps

    Computer Specs:
    Dell Precision 3660, Core i9-12900K 5.2GHz, 64GB DDR5 RAM, PCIe 4.0 M.2 SSD (RAID 0), 16GB NVIDIA RTX A4000

  4. #4
    Certified AUGI Addict cadtag's Avatar
    Join Date
    2000-12
    Location
    Cairo - no, not Illinois
    Posts
    5,069
    Login to Give a bone
    0

    Default Re: Duplicate points

    Is there a quick way to identify duplicated points? Example:

    I've gotten a drawing in from surveyor, and in various locations he's got identical point symbols and locations for a sanitary cleanout stacked on top of each other. identical except for point number. other than hovering over every object in the drawing with selection cycling on..... is there a better way?

  5. #5
    Administrator rkmcswain's Avatar
    Join Date
    2004-09
    Location
    Earth
    Posts
    9,803
    Login to Give a bone
    1

    Default Re: Duplicate points

    @cadtag - Not sure in what all versions this is in, but I just tested it in C3D 2017.

    Toolspace > Toolbox > Miscellaneous Utilities > Point > Point Proximity Report

    That should do it.



    R.K. McSwain | CAD Panacea |

  6. #6
    Certified AUGI Addict cadtag's Avatar
    Join Date
    2000-12
    Location
    Cairo - no, not Illinois
    Posts
    5,069
    Login to Give a bone
    0

    Default Re: Duplicate points

    Thanks RK -- that gave me a 5 page printed report of apparent duplicates. The 'Zoom to selected point' doesn't do anything here unless there's a visible point symbol, but it if beats the heck out of guessing or scrolling though the point list looking for matching X and Y coordinates

  7. #7
    All AUGI, all the time
    Join Date
    2004-06
    Location
    Slidell, Louisiana
    Posts
    968
    Login to Give a bone
    0

    Default Re: Duplicate points

    check out this video for an alternative method. https://www.youtube.com/watch?v=E9MbWs6eoVI

    - - - Updated - - -

    Quote Originally Posted by rkmcswain View Post
    @cadtag - Not sure in what all versions this is in, but I just tested it in C3D 2017.

    Toolspace > Toolbox > Miscellaneous Utilities > Point > Point Proximity Report

    That should do it.



    it's in C3D 2016 if you have the civil 3d 2016 transportion extension.

  8. #8
    Administrator rkmcswain's Avatar
    Join Date
    2004-09
    Location
    Earth
    Posts
    9,803
    Login to Give a bone
    0

    Default Re: Duplicate points

    Quote Originally Posted by rmk View Post
    check out this video for an alternative method. https://www.youtube.com/watch?v=E9MbWs6eoVI
    Very nice methods by Jerry Bartels!

    Attempt to embed video here:

    R.K. McSwain | CAD Panacea |

  9. #9
    Administrator BlackBox's Avatar
    Join Date
    2009-11
    Posts
    5,714
    Login to Give a bone
    0

    Default Re: Duplicate points

    To save time, I just wrote this - It iterates the COGO Points in the active drawing, and adds any with same X,Y to a new dated Point Group allowing user to sort them out, without disrupting their original Point Group assignments (supports UNDO):

    Code:
    (vl-load-com)
    
    (defun c:FindDuplicateCogo (/ *error* vrsn acApp aeccApp aeccDoc 
                                aeccDb oPointGroups oPoints acDoc i n loc 
                                dup cogo name oPointGroup)
    
      (defun *error* (msg)
        (if aeccApp
          (vlax-release-object aeccApp)
        )
        (if acDoc (vla-endundomark acDoc))
        (cond ((not msg))                                                   ; Normal exit
              ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
              ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
        )
        (princ)
      )
    
      (if
        (and
          (setq vrsn
                 (if vlax-user-product-key                                  ; If 2013+
                   (vlax-user-product-key)                                  ; Use new function
                   (vlax-product-key)                                       ; Use legacy function
                 )
          )
          (setq vrsn
                 (cond
                   ((vl-string-search "22.0" vrsn) "12.0")                  ; 2018
                   ((vl-string-search "21.0" vrsn) "11.0")                  ; 2017
                   ((vl-string-search "20.1" vrsn) "10.5")                  ; 2016
                   ((vl-string-search "20.0" vrsn) "10.4")                  ; 2015
                   ((vl-string-search "19.1" vrsn) "10.3")                  ; 2014
                   ((vl-string-search "19.0" vrsn) "10.0")                  ; 2013
                   ((vl-string-search "18.2" vrsn) "9.0")                   ; 2012
                   ((vl-string-search "18.1" vrsn) "8.0")                   ; 2011
                   ((vl-string-search "18.0" vrsn) "7.0")                   ; 2010
                   ((vl-string-search "17.2" vrsn) "6.0")                   ; 2009
                   ((vl-string-search "17.1" vrsn) "5.0")                   ; 2008
                   (T nil)
                 )
          )
          (setq aeccApp (vla-getinterfaceobject
                          (setq acApp (vlax-get-acad-object))
                          (strcat "AeccXUiLand.AeccApplication." vrsn)
                        )
          )
          (setq aeccDoc (vlax-get-property aeccApp "ActiveDocument"))
          (setq aeccDb (vlax-get-property aeccDoc "Database"))
          (setq oPointGroups (vlax-get-property aeccDb "PointGroups"))
          (setq oPoints (vlax-get-property aeccDb "Points"))
          (princ "\nWorking, please wait... ")
          (princ)
        )
         (progn
           (vla-startundomark
             (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
           )
           (setq i (vlax-get oPoints 'count))
           (setq n 0)
           (vlax-for x oPoints
             (setq loc (vlax-get x 'location))
             (if (vl-position (setq loc (list (car loc) (cadr loc))) cogo) 
               (progn
                 (setq dup (cons (vlax-get x 'number) dup))
                 (setq n (1+ n))
               )
               (setq cogo (cons loc cogo))
             )
           )
    
           (if dup
             (progn
               (if
                 (vl-catch-all-error-p
                   (setq oPointGroup
                          (vl-catch-all-apply
                            'vla-add
                            (list oPointGroups
                                  (setq name
                                         (strcat
                                           (menucmd
                                             "M=$(edtime,$(getvar,date),YYYY-MO-DD)"
                                           )
                                           " Duplicate COGO Points"
                                         )
                                  )
                            )
                          )
                   )
                 )
                  (setq oPointGroup
                         (vl-catch-all-apply 'vla-item (list oPointGroups name))
                  )
               )          
                 
               (vlax-put (vlax-get oPointGroup 'querybuilder)
                         'includenumbers
                         (vl-string-right-trim
                           ","
                           (apply
                             'strcat
                             (mapcar
                               (function
                                 (lambda (x) (strcat (itoa x) ","))
                               )
                               dup
                             )
                           )
                         )
               )
               (prompt
                 (strcat
                   "\n"
                   (itoa n)
                   " of "
                   (itoa i)
                   " Duplicate COGO Point"
                   (if (= 1 i)
                     " was"
                     "s were"
                   )
                   " found, see Point Group: \n--> \""
                   name
                   "\"\n\n "
                 )
               )
             )
             (prompt "\n** No Duplicate COGO Points Found ** \n")
           )
         )
      )
    
      (*error* nil)
    )
    [Edit] - I don't use Survey DB, so let me know if there is an issue with that, so I can help.

    Cheers
    Last edited by BlackBox; 2018-02-12 at 05:33 PM.
    "How we think determines what we do, and what we do determines what we get."

    Sincpac C3D ~ Autodesk Exchange Apps

    Computer Specs:
    Dell Precision 3660, Core i9-12900K 5.2GHz, 64GB DDR5 RAM, PCIe 4.0 M.2 SSD (RAID 0), 16GB NVIDIA RTX A4000

Similar Threads

  1. 2014: Duplicate points
    By rmk in forum AutoCAD Civil 3D - Surfaces
    Replies: 11
    Last Post: 2014-12-10, 08:27 PM
  2. Duplicate centerline points on corridor
    By pkupec in forum AutoCAD Civil 3D - Corridors
    Replies: 2
    Last Post: 2008-06-12, 09:06 PM
  3. Remove duplicate points in polyline
    By GreyHippo in forum AutoLISP
    Replies: 1
    Last Post: 2007-03-24, 11:29 PM
  4. Duplicate points removing
    By bprabhakar001 in forum AutoLISP
    Replies: 2
    Last Post: 2005-12-19, 12:56 PM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •