How to get length of line

[avinash00002002]

I have a somaby lines. I want to measure it individual and sum it and give me final length of conductor by selecting all the lines.


it gives me property like:

((-1 . <Entity name: 78ee2870>) (0 . "LWPOLYLINE") (330 . <Entity name:
7d888c10>) (5 . "2BF9E") (100 . "AcDbEntity") (67 . 0) (410 . "MODEL") (8 .
"GRID") (100 . "AcDbPolyline") (90 . 2) (70 . 0) (43 . 0.0) (38 . 0.0) (39 .
0.0) (10 455452.0 336457.0) (40 . 0.0) (41 . 0.0) (42 . 0.0) (10 455452.0
221507.0) (40 . 0.0) (41 . 0.0) (42 . 0.0) (210 0.0 0.0 1.0))

first point is: (10 455452.0 336457.0)
second point is: 10 455452.0 221507.0)

How can I call this different type of point bus assoc description is same (10)

or some thing else can be done.


Avinash Patil
Pixle park

[rkmcswain]

I have a somaby lines. I want to measure it individual and sum it and give me final length of conductor by selecting all the lines.


it gives me property like:

((-1 . <Entity name: 78ee2870>) (0 . "LWPOLYLINE") (330 . <Entity name:
7d888c10>) (5 . "2BF9E") (100 . "AcDbEntity") (67 . 0) (410 . "MODEL") (8 .
"GRID") (100 . "AcDbPolyline") (90 . 2) (70 . 0) (43 . 0.0) (38 . 0.0) (39 .
0.0) (10 455452.0 336457.0) (40 . 0.0) (41 . 0.0) (42 . 0.0) (10 455452.0
221507.0) (40 . 0.0) (41 . 0.0) (42 . 0.0) (210 0.0 0.0 1.0))

first point is: (10 455452.0 336457.0)
second point is: 10 455452.0 221507.0)

How can I call this different type of point bus assoc description is same (10)

or some thing else can be done.

That is an LWPOLYLINE entity, not a line. Look at DXF group code 0

Pass your entity to this function to retreive the length

(defun getlen (ent)
(vla-get-length (vlax-ename->vla-object ent))
)

[Opie]

Please note I have *moved* this thread from the VBA Forum to this one due to the AutoLisp property information listed and the AutoLisp solution provided.

Thanks,

Richard
Forum Moderator

[rkmcswain]

Sorry, I forgot. Here is a complete solution.

Load this, run GETLENS at the command prompt, length will be returned in an ALERT dialog.

(defun getlen (ent)
  (vla-get-length (vlax-ename->vla-object ent))
)
(defun c:getlens ()
  (setq sset (ssget "X" '((0 . "LWPOLYLINE"))) tot 0.0 i 0)
  (repeat (sslength sset)
	(setq tot (+ tot (getlen (ssname sset i))) i (1+ i))
  )
  (alert (strcat "Total Length = " (rtos tot)))
)

[CAB2k]

Use this to see length as you pick each.

;;  CAB  05/04/2005
;;  Total length print
(defun c:tlength (/ en len lentotal typ)
  (vl-load-com)
  (setq lentotal 0)
  (while (setq en (entsel "\nPick object for length."))
    (setq en (car en))
    (if (member (setq typ (cdr (assoc 0 (entget en))))
                '("LWPOLYLINE" "POLYLINE" "LINE" "SPLINE" "ARC")
        )
      (progn
        (setq len      (vlax-curve-getdistatparam en (vlax-curve-getendparam en))
              lentotal (+ len lentotal)
        )
        (prompt (strcat "\nLength of " typ " is " (rtos len)))
        (prompt (strcat "\n***  Running Total is " (rtos lentotal) "  ***"))
      )
      (prompt "\n***  Wrong type object, try again.")
    )
  )
  (if lentotal
    (prompt (strcat "\n***  Grand Total length is " (rtos lentotal) "  ***"))
  )
  (princ)
)
(prompt "\nLength Total loaded, Enter tlength to run")
(princ)

[Adesu]

I have a somaby lines. I want to measure it individual and sum it and give me final length of conductor by selecting all the lines.


it gives me property like:

((-1 . <Entity name: 78ee2870>) (0 . "LWPOLYLINE") (330 . <Entity name:
7d888c10>) (5 . "2BF9E") (100 . "AcDbEntity") (67 . 0) (410 . "MODEL") (8 .
"GRID") (100 . "AcDbPolyline") (90 . 2) (70 . 0) (43 . 0.0) (38 . 0.0) (39 .
0.0) (10 455452.0 336457.0) (40 . 0.0) (41 . 0.0) (42 . 0.0) (10 455452.0
221507.0) (40 . 0.0) (41 . 0.0) (42 . 0.0) (210 0.0 0.0 1.0))

first point is: (10 455452.0 336457.0)
second point is: 10 455452.0 221507.0)

How can I call this different type of point bus assoc description is same (10)

or some thing else can be done.


Avinash Patil
Pixle park

Hi Avinash Patil,
Here more simple

(setq ss (car (entsel "\nSelect a object")))
(setq tlen (vla-get-length (vlax-ename->vla-object ss)))

[rkmcswain]

Hi Avinash Patil,
Here more simple

(setq ss (car (entsel "\nSelect a object")))
(setq tlen (vla-get-length (vlax-ename->vla-object ss)))

...about the same as http://forums.augi.com/showthread.ph...729#post344729

[jwanstaett]

use this code to get the length of a line or any other curve entity

;Test the curve_length function
;enter test_curve_lingth at command line
(defun c:test_Curve_length()
(curve_length(car (entsel)))
 
)
;function curve_length(en)
;return length of the curve
; en is the entitiy name of a curve entity
;2dPolyline
;3dPolyline
;Arc
;Circle
;Ellipse
;Leader
;Line
;Polyline
;Ray
;Spline

(defun curve_length(en)
(vlax-curve-getDistAtParam en (vlax-curve-getEndParam en))
)

edit code 05/23/06 line function name type wrong

[kennet.sjoberg]

use this code to get the length of a line or any other curve entity. . .

Sorry, it will not work on a Ray, and you must convert "en" to "Vl-Obj"

: ) Happy Computing !

kennet

[kennet.sjoberg]

Try this :

(defun c:Length ( / Ent Vl-Obj ObjLen )
  (setq Ent (entsel) )
  (if (and Ent (member (cdr (assoc 0 (entget (car Ent )))) (list "LINE" "ARC" "CIRCLE" "LWPOLYLINE" "POLYLINE" "LEADER" "SPLINE" "ELLIPSE" )) )
    (progn
      (vl-load-com)
      (setq Vl-Obj (vlax-ename->vla-object (car Ent )) )
      (princ (strcat "\nCommand: " (cdr (assoc 0 (entget (car Ent )))) " length is : " (rtos (vlax-curve-getDistAtParam Vl-Obj (vlax-curve-getEndParam Vl-Obj )))) )
    )
    (if Ent (princ "Not a legal object. " ) (princ "..nothing Selected." ) )
  )
  (princ)
)

: ) Happy Computing !

kennet

PS. If you use any Code I post or Down Load Attachment I would like to say. . . Thank You, and enjoy.