Combining/running five different lisp routines at once

[Straka04]

I need your guys' help with a Lisp routine. I have been trying to find faster ways of completing operations.
Basically what I am trying to do is create a Lisp that actuates multiple Lisps, or combine one giant lisp, so that I am able to type in the command bar something like "SETUP" and the drawing I have open will be impacted by the operations below. It will help set up the jobs I have way faster. The operations I want to accomplish when using this Lisp are the following in order:

• Delete all paper space tabs
• Detach all xrefs (PDFs, DWGs, etc.)
• Delete all scales (under SCALELISTEDIT)
• Turn on and thaw all layers
• Purge all

If you have any tips, tricks or better ideas, please let me know.
Thanks in advance!!

[peter]

Here is the scalelist clear function.

P=

(defun ScaleListClear (/ objDictionary objXRecord)
 (if (setq objDictionary (vla-item (vla-get-dictionaries
                                    (vla-get-activedocument
                                     (vlax-get-acad-object)
                                    )
                                   )
                                   "ACAD_SCALELIST"
                         )
     )
  (vlax-for objXRecord objDictionary
   (vla-delete objXRecord)    
  )   
 )
)
(vl-load-com)

[peter]

Delete Layouts.

(defun LayoutsClear (/ colLayouts objLayout)
 (if (setq colLayouts (vla-get-layouts
                       (vla-get-activedocument
                        (vlax-get-acad-object))))

  (vlax-for objLayout colLayouts
   (if (/= (vla-get-name objLayout) "Model")
    (errortrap '(vla-delete objLayout))
   )  
  )   
 )
)

(defun ErrorTrap (symFunction / objError result)
 (if (vl-catch-all-error-p
      (setq objError (vl-catch-all-apply
                     '(lambda (X)(set X (eval symFunction)))
                      (list 'result))))
  nil
  (if result result 'T)
 )
)


(vl-load-com)

[peter]

Turn Layers On, Thaw and Unlock for good measure.

Syntax

(LayerOnThawUnlock "X1*")

for example will change all layers that match the "X1*" wildcard filter

(defun LayerOnThawUnlock (strWCLayerName / objLayer)
 (vlax-for objLayer (vla-get-layers
                     (vla-get-activedocument
                      (vlax-get-acad-object)
                     )
                    )
  (and
   (wcmatch (strcase (vla-get-name objLayer)) (strcase strWCLayerName))

   (ErrorTrap '(vla-put-lock    objLayer :vlax-false))

   (ErrorTrap '(vla-put-freeze  objLayer :vlax-false))

   (ErrorTrap '(vla-put-LayerOn objLayer :vlax-true))

  )
 )
)

(defun ErrorTrap (symFunction / objError result)
 (if (vl-catch-all-error-p
      (setq objError (vl-catch-all-apply
                     '(lambda (X)(set X (eval symFunction)))
                      (list 'result))))
  nil
  (if result result 'T)
 )
)

(vl-load-com)

[Straka04]

Wow thanks Peter!

Do you know how I could combine these lisps, so if I typed something like "SETUP", it would actuate those lisps?

[BIG-AL]

Just copy all the defuns then at the bottom put each defun in order within a c:defun

(defun c:setup ()
(ScaleListClear)
(LayoutsClear)
(LayerOnThawUnlock "X1*")
)

)