Any wanna take a look on this?

[poa.neds697667]

HI all

I´m working this Lisp and to be honest I´m new to all this..

LISP:

(Defun c:SGM (/ s ss sn i) 
 (foreach lay (layoutlist)
    (setvar 'ctab lay)
  (if (setq s  (ssadd)
        ss (ssget "_x" '((0 . "ARC,LINE,LWPOLYLINE") (8 . "GRUPPEOMRÅDE")))
      )
    (progn
      (repeat (setq i (sslength ss))
    (setq sn (ssname ss (setq i (1- i))))
    (if (not (eq (cdr (assoc 100 (reverse (entget sn))))
             "AcDb3dPolyline"
         )
        )
      (ssadd sn s)
    )
      )
      (if (> (sslength s) 0)
    (command "_.pedit" "_m" s "" "w" 1.4 "")
      )
      (princ "\n .... ")
     )
       ); end foreach
    (princ "\n Couldn't find any 2D polyline !!")
  )
  (princ)
)

What it should do is: For each layout go to layer "Gruppeområde" select all lines, arcs ,polylines, 3d polylines and set width to 1.4.

Any that can see what i do wrong?
I get the error :"invalid window specification"

[Opie]

You are not accounting for the value of the PEDITACCEPT system variable. If it is set at 0 and you select items which are not polylines, the prompt to convert them is presented.

[Tom Beauford]

You can only set width to polylines, not lines or arcs. Are you doing that to Paper Space objects or Model Space objects in a viewport? You can change the lineweight of all lines, arcs, and polylines in a viewport using viewport overrides. If you modify the lineweight or width of an object then it would have that lineweight or width in every viewport.

[poa.neds697667]

You can only set width to polylines, not lines or arcs. Are you doing that to Paper Space objects or Model Space objects in a viewport? You can change the lineweight of all lines, arcs, and polylines in a viewport using viewport overrides. If you modify the lineweight or width of an object then it would have that lineweight or width in every viewport.

i forgot to tell that i have this lisp without the "foreach" and it works perfekt..
it ask if i wanna make the lines and arcs to poly lines.. i say yes and it do the rest by makeing all with 1.4 in line width.

all the lines in layer"GRUPPEOMRÅDE" is placed in paperspace.

Why i wanna have this lisp is because we need to see the lines like the printouts when we are placeing symbols in paperspace.

[rkmcswain]

Try this, per Opie's solution.

(Defun c:SGM (/ s ss sn i)
  (setvar "peditaccept" 1)
  (foreach lay (layoutlist)
    (setvar 'ctab lay)
    (if	(setq s	 (ssadd)
	      ss (ssget	"_x"
			'((0 . "ARC,LINE,LWPOLYLINE") (8 . "GRUPPEOMRÅDE"))
		 )
	)
      (progn
	(repeat	(setq i (sslength ss))
	  (setq sn (ssname ss (setq i (1- i))))
	  (if (not (eq (cdr (assoc 100 (reverse (entget sn))))
		       "AcDb3dPolyline"
		   )
	      )
	    (ssadd sn s)
	  )
	)
	(if (> (sslength s) 0)
	  (command "_.pedit" "_m" s "" "w" 1.4 "")	    
	)
	(princ "\n .... ")
      )
    )					; end foreach
    (princ "\n Couldn't find any 2D polyline !!")
  )
  (princ)
)

[poa.neds697667]

Try this, per Opie's solution.

(Defun c:SGM (/ s ss sn i)
  (setvar "peditaccept" 1)
  (foreach lay (layoutlist)
    (setvar 'ctab lay)
    (if	(setq s	 (ssadd)
	      ss (ssget	"_x"
			'((0 . "ARC,LINE,LWPOLYLINE") (8 . "GRUPPEOMRÅDE"))
		 )
	)
      (progn
	(repeat	(setq i (sslength ss))
	  (setq sn (ssname ss (setq i (1- i))))
	  (if (not (eq (cdr (assoc 100 (reverse (entget sn))))
		       "AcDb3dPolyline"
		   )
	      )
	    (ssadd sn s)
	  )
	)
	(if (> (sslength s) 0)
	  (command "_.pedit" "_m" s "" "w" 1.4 "")	    
	)
	(princ "\n .... ")
      )
    )					; end foreach
    (princ "\n Couldn't find any 2D polyline !!")
  )
  (princ)
)

Dosn´t work.

Stop at 2nd. layout and say invalid window specification.

This works find but as you see it dosn´t have the "FOREACH" that i want. we have up to 300 layers in each dwg that need this done

(Defun c:SGM (/ s ss sn i)
(if (setq s (ssadd)
ss (ssget "_x" '((0 . "ARC,LINE,LWPOLYLINE") (8 . "GRUPPEOMRÅDE")))
)
(progn
(repeat (setq i (sslength ss))
(setq sn (ssname ss (setq i (1- i))))
(if (not (eq (cdr (assoc 100 (reverse (entget sn))))
"AcDb3dPolyline"
)
)
(ssadd sn s)
)
)
(if (> (sslength s) 0)
(command "_.pedit" "_m" s "" "w" 1.4 "")
)
(princ "\n .... ")
(princ (strcat "Number of Polylines changed : "
" < "
(itoa (sslength s))
" > "
)
)
)
(princ "\n Couldn't find any 2D polyline !!")
)
(princ)
)

[rkmcswain]

Well, it does work, in certain situations, because it works just fine here on my sample drawing.

Can you post a sample drawing of yours?

[rkmcswain]

Give this a shot.

(Defun c:SGM (/ s ss sn i)
  (setvar "peditaccept" 1)
  (foreach lay (layoutlist)
    (setvar 'ctab lay)
    (setq s  (ssadd)
	  ss (ssget "_x"
		    (list
		      (cons 0 "ARC,LINE,LWPOLYLINE")
		      (cons 8 "GRUPPEOMRÅDE")
		      (cons 410
			    (if	(eq 1 (getvar 'CVPORT))
			      (getvar 'CTAB)
			      "Model"
			    )
		      )
		    )
	     )
    )
    (if	ss
      (progn
	(repeat	(setq i (sslength ss))
	  (setq sn (ssname ss (setq i (1- i))))
	  (if (not (eq (cdr (assoc 100 (reverse (entget sn))))
		       "AcDb3dPolyline"
		   )
	      )
	    (ssadd sn s)
	  )
	)
	(if (> (sslength s) 0)
	  (command "_.pedit" "_m" s "" "w" 1.4 "")
	)
	(princ "\n .... ")
      )
    )					; end foreach
    (princ "\n Couldn't find any 2D polyline !!")
  )
  (princ)
)

[poa.neds697667]

Works like a charm...

Great job thanks!