Hatch closed polygon on a choosen layer

[mmontoya26684426]

Does anyone have or can write a LISP routine that will do the following:

1. With select the layer from the layer name I input.
2. Allow me the set the color for the solid pattern.
3. Hatch all the closed polygon on the layer I called to be hatched.

Any help would be greatly appreciated..... THANKS!!

[ReachAndre]

Crude but but here's an old one of mine slightly modified

(defun c:yay (/ ss1)  
  (setq ss1 (ssget '((0 . "LWPOLYLINE")(8 . "HATCH-BOUND"))))
  (if (/= ss1 nil)
    (progn
      
      (command "-hatch"
	       "la" "HATCH-PATT"
	       "P" "SOLID"
	       "S" ss1
	       "")
      ))  
  (princ))

[Tharwat]

Try this draft and change the layer names as you require with the color number as well .

(defun c:Test (/ layers color ss)
  ;; Tharwat 04.12.2014    ;;
  (setq layers "Layer1,Layer2,Layer3" ;; <= Layer names
        color  1      ;; <= Color number between 1 to 256 
  )
  (if (setq ss (ssget "_X"
                      (list '(0 . "LWPOLYLINE")
                            (cons 8 layers)
                            '(-4 . "&=")
                            '(70 . 1)
                      )
               )
      )
    ((lambda (i / sn h)
       (while (setq sn (ssname ss (setq i (1+ i))))
         (setq
           h (vla-addhatch
               (vlax-get
                 (vla-get-activelayout
                   (vla-get-ActiveDocument (vlax-get-acad-object))
                 )
                 'block
               )
               acHatchPatternTypePredefined
               "SOLID"
               :vlax-true
             )
         )
         (vlax-invoke
           h
           'AppendOuterLoop
           (list (vlax-ename->vla-object sn))
         )
         (vlax-invoke h 'Evaluate)
         (vla-put-color h color)
       )
     )
      -1
    )
  )
  (princ)
)(vl-load-com)

[BlackBox]

Try this draft and change the layer names as you require with the color number as well .

(defun c:Test (/ layers color ss)
  ;; Tharwat 04.12.2014    ;;
  (setq layers "Layer1,Layer2,Layer3" ;; <= Layer names
        color  1      ;; <= Color number between 1 to 256 
  )
  (if (setq ss (ssget "_X"
                      (list '(0 . "LWPOLYLINE")
                            (cons 8 layers)
                            '(-4 . "&=")
                            '(70 . 1)
                      )
               )
      )
    ((lambda (i / sn h)
       (while (setq sn (ssname ss (setq i (1+ i))))
         (setq
           h (vla-addhatch
               (vlax-get
                 (vla-get-activelayout
                   (vla-get-ActiveDocument (vlax-get-acad-object))
                 )
                 'block
               )
               acHatchPatternTypePredefined
               "SOLID"
               :vlax-true
             )
         )
         (vlax-invoke
           h
           'AppendOuterLoop
           (list (vlax-ename->vla-object sn))
         )
         (vlax-invoke h 'Evaluate)
         (vla-put-color h color)
       )
     )
      -1
    )
  )
  (princ)
)(vl-load-com)

FWIW -

If using Visual LISP Methods, you'd simplify (and speed up) your code to use vlax-For on the ActiveDocument's ActiveSelectionSet Property, in lieu of WHILE + SSNAME + vlax-Ename->vla-Object.

Also, you can store the ActiveLayout's Block once prior to iterating the Selection Set.

Cheers

[Tharwat]

FWIW -

If using Visual LISP Methods, you'd simplify (and speed up) your code to use vlax-For on the ActiveDocument's ActiveSelectionSet Property, in lieu of WHILE + SSNAME + vlax-Ename->vla-Object.

Also, you can store the ActiveLayout's Block once prior to iterating the Selection Set.

Cheers

Absolutely right and many thanks for the notes .
like.jpg