Dynamic User Input with Getstring List?

[stusic]

It seems I need to kind of "reset" the initget code each time it goes through the while loop, so I added this and it seems to work:

 (prompt "\nNothing Entered or Not 3 Characters")
	(initget 128 TypStr) ; in addition to the original one at the beginning
	  (setq str nil)

[BIG-AL]

Why not a dcl list to select from this one is from Alan J Thompson the calling code is
(if (not AT:listselect )(load "listselect"))
(AT:ListSelect title label height width multi lst)
the lst being just that your list to pick from, just check the answer returned for say "ADD" then add to lst and rerun again.

  ;; List Select Dialog (Temp DCL list box selection, based on provided list)
  ;; title - list box title
  ;; label - label for list box
  ;; height - height of box
  ;; width - width of box
  ;; multi - selection method ["true": multiple, "false": single]
  ;; lst - list of strings to place in list box
  ;; Alan J. Thompson, 09.23.08 / 05.17.10 (rewrite)
(defun AT:ListSelect (title label height width multi lst / fn fo d f)
  (setq fo (open (setq fn (vl-filename-mktemp "" "" ".dcl")) "w"))
  (foreach x (list (strcat "list_select : dialog { label = \"" title "\"; spacer;")
                   (strcat ": list_box { label = \"" label "\";" "key = \"lst\";")
                   (strcat "allow_accept = true; height = " (vl-princ-to-string height) ";")
                   (strcat "width = " (vl-princ-to-string width) ";")
                   (strcat "multiple_select = " multi "; } spacer; ok_cancel; }")
             )
    (write-line x fo)
  )
  (close fo)
  (new_dialog "list_select" (setq d (load_dialog fn)))
  (start_list "lst")
  (mapcar (function add_list) lst)
  (end_list)
  (setq item (set_tile "lst" "0"))
  (action_tile "lst" "(setq item $value)")
  (setq f (start_dialog))
  (unload_dialog d)
  (vl-file-delete fn)
  (if (= f 1)
    ((lambda (s / i s l)
       (while (setq i (vl-string-search " " s))
         (setq l (cons (nth (atoi (substr s 1 i)) lst) l))
         (setq s (substr s (+ 2 i)))
       )
       (reverse (cons (nth (atoi s) lst) l))
     )
      item
    )
  )
)

[truevis]

Easiest way is to use DOSLib -- dos_listbox
http://www.en.na.mcneel.com/doslib/index.html
Example:
dos_listbox.jpg

Command: (dos_listbox "Set Current Layer" "Select a layer" '("Layer1" "Layer2" "Layer3"))
"Layer1"

[Jim_Fisher]

That's a good suggestion truevis (DOSLib is a great tool ), but doesn't meet the requirement of allowing the user to add to the list ...

[truevis]

That's a good suggestion truevis (DOSLib is a great tool ), but doesn't meet the requirement of allowing the user to add to the list ...

Then I'd use dos_editlist

dos_combolist

or one of their other functions -- just so easy!

[stusic]

I ended up with this, which works very well. Thanks for the help everyone

  (defun _implode	(data delim / str n)
  ;; Join list items into string with delimiter string
  (if (and (= (type data) 'LIST)
	   (= (type delim) 'STR)
	   (> (strlen delim) 0)
      )
    (foreach n data
      (if str
	(setq str (strcat str delim n))
	(setq str n)
      )
    )
  )
)

  ; SET DEFAULT TYPE LIST
  (setq *TypLst (list
		 "PNL"
		 "CAB"
		 "DSK"
		 "CLT"
		 "TFS"
		 "STD"
		 "SGN"
		 "DOR"
		 "CLG"
		 "FAS"
		 "PST"
		 "SUP"
		 "MIS"
		 )
	)
  
  ; ADD ANY OTHERS TO THE OPTION LIST IF NOT ALREADY PRESENT
  (if (setq bss (ssget "x" (list '(0 . "INSERT") (cons 2 "@@@-#*,@@@-##*,@@@-###*"))))
    (progn
      (setq i 0)
      	(repeat (sslength bss)
	  (setq en (ssname bss i))
     	  (setq blocktype (substr (_EFName en) 1 3))
	    (if
    		(not (member blocktype *TypLst))
    		(setq *TypLst (cons blocktype *TypLst))
    		)
	  (setq i (+ i 1))
	  )
    )
  )

  ; SORT THE LIST
  (setq *TypLst (acad_strlsort *TypLst))

  ; BREAK THE LIST UP INTO A STRING WITH SPACES

(setq TypStr (_implode *TypLst " "))

  ; ON FIRST RUN, SET DEFAULT OPTION
  
(if (not *Typ) (setq *Typ (car *TypLst)))

  ; GET TYPE FROM USER

(initget 128 TypStr)
  
	(while
	    (and
	      (setq
		str1 (getkword
			       (strcat "\nChoose ["
				       (vl-string-translate " " "/" TypStr)
				       "] <"
				       *Typ
				       ">: "
			       )
			     )
	      )
		(/= str1 nil)
	        (/= (strlen str1) 3)
	    )
	  (prompt "\nNot 3 Characters")
	  (initget 128 TypStr)
	  (setq str1 nil)
	)
  
(if
  (eq str1 nil)
   (setq str1 (strcase *Typ))
   (setq *Typ (strcase str1))
)

  (princ *Typ)