Wildcard Character * Not Allowing Renaming of Multiple Layers

[rbdome]

In the RENAME dialog, I am using the *wildcard character to rename multiple layers.
See Attached.
But No Layers are renamed.
What's the problem?

Thanks

[tedg]

In the RENAME dialog, I am using the *wildcard character to rename multiple layers.
See Attached.
But No Layers are renamed.
What's the problem?

Thanks

I don't think you can use (2) wildcards, I've tried it before too and couldn't make it work.
You many have to do it in pieces:

Rename:
"Lev2-~Anno*" to "Lev2-~An*"

"Lev5 Deluxe Suite-~Anno*" to "Lev5 Deluxe Suite-~An*"

And so on.
Realizing that you seem to only have a couple changes per type, not real efficient.

I agree it should work as you attempted, but it doesn't.
Unless someone else has better advice.

[Tom Beauford]

tedg's method is the best you could ever do using Rename.

cadtag's alternative http://forums.augi.com/showthread.ph...=1#post1289182

[BlackBox]

I've not downloaded the PDF (I prefer the contents included in the post, personally).

That said, I *think* this old LISP routine might be of use; It is case-sensitive (just like WCMATCH), and can effectively replace sub-strings in the middle of a given Layer name:

(vl-load-com)

(defun c:LAYREN () (c:LayerRename))
(defun c:LayerRename
       (/ *error* old new acDoc oLayers i oldName newName)

  (defun *error* (msg)
    (if acDoc
      (vla-endundomark acDoc)
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (if (and (setq old (getstring T "\nEnter string to replace: "))
           (setq new (getstring T "\nEnter replacement string: "))
      )
    (progn
      (vla-startundomark
        (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
      )
      (setq oLayers (vla-get-layers acDoc))
      (setq i 0)
      (vlax-for x oLayers
        (if (vl-string-search old (setq oldName (vla-get-name x)))
          (if
            (tblsearch "layer"
                       (setq newName (vl-string-subst new old oldName)) ; single replacement only
            )
             (prompt
               (strcat
                 "\nLayer \""
                 newName
                 "\" already exists. "
                 "Move all objects, then delete layer \""
                 oldName
                 "\" "
               )
             )
             (progn
               (vla-put-name x newName)
               (setq i (1+ i))
             )
          )
        )
      )
      (prompt
        (strcat "\n"
                (itoa i)
                " layer"
                (if (= 1 i)
                  " "
                  "s "
                )
                "renamed. "
        )
      )
    )
  )

  (*error* nil)
)

Quick example from Command Line:

Command:
Command: LAYREN
Enter string to replace: ANNO
Enter replacement string: AN
46 layer renamed.
Command:

Cheers

[david-k]

...That said, I *think* this old LISP routine might be of use; It is case-sensitive (just like WCMATCH), and can effectively replace sub-strings in the middle of a given Layer name...

Is this your code? I may want to keep it with me, as it may come in handy, and want to give proper credit .

[BlackBox]

Is this your code? I may want to keep it with me, as it may come in handy, and want to give proper credit .

It is, yes - no need for attribution, and feel free to take from it what you like.


Cheers

[david-k]

Cheers!