Find text, change layer

[demetrius.adams707933]

Hi All,

I'm new to lisps and the syntax is a little confusing to me so I'm having a little trouble. I have a text layer that contains around 500 text and mtext strings. I need to search for a string within the text and if it matches, change the layer. Here's an example of the logic:

find "HW"
change object layer to "HW-TXT"

find "WFI"
change object layer to "WFI-TXT"

find "CHWS"
change object layer to "CHWS-TXT"
ect...

If possible, it would be nice to be able to view the object before the layer is changed similar to how you can view all of the text when you use find and replace before replacing it but it's not absolutely necessary.

Thanks in advance

[peter]

(defun C:TextLayer ()
 (command "layer" "m" "HW-TXT" "m" "WFI-TXT" "m" "CHWS-TXT" "u" "*" "")
 (and
  (setq ssSelections (ssget "x" (list (cons 0 "*text"))))
  (setq	lstObjects   (SelectionSetToList ssSelections))
  (mapcar '(lambda (X)(changetextlayer X "*HW*"   "HW-TXT"  )) lstObjects)
  (mapcar '(lambda (X)(changetextlayer X "*WFI*"  "WFI-TXT" )) lstObjects)
  (mapcar '(lambda (X)(changetextlayer X "*CHWS*" "CHWS-TXT")) lstObjects)
 )
)

(defun ChangeTextlayer (objItem strWCMatch strLayer)
 (if (wcmatch (strcase (vla-get-textstring objItem)) (strcase strWCMatch))
  (vla-put-layer objItem strLayer)
 )
)

(defun SelectionSetToList (ssSelections / entSelection intCount lstObjects objSelection )
 (repeat (setq intCount (sslength ssSelections))
  (setq intCount (1- intCount))
  (setq entSelection (ssname ssSelections intCount))
  (setq objSelection (vlax-ename->vla-object entSelection))
  (setq lstObjects   (cons objSelection lstObjects))
 )
 (reverse lstObjects)
)

(vl-load-com)