Remove $0$ and everything before from Layer names

[cadd4la]

Hi everyone,

Does someone know how to write a lisp or know where I can find the code, that will remove $0$ and everything before that from the layer name in the layer manager.

From this - 532-IMP-BASE$0$area
to this - area

We are binding all the Civil, Architecture, & our base file to map a key map for the project.

Thanks,

Kyle C.

[Opie]

When you BIND the xref, have you tried the INSERT option? I believe this would resolve the problem, unless you have already done the binding.

[cadd4la]

Opie,

I did use the insert option when I binded the xref's, thats why I got the $0$.

but thanks for your input.

Kyle C.

When you BIND the xref, have you tried the INSERT option? I believe this would resolve the problem, unless you have already done the binding.

[kennet.sjoberg]

. . .I did use the insert option when I binded the xref's, thats why I got the $0$. . . .

Nope,

you can
bind as bind
and
bind as insert

: ) Happy computing !

kennet

[kennet.sjoberg]

. . . From this - 532-IMP-BASE$0$area
to this - area . . .

This is a sticky task,
if layer area do not exist, rename is easy to do,
if layer area exist, objects must move from .....$0$area to layer area.

: ) Happy Computing !

kennet

[cadd4la]

kennet,

No new layers exist other then the layers that we added in our base file, because all I am doing is doing a save as of our base and binding the xref's.

Kyle C.

This is a sticky task,
if layer area do not exist, rename is easy to do,
if layer area exist, objects must move from .....$0$area to layer area.

: ) Happy Computing !

kennet

[Opie]

kennet,

No new layers exist other then the layers that we added in our base file, because all I am doing is doing a save as of our base and binding the xref's.

Kyle C.

How many xrefs? If more than one xref contains the same layer names then the situation that kennet mentioned will occur.

[cadd4la]

Opie,

Now I have a problem, I don't think about that .

I have about 26 xref's and 13 of them are from the architect and I know they have the same named layers in all of them.

Any Ideas on how to get around this maybe when it reads the layer name it can add a "X" and a "number" that increases, I just looking to get the layer names to be smaller.

bko_451-xf-1a1$0$ABVBLW to X1ABVBLW

bko_451-xf-1b1$0$ABVBLW to X2ABVBLW
etc.

Thanks,

Kyle C.

How many xrefs? If more than one xref contains the same layer names then the situation that kennet mentioned will occur.

[kennet.sjoberg]

. . .Now I have a problem. . .

Yes you have,
if there is block in the binded xref ( and of course there is ) you have problem in problem.
and it is not only layers, it is textfons, linefonts, dimensionstyles. . . .

Next time bind as insert ; )

: ) Happy Computing !

kennet

[CAB2k]

Perhaps this will help.

;;;=======================[ LayerXrename.lsp ]======================= 
;;; Author:  Charles Alan Butler 
;;; Version:  1.0 jan. 10, 2006
;;; Purpose: Rename Bound xref layers  $0$ to X1-Layername
;;; Sub_Routines: -None 
;;;==============================================================
(defun c:layerxrename (/ usercmd lnamelst laylst x newname prefix prefixcnt tmp)
  (vl-load-com)
  (setq usercmd (getvar "CMDECHO"))
  (setvar "CMDECHO" 0)
  (setq laylst (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
  (vlax-for x laylst
    (setq lnamelst (cons (list (vla-get-name x) x) lnamelst))
  )

  (setq lnamelst (vl-sort lnamelst '(lambda (e1 e2) (< (car e1) (car e2)))))
  (setq prefix ""
        prefixcnt 0
  )
  (foreach x lnamelst
    (if (wcmatch (car x) "*$*$*") ; rename the layer
      (progn
        (if (/= (setq tmp (substr (car x) 1 (vl-string-search "$" (car x)))) prefix)
          (setq prefixcnt (1+ prefixcnt)
                prefix tmp)
        )
        (setq newname (strcat "X" (itoa prefixcnt)  "-"
                              (substr (car x) (+ 4 (vl-string-search "$0$" (car x))))
                      )
        )
        (vl-catch-all-apply 'vla-put-name (list (cadr x) newname))
      )
    )

  )
  (setvar "CMDECHO" usercmd)
  (princ)
)
(prompt "\nXref Layer Rename removes $0$, Enter LayerXrename to run.")
(princ)