Summary Info Object Questions

[jason25]

First off, my apologies for bumping an old thread. This is the closest thread to giving me what I need. I know nothing about LISP and have been tasked with improving our CAD operator workflow and am in need of some assistance.

I have a block and there is an attribute which contains a value that I want to use as part of an expression in another mtext field. I started out using the script from Lee Mac and am having trouble understanding it.

Edit: I'm using AutoCAD 2014

backstop_pusher_value.jpg

[marko_ribar]

What is the name of block you're pointing with text bubble, what is the name of block containing STOP-LOCATION attribute : Left_Stop_Locat??? (red arrow is crossing its name), and please show us a picture where is stored width of the material you're speaking of (defined in a dwgprop)...

[jason25]

The box with the text bubble is currently not a block. It is just a text box where the programmer manually enters a calculated value, I'm hoping to make that automatic. The block containing STOP-LOCATION is named Left_Stop_Locator.

dwgprops.jpg

[peter]

Can you post the drawing?

Peter

[jason25]

Here is the dwt and an image. I found out that the block (Left_Stop_Locator) actually grabs it attribute tag from the value of the Left_Stop, circled in the image. If I can get the position of this block, I can then hopefully use it in an expression to push to the "Pusher" value.
left_stop.jpg

[peter]

Let's start with the dwg props (custom info object) to get the multiplier for the material.

OK I got a little carried away writing this...

P=

;___________________________________________________________________________________________________________ 
;
; CustomInfo Tools Written By; Peter Jamtgaard Copyright 2015
;___________________________________________________________________________________________________________ 
;
; Function List

; (CustomInfoToList)
; (CustomInfo strKey)
; (CustomInfoPut strKey strValue)
; (CustomInfoAdd strKey strValue)
; (CustomInfoRevove strKey)
; (Errortrap (quote symFunction))

;___________________________________________________________________________________________________________ 
;
; Function to read the summaryinfo information from the summaryinfo object.
; Returns a list of sublists 
; Each sublist includes summary key, index number and value for each key in a sublist.
; Syntax (CustomInfoToList)
; Returns (("PROGRAMMER" 0 "MIKE BOCKOVER") ("DRAWING #" 1 "#") ("REVISION" 2 "A") ) ;<- Abbreviated list
;___________________________________________________________________________________________________________

(defun CustomInfoToList (/
                         intCustomInfo
                         lstCustomInfoSublists ; List of Custom Information Pairs
                         objSummaryInfo
                         strPValue
                         strPKey
                        )
 (setq objSummaryInfo (SummaryInfoObject))
 (repeat (setq intCustomInfo (vla-NumCustomInfo objSummaryInfo))
  (setq intCustomInfo (1- intCustomInfo))
  (vla-GetCustomByIndex objSummaryInfo intCustomInfo 'strPKey 'strPValue)       
  (setq lstCustomInfoSublists (cons (list strPKey intCustomInfo strPValue) lstCustomInfoSublists))
 )
)



;___________________________________________________________________________________________________________

; After Notes: 
; The SummaryInfo is an object property of the acgivedocumemnt
; The NumCustomInfo is a method of the SummaryInfo object that specifies the number of keys
; The GetCustomByInfo is also a method of the SummaryInfo object that sets a key and its value.
; The CustomInfoSublists is a list of sublists 
;___________________________________________________________________________________________________________

;___________________________________________________________________________________________________________
;
; Functions to get summary info object
; Syntax: (SummaryInfoObject)
;___________________________________________________________________________________________________________

(defun SummaryInfoObject ()
 (vla-get-summaryinfo 
  (vla-get-activedocument 
   (vlax-get-acad-object)))
)

;___________________________________________________________________________________________________________
;
; Function to get summary info value by key.
; Syntax (CustomInfo "PROGRAMMER")
;___________________________________________________________________________________________________________

(defun CustomInfo (strKey)
 (if (errortrap (quote (vla-getcustombykey (SummaryInfoObject) (vl-princ-to-string strKey) 'strValue)))
  strValue
 )
)

;___________________________________________________________________________________________________________
;
; Function to put summary info value by key.
; Syntax (CustomInfoPut "PROGRAMMER" "FRED JONES")
;___________________________________________________________________________________________________________

(defun CustomInfoPut (strKey strValue)
 (or
  (errortrap (quote (vla-setcustombykey (SummaryInfoObject) 
                                        (vl-princ-to-string strKey) 
                                        (vl-princ-to-string strValue))))
  (CustomInfoAdd strKey strValue)
 )
) 

;___________________________________________________________________________________________________________
;
; Function to add a new summary info value with key and value
; Syntax (CustomInfoAdd "PROGRAMMER" "FRED JONES")
;___________________________________________________________________________________________________________

(defun CustomInfoAdd (strKey strValue)
 (errortrap (quote (vla-AddCustomInfo (SummaryInfoObject) 
                                      (vl-princ-to-string strKey) 
                                      (vl-princ-to-string strValue))))
)

;___________________________________________________________________________________________________________
;
; Function to add a new summary info value with key and value
; Syntax (CustomInfoRemove "PROGRAMMER")
;___________________________________________________________________________________________________________

(defun CustomInfoRemove (strKey)
 (errortrap (quote (vla-RemoveCustomByKey (SummaryInfoObject) 
                                          (vl-princ-to-string strKey))))
)

;___________________________________________________________________________________________________________
;
; Function to Trap LISP Errors
;___________________________________________________________________________________________________________

(defun ErrorTrap (symFunction / objError result)
 (if (vl-catch-all-error-p
      (setq objError (vl-catch-all-apply
                     '(lambda (X)(set X (eval symFunction)))
                      (list 'result))))
  nil
  (if result result 'T)
 )
)


(vl-load-com)

;___________________________________________________________________________________________________________

; After Notes:
; The SummaryInfo is an object property of the activedocumemnt
; The NumCustomInfo is a method of the SummaryInfo object that specifies the number of keys
; The GetCustomByInfo is also a method of the SummaryInfo object that sets a key and its value.
; The CustomInfoSublists is a list of sublists
;___________________________________________________________________________________________________________

See two new functions in code box

(CustomInfo "PROGRAMMER") returns the value from the PROGRAMMER custom info
(CustomInfoPut "PROGRAMMER" "FRED JONES") sets the value of the PROGRAMMER custom info to FRED JONES

[jason25]

excellent! I like "baby steps". I see that this portion of code pulls all the DWGPROPs. That is one value that I need to get. I really appreciate the help, I've spent the last few days looking at website after website trying to understand LISP. Would it be possible to add some programming notes so that I understand what is happening? I'd like to be helpful here someday too.

[peter]

See additional notes above.

Actually I write lisp with long variable names that are self descriptive.

I find that the code, with the descriptive variable names is almost self explanatory.

I use the reddick naming convention (with a few tweaks) so you always know what the variable holds obj for object etc...

The camel naming describes what is in the variable.

I like longer variable names instead of x or a, and then I have to find where it is defined to understand what it is and what value it holds.

My preference.


P=

[BlackBox]

Hi Peter,

Can you post the two SummaryInfo Overloads mentioned above?

Cheers

[peter]

My Bad,

They were typo's

Should be

CustomInfo
CustomInfoPut

They are in the attached file CustomInfoTools.lsp above