Need help fixing lisp routine that bumps up number in an attribute

[nlawler]

I found a lisp quite some time ago on here that add/subtracts to an attribute number within a drawing. However, it gives you an option to add/subtract a number between -5 and 5, I need it to not ask that and just add 1 to the existing number in the attribute without any prompts. I'm quite new to actually dissecting lisps as well but I'm trying to figure it out!

I have to add +1 to the revision number in 100+ drawings frequently and this would be super helpful. Below is the existing lisp, I think I can figure it out to how to make it batch open and save multiple drawings in a selected folder, but some input on that is also welcome, thanks!

Block Name: TAD15
Tag: REV

(defun c:RevPurge ( / ToSum SelSet Items Index BlkName AttName AttDxf )
  (initget 3 )
  (if (setq ToSum (getint "Enter an integer (example 5 or -5 ) to add or subtract : " ) )
    (progn
      (while (setq SelSet (ssget '((-4 . "<and" )(0 . "INSERT" )(2 . "TAD15" )(-4 . "and>" ))) )
        (setq Items (sslength SelSet ) )
        (setq Index -1 )
        (repeat Items
          (setq Index (1+ Index ) )
          (setq BlkName (ssname SelSet Index ) )
          (setq AttName (entnext BlkName ) )
          (while AttName
            (setq AttDxf (entget AttName ) )
            (if (=(cdr (assoc 2 AttDxf )) "REV"  )
              (progn
                (setq AttDxf (subst (cons 1 (itoa (+ (atoi (cdr (assoc 1 AttDxf ))) ToSum ))) (assoc 1 AttDxf ) AttDxf ) )
                (entmod AttDxf )
                (entupd BlkName )
              )
              ( )
            )
            (if (= (cdr (assoc 0 (entget AttName ))) "SEQEND" ) (setq AttName nil ) (setq AttName (entnext AttName )) )
          )
        )
      )
    )
    ( )
  )
  (princ)
)

[devitg.89838]

Try it

  (if
    ;(setq ToSum (getint "Enter an integer (example 5 or -5 ) to add or subtract : " ) )
    (setq ToSum 1)

the semi colon coment the line , or override

then it set tosum to be 1

As I dont have your DWG , I cant test.

[nlawler]

Thanks for your input! Unfortunately I cannot seem to get that to work, I'll attach a similar dwg with the block in which I'm asking.

ACAD-TITLEBLOCK.dwg

All I need is the code to establish the current number in the revision tag of the block, then add +1 to the value. Ideally I could then locate a folder and have it batch open, lisp command, then save all dwg files within the folder.

[devitg.89838]

I can not see the TAD15 block

no tad15 block.PNG

[nlawler]

Sorry,

the block name in the attached drawing has changed to "TITLEBLOCK", the tag is still "REV"

[devitg.89838]

Hi try it please

;; Arranged  by Gabo CALOS DE VIT from CORDOBA ARGENTINA
;;;    Copyleft 1995-2017 by Gabriel Calos De Vit 
;; DEVITG@GMAIL.COM    

;;*************************************************************************************************************************

;; it is not mine , 
(defun GetAllAttributes (objSelection /)
 (if (= (type objSelection) 'ename)
  (setq objSelection (vlax-ename->vla-object objSelection))
 )
 (if (vlax-property-available-p objSelection "hasattributes")  
  (if (= (vla-get-hasattributes objSelection) :vlax-true)  
   (vlax-safearray->list 
    (variant-value 
     (vla-getattributes objSelection)
    )
   ) 
  )
 )
)
;;************************************************************************************
;; some changes 
(DEFUN C:ATT-ADD-1  (/ ATT-LIST BLKNAME SELSET TAG-NAME TAG-VALUE TOSUM)
(vl-load-com)

  (SETQ TOSUM 1)
  (IF (SETQ SELSET (SSGET "_x" '((0 . "INSERT") (2 . "TITLEBLOCK"))))
    (PROGN
      (SETQ BLKNAME (SSNAME SELSET 0))
      (SETQ ATT-LIST (GETALLATTRIBUTES BLKNAME))
      (FOREACH ATT  ATT-LIST
        (IF (= "REV" (SETQ TAG-NAME (VLA-GET-TAGSTRING ATT)))
          (PROGN
            (SETQ TAG-VALUE (VLA-GET-TEXTSTRING ATT))
            (VLA-PUT-TEXTSTRING ATT (ITOA (+ TOSUM (ATOI (VLA-GET-TEXTSTRING ATT)))))
            ) ;progn
          ) ; if
        ) ; foreach
      ) ;progn
    ) ;if
  )
;; end C:ATT-ADD-1


;|«Visual LISP© Format Options»
(180 2 1 0 nil "end of " 100 20 2 2 nil nil T nil T)
;*** DO NOT add text below the comment! ***|;

[nlawler]

That works PERFECTLY! Thank you so much!

[devitg.89838]

Glad to know , you can change the TOSUM variable , the block name and the TAG NAME , to suit for other need

(SETQ TOSUM 1)

1

(2 . "TITLEBLOCK")

TITLEBLOCK

(= "REV" (SETQ TAG-NAME (VLA-GET-TAGSTRING ATT))

REV