My quick Saves - Any improvements, ideas?

[madcadder]

Any improvement ideas???

(DEFUN c:qs (/ |cmdecho|)
  (SETQ |cmdecho| (GETVAR "cmdecho"))
  (SETVAR "cmdecho" 0)
  (COMMAND "_qsave")
  (c:setmacro)
  (PRINC "\nQSave Complete:")
  (SETVAR "cmdecho" |cmdecho|)
  (PRINC)
) ;_ end of DEFUN

(DEFUN c:qsa (/ |cmdecho|)
  (SETQ |cmdecho| (GETVAR "cmdecho"))
  (SETVAR "cmdecho" 0)
  (COMMAND "_saveas" "" "~")
  (c:setmacro)
  (PRINC "\nSaveAs Complete:")
  (SETVAR "cmdecho" |cmdecho|)
  (PRINC)
) ;_ end of DEFUN

(DEFUN c:qsall (/ |cmdecho|)
  (VL-LOAD-COM)
  (VLA-RUNMACRO (VLAX-GET-ACAD-OBJECT) "WriteSnapshot")
  (VLAX-FOR doc	(VLA-GET-DOCUMENTS (VLAX-GET-ACAD-OBJECT))
	(IF	(AND
	  (= :VLAX-FALSE (VLA-GET-SAVED doc) (VLA-GET-READONLY doc))
	) ;_ end of AND
	  (PROGN (WRITE-LINE (STRCAT "\nSaving " (VLA-GET-NAME doc)))
		 (VLA-SAVE doc)
	  ) ;_ end of PROGN
	) ;_ end of IF
  ) ;_ end of VLAX-FOR
  (c:setmacro)
  (PRINC)
) ;_ end of DEFUN

(DEFUN c:qsc ()
  (IF (= (GETVAR "DWGTITLED") 1)
	(PROGN (COMMAND "qsave") (COMMAND "close"))
	(PROGN (INITDIA) (COMMAND "SAVE") (COMMAND "CLOSE"))
  ) ;_ end of IF
  (PRINC)
) ;_ end of DEFUN

(DEFUN c:qscopy	(/ |cmdecho|)
  (SETQ |cmdecho| (GETVAR "cmdecho"))
  (SETVAR "cmdecho" 0)
  (COMMAND "_qsave")
  (COMMAND "_save" "~")
  (c:setmacro)
  (PRINC "\nSaved and Saved Copy Complete:")
  (SETVAR "cmdecho" |cmdecho|)
  (PRINC)
) ;_ end of DEFUN

(DEFUN c:qse (/)
  (VL-LOAD-COM)
  (VLA-RUNMACRO (VLAX-GET-ACAD-OBJECT) "WriteSnapshot")
  (VLAX-FOR doc	(VLA-GET-DOCUMENTS (VLAX-GET-ACAD-OBJECT))
	(IF	(AND
	  (= :VLAX-FALSE (VLA-GET-SAVED doc) (VLA-GET-READONLY doc))
	) ;_ end of AND
	  (PROGN (WRITE-LINE (STRCAT "\nSaving " (VLA-GET-NAME doc)))
		 (VLA-SAVE doc)
	  ) ;_ end of PROGN
	) ;_ end of IF
  ) ;_ end of VLAX-FOR
;  (COMMAND "_quit")
  (PRINC)
) ;_ end of DEFUN

[Terry Cadd]

Your Qsave functions gave me some ideas for simplifying some of mine relating to Save, SaveAs, and Close.
In general I use the shortcut (Ctrl-S) for SaveAs or Qsave.
For Close I have a shortcut c:CX. It will only prompt to save the drawing if something has changed.
(defun c:CX ()(princ "\nCLOSE")(command "CLOSE")(princ))

I'm not sure what your function (c:setmacro) does. Can you include it so I can test it?

[madcadder]

I'm not sure what your function (c:setmacro) does. Can you include it so I can test it?

;;; SETMACRO function sets modemacro to show current "Last Saved Time", "Dimscale", "Osmode" value, "Textstyle",
;;; and "Group ON/OFF" on status line.

(DEFUN c:setmacro (/ |savetime|)
  (SETQ	|savetime|
	 (MENUCMD
;;;	   "M=$(edtime,$(getvar,date),DDD MO/DD/YYYY - H:MM:SS AM/PM)"
	   "M=$(edtime,$(getvar,date),H:MM:SS AM/PM)"
	 ) ;_ end of MENUCMD
  ) ;_ end of SETQ
  (SETVAR "modemacro"
	  (STRCAT
		"Last Saved: "
		|savetime|
		","
		" Cmdecho: $(if,$(and,$(getvar,cmdecho),1),ON,OFF),"
;;;		" Groups: $(if,$(and,$(getvar,pickstyle),1),ON,OFF),"
		" Psltscale: $(getvar,psltscale),"
		" Ltscale: $(getvar,ltscale),"
		" Dimscale: $(getvar,dimscale)"
;;;		 " Osnap: $(if,$(=,$(getvar,osmode),0),OFF,$(getvar,osmode)),"
;;;		" SpaceSwitch: $(if,$(=,$(getvar,spaceswitch),0),OFF,ON),"
;;;		" Textstyle: $(getvar,textstyle),"
;;;		" Pointstyle: $(getvar,pdmode)"
;;;		" ."
	   ) ;_ end of STRCAT
  ) ;_ end of SETVAR
  (PRINC)
) ;_ end of DEFUN

(c:setmacro)

[Terry Cadd]

I really liked what you did in (c:setmacro) with displaying information on the status line. Looks like it's easy to customize. I also liked your functions qs, qsa, qsc, and qscopy.

[madcadder]

Thank you. They're getting there.

Everything worked great in A2k2, but I'm ripping just about everything apart before I move it to A2k7.