Rounding up to the nearest 5

[ReachAndre]

Hey all,
I wrote a basic lisp so that I can calculate CFM. I woudl like this to round up to the nearest 5. Ex: 31.55 will equal 35. Hope this is descriptive enough. Though I am asking about ho wto do that, any help simplifying my code would be appreciated.
Thank you all in advance,
Andre

;Set CFM per Square Foot
(defun c:cfmsf ()
  (setq cfmpersqft (getreal "\enter CFM per sq ft number: "))
  (princ (strcat "CFM per sq ft set to " cfmpersqft " "))
  (princ))

;Placing CFM tag
(defun c:cfm (/ currlay sqft)
  (command "undo" "begin")
  (setq currlay (getvar "Clayer"))
  (setq sqft (getreal "\nenter room square foot: "))
  (setvar "clayer" "M-QUCO-CHCK")
  (command ".text" pause "9" 0 (strcat (rtos (* sqft cfmpersqft)) " CFM" ""))
  (setvar "clayer" currlay)
  (command "undo" "end")
  (princ))

[Tom Beauford]

Here's an old routine that works very well:

;;; Written by Doug Broad
;;; If value given 'to' argument is a real, a real is returned.

(defun round (value to)
  (setq to (abs to))
  (* to (fix (/ ((if (minusp value) - +) value (* to 0.5)) to)))
)

; examples:
; (round 12232e-015 1)
; 0
; (round 12232e-015 1.0)
; 0.0
; (round 123.6 1.0)
; 124.0
; (round -123.6 1.0)
; -124.0
; (round 6.00000000008 4)
; 8
; 6.00000000008  rounded to the nearest multiple of 4 is 8

[kennet.sjoberg]

. . . round up to the nearest 5. Ex: 31.55 will equal 35.. .

Like this ?

(defun 5up ( value / )
  (float (+ (* 5 (/ (fix value) 5 )) 5 ))
)

(5up 31.55 ) => 35.0
(5up 37.55 ) => 40.0
(5up 0.55 ) => 5.0
(5up 4.55 ) => 5.0
(5up 0 ) => 5.0 ?
(5up 30 ) => 35.0 ?

: ) Happy Computing !

kennet

[peter]

Kennet I noticed that 5up will turn 5.0 to 10.0

maybe

(defun RoundUp (sngValue)(* (fix (/ (+ sngValue 4.9999999999999999) 2)) 2.0))

Peter

[kennet.sjoberg]

Kennet I noticed that 5up will turn 5.0 to 10.0

. . Yes, I believe that that is still the mission. Or ?

: ) Happy Computing !

kennet

[Tom Beauford]

Hey all,
I wrote a basic lisp so that I can calculate CFM. I woudl like this to round up to the nearest 5. Ex: 31.55 will equal 35. Hope this is descriptive enough.

;roundup modifyed from round.
(defun roundup (value to)
(setq to (abs to))
(* to (fix (/ ((if (minusp value) - +) value (1+(* to 0.5))) to)))
)

; (roundup 31.55 5)
; 35
Which was the origional request.

If you want more decimal places...
; (roundup 31.55 5.0)
; 35.0
; (roundup 31.55 5.00)
; 35.00

[kennet.sjoberg]

; (roundup 31.55 5)
; 35
Which was the origional request.

Yes, but where ? is the breakpoint
; (roundup 30.99 5) = 30
; (roundup 30.01 5) = 30
; (roundup 31.01 5) = 30
; (roundup 31.55 5) = 35

I think OP have to clarify. . .otherwise my code always step up to next n*5

: ) Happy Computing !

kennet

[Tom Beauford]

Yes, but where ? is the breakpoint
; (roundup 30.99 5) = 30
; (roundup 30.01 5) = 30
; (roundup 31.01 5) = 30
; (roundup 31.55 5) = 35

I think OP have to clarify. . .otherwise my code always step up to next n*5

: ) Happy Computing !

kennet

One more try:

 (defun roundup (value to)
  (setq to (abs to)
		  try (+(* to (fix (/ ((if (minusp value) - +) value (* to 0.5)) to)))to)
  )
  (if(eq (+ 0.1 try) (+ 0.1 value to))(- try to) try)
)

Tested this one better, I went with 35=35 though.