Checking if something is nothing??

[BunyipCatcher]

G'day All,
Am having a crack at this VBA thing and have gone alright today. Iam trying to create a polyline
where the user can select as many points as they want and when they finish they type T to finish.

But I have two problems:

1. The way I have done it is to have a varible for the first point, the second point, and a variable to take all the other points picked by the user (varTendonPoint). But on my first go into my loop it wont have a value for use to draw a line from last point. I tried testing it to nothing but that doesnt seem to work...Is there a more elegant way?
2. If I type T at the command line it doesnt terminate the polyline it just says invalid option....I thought that if I typed T it would produce an error and I could get out....hmmm lost with using this error stuff in VBA any pointers. It seems pretty clunky.

Cheers for any help,
Scott

 
On error resume next
ThisDrawing.Utility.InitializeUserInput 128, "T t"
	Do Until Err.Number <> 0
		'If this is the first point after the second point then use the second point to draw the previous line from
		If varTendonPoint = Nothing Then
			varTendonPoint = ThisDrawing.Utility.GetPoint(varSecondTendonPoint, "Specify next tendon point or [<T>erminate tendon]:")
		'Otherwise use the last point that was picked to draw the previous line from
		Else
			varTendonPoint = ThisDrawing.Utility.GetPoint(varTendonPoint, "Specify next tendon point or [<T>erminate tendon]:")
		End If
		
		ReDim Preserve dblTendonPoints(UBound(dblTendonPoints) + 2)
		dblTendonPoints(UBound(dblTendonPoints) - 1) = varTendonPoint(0): dblTendonPoints(UBound(dblTendonPoints)) = varTendonPoint(1)
	Loop

[jwanstaett]

ThisDrawing.Utility.InitializeUserInput need to be call before each call to ThisDrawing.Utility.GetPoint it only good for on call to getpoint
and you can use a Collection to save you points in

you should use IsEmpty function

if IsEmpty(varTendonPoint ) then

NOT

If varTendonPoint = Nothing Then

here the code I would use

Dim x, y
Dim c As New Collection
'C IS A COLLECTION OF POINTS
On Error Resume Next
Do While True
x = x + 1
ThisDrawing.Utility.InitializeUserInput 128, "T t"
If x = 1 Then
y = ThisDrawing.Utility.GetPoint(, "Point  " & CStr(x))
Else
y = ThisDrawing.Utility.GetPoint(c(c.Count), "Point  " & CStr(x))
End If
If Err Then Exit Do
c.Add y
Loop

this code will next on any error of the in put data need to and code to check for keyword in put

[Jeff_M]

Here's a sample I posted for someone a while back that does basically what you want...except it is for 3dpoly's. Modify as needed for LW poly's.... mainly the Dim'ed object and LW plines only use x & y. By using this method it allows you to the pline as you draw, a la the pline command.

Sub testpoly()
Dim vpick As Variant
Dim dCoords() As Double
Dim I As Long
Dim oPoly As Acad3DPolyline

On Error Resume Next
vpick = ThisDrawing.Utility.GetPoint(, vbCr & "First point: ")
If Err = 0 Then
    ReDim dCoords(2)
    dCoords(I) = vpick(0): dCoords(I + 1) = vpick(1): dCoords(I + 2) = 
vpick(2)
    Do Until Err.Number <> 0
        I = I + 3
        vpick = ThisDrawing.Utility.GetPoint(vpick, vbCr & "..next point: ")
        ReDim Preserve dCoords(UBound(dCoords) + 3)
        dCoords(I) = vpick(0): dCoords(I + 1) = vpick(1): dCoords(I + 2) = 
vpick(2)
        If oPoly Is Nothing Then
            Set oPoly = ThisDrawing.ModelSpace.Add3DPoly(dCoords)
        Else
            oPoly.Coordinates = dCoords
        End If
    Loop
End If
End Sub