Need a Lisp

[Tharwat]

Hi,

Add your list of layer names as indicated in the following routine and let me know how this works:

(defun c:frz (/ sel ref pfx lay frz get)
  ;; Tharwat - date: 28.Jun.2018	;;
  (and (princ "\nPick on Xref to freeze layers :")
       (setq sel (ssget "_+.:S:E" '((0 . "INSERT"))))
       (or (/= ""
               (setq ref
                      (cdr
                        (assoc 1
                               (entget (tblobjname
                                         "BLOCK"
                                         (cdr (assoc 2 (entget (ssname sel 0))))
                                       )
                               )
                        )
                      )
               )
           )
           (alert "Pick object is not an Xref <!>")
       )
       (setq pfx (vl-filename-base ref))
       (foreach lst '("Layer1" "Layer2" "Layer3") ;; Add your list of layer names here.
         (and (tblsearch "LAYER" (setq lay (strcat pfx "|" lst)))
              (not (= 1
                      (logand 1
                              (setq frz
                                     (cdr
                                       (assoc 70
                                              (setq get (entget (tblobjname "LAYER" lay)))
                                       )
                                     )
                              )
                      )
                   )
              )
              (entmod (subst (cons 70 (+ frz 1)) (assoc 70 get) get))
         )
       )
  )
  (princ)
)

[cadd4la]

Tharwat,

Thanks once again for your help it works on the xref in the opened file but can it have an option to drill down and also freeze the layers with the same name that are in a file that is xref'd as an attachment in that xref file that I'm using the lisp program in?

Regards,

[Tharwat]

Tharwat,

Thanks once again for your help it works on the xref in the opened file but can it have an option to drill down and also freeze the layers with the same name that are in a file that is xref'd as an attachment in that xref file that I'm using the lisp program in?

Regards,

Sorry, I did not get your point that clearly.

[tedg]

If you want to freeze the same layer names for ALL present xrefs, why couldn't you use a wildcard in your layer names list, instead of picking an xref?

......
(command "-layer" "freeze" "*|layer1" "")

Just a thought,
Tharwat's code is WAY over my head to attempt to modify it

[cadd4la]

Sorry, I did not get your point that clearly.

Tharwat,

I have a file that has for an example a layer named xclip plus a few more and then another file that also has a layer named xclip plus a few more. Both files are in the output file that is plotted with one of the files being xref'd into the other as an attachment and then that file is then xref'd into the output file so both are in the output file. What I have done in the past is use the layer manager and go to each one of the xrefs and freeze the layers one at a time. The code you gave me will freeze the layers from the list but will not freeze the same layer names on a file that is xref'd into the master xref file.

Hope this helps you understand.

Thanks,

[Tharwat]

Just a thought,
Tharwat's code is WAY over my head to attempt to modify it

Please ask if you would like me to explain anything about the codes for you.

Tharwat,

I have a file that has for an example a layer named xclip plus a few more and then another file that also has a layer named xclip plus a few more. Both files are in the output file that is plotted with one of the files being xref'd into the other as an attachment and then that file is then xref'd into the output file so both are in the output file. What I have done in the past is use the layer manager and go to each one of the xrefs and freeze the layers one at a time. The code you gave me will freeze the layers from the list but will not freeze the same layer names on a file that is xref'd into the master xref file.

Hope this helps you understand.

Thanks,

Hi,

Something like this?

 (defun c:frz (/ nxt lay frz get)
  ;; Tharwat - Date: 29.Jun.2018	;;
  (while (setq nxt (tblnext "LAYER" (not nxt)))
    (and (vl-some '(lambda (chk)
                     (wcmatch (setq lay (cdr (assoc 2 nxt)))
                              (strcat "*" chk "*")
                     )
                   )
                  '("Layer1" "Layer2" "Layer3") ;; Add your list of layer names here.
         )
        (not (= 1
                      (logand 1
                              (setq frz
                                     (cdr
                                       (assoc 70
                                              (setq get (entget (tblobjname "LAYER" lay)))
                                       )
                                     )
                              )
                      )
                   )
              )
              (entmod (subst (cons 70 (1+ frz)) (assoc 70 get) get))
    )
  )
  (princ)
) (vl-load-com)

@MODERATORS, lately I don't receive emails when users reply to one of the threads that I ready contributed with to my inbox nor to spam folder.

[cadd4la]

Tharwat,

The code works great, thank you for all your hard work.

Cadd4la

[Tharwat]

Tharwat,

The code works great, thank you for all your hard work.

Cadd4la

Excellent. You are welcome anytime.