Invoke the Colour Index to change a selected object's layer colour

[montyLalor]

Hi,

I have unsuccessfully searched the AutoLISP sub-forum for a routine to help deal with a few received dwg files generated in Archicad. At least I think it's Archicad. All the layers are white, with every object even having a colour override of 'white'. Pure pain.

My first point of call has been to use setbylayer (changing only colour properties) to rid myself of all object's colour overrides.

As the layer names in this non-Autodesk dwg file are insanely vague, I would like to be able to change all of the layer's colours to specific colours that will suit my .ctb file. I would like to simply select objects and have the routine invoke the Colour Index Table so I can choose a new colour for the selected object's layer.

I do not wish to create colour overrides of any object (it's a pet hate). I wish to only change a layer's colour by selecting an object first.

For example, if I pick on one of the gridlines, the lisp routine will have the Colour Index dialog box come up so I can manually change the gridline layer's colour to, say, 250. Then, by repeating the command and selecting a line that is an outline of a concrete column, I can change the coloumn's layer colour to, say, 100.

If a lisp routine like this exists, could you please direct me to where it has been posted..

Thank you.

Luke

[Tharwat]

Hi,

Something like this?

(defun c:test (/ sel lay int ent lst get)
  (if (and (setq int -1 sel (ssget "_:L" '((0 . "~VIEWPORT"))))
           (setq *clr* (acad_colordlg (if *clr* *clr* 1)))
      )
    (while (setq ent (ssname sel (setq int (1+ int))))
      (or (member (setq lay (cdr (assoc 8 (entget ent)))) lst)
          (progn
            (setq lst (cons lay lst))
            (entmod
              (subst
                (cons 62 *clr*)
                (assoc 62 (setq get (entget (tblobjname "LAYER" lay))))
                get
              )
            )
          )
      )
    )
  )
  (princ)
)