set distance by lisp in a dynamic block

[R0m3r014]

Hi.
Maybe someone here in this forum can help me.
I'm trying to set the distance for a dynamic block of a single parameter; which is linear and is called Distance1.
I do not know what I'm doing wrong, but I can not do it and change the desired distance.
He helped me with the functions of Lee Mac, but something is wrong. Any help very similar, I will be completely grateful.

(defun c: ddd (/ obj dd)     

(if (y (setq obj (car (entsel "\ ndynamic block:")              
(setq dd (getdist "\ Length:"))))              
(= "AcDbBlockReference" (vla- get-objectname (setq obj (vlax-esame-> vla-object obj))))              
(=: vlax-true (vla-get-isdynamicblock obj))         
)         

(LM: setdynpropvalue obj "Distance1" dd)     
)     

(princ) 

)


(defun LM: setdynpropvalue (blk prp val)     
(setq prp (strcase prp))     

(vl-some        '(lambda (x)             
(if (= prp (strcase (vla-get-propertyname x)))                 
(progn                     
(vla- put-value x (vlax-make-variant val (vlax-variant-type (vla-get-value x))))                     
(cond (val) (t))                 
)             
)         
)         
(vlax-invoke blk 'getdynamicblockproperties)     ) ) 
(vl-load-com) (princ)

[Tharwat]

Hi,

Try this function.

(defun set:distance (blk dis)
  (vl-some '(lambda (x)
              (and (eq "Distance1" (vla-get-propertyname x)) (vlax-put x 'Value dis))
            )
           (vlax-invoke (vlax-ename->vla-object blk) 'getdynamicBlockproperties)
           )
) (vl-load-com)

Usage of above function:

(set:distance <BlockEntityName> <DistanceValue>)

[sergpush36721006]

Both doesn't work.

[Tharwat]

Both doesn't work.

What do you mean by both?

[peter]

;___________________________________________________________________________________________________________|
;
; Written By: Peter Jamtgaard C.E., P.E., S.E. copyright 2018 All Rights Reserved
;___________________________________________________________________________________________________________|
;
; Any use by unauthorized person or business is strictly prohibited.
;___________________________________________________________________________________________________________|

;___________________________________________________________________________________________________________|
;
; General Function Header List
;___________________________________________________________________________________________________________|

;  Function List Argument1 Argument2 Arguement3

;* (DynamicBlockPropertyPut objSelection strWCProperty sngValue)
;* Function to change (put) dynamic block property values

;* (ErrorTrap symFunction)
;* Function to trap errors

;$ End Header

;___________________________________________________________________________________________________________|
;
; Function to change (put) dynamic block property values
;___________________________________________________________________________________________________________|

(defun DynamicBlockPropertyPut (objSelection strWCProperty sngValue / lstDynamicBlockProperties objDynamicBlockProperty)
 (if (and (= (type objSelection) 'vla-object)
          (vlax-property-available-p objSelection "isdynamicblock")
          (= (vla-get-isdynamicblock objSelection) :vlax-true)
          (setq lstDynamicBlockProperties (vlax-invoke objSelection "getdynamicblockproperties"))
     )
  (foreach objDynamicBlockProperty lstDynamicBlockProperties
   (if (wcmatch (strcase (vla-get-propertyname objDynamicBlockProperty)) (strcase strWCProperty))
    (errortrap '(vla-put-value objDynamicBlockProperty sngValue))
   )
  )
 )
)

;___________________________________________________________________________________________________________|
;
; Function to trap errors
;___________________________________________________________________________________________________________|

(defun ErrorTrap (symFunction / objError result)
 (if (vl-catch-all-error-p
      (setq objError (vl-catch-all-apply
                     '(lambda (X)(set X (eval symFunction)))
                      (list 'result))))
  nil
  (if result result 'T)
 )
)

(princ)

(DynamicBlockPropertyPut obj "Distance1" 180.0)

where obj was a valid vla-object

Worked for me...

Also I saw a lot of typos in LM's code... He is usually good about testing his stuff... Maybe it copied wrong...