Exploded Dimensions, bring them back to life

[Stephen.Walz]

I can't even begin to tell you how frustrating it is to come across a drawing with exploded dimensions. It is, by far, my biggest pet peeve about the CAD World...what are these people thinking?

Has anyone found a way to convert these objects back into dimensions?

[madcadder]

I don't have a way to put them back, but I can offer a easy way to identify the lil buggers.

;;;
;;;  FUDGE.LSP   Version 1.0
;;;
;;;  Copyright (C) 1996 by Jay Garnett
;;;
;;;  Permission to use, copy, modify, and distribute this software
;;;  for any purpose and without fee is hereby granted, provided
;;;  that the above copyright notice appears in all copies and
;;;  that both that copyright notice and the limited warranty 
;;;  below appear in all supporting documentation.
;;;
;;;  JAY GARNETT PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
;;;  JAY GARNETT SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
;;;  MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE. JAY GARNETT
;;;  DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
;;;  UNINTERRUPTED OR ERROR FREE.
;;;
;;;  DESCRIPTION
;;;  Finds any "fudged" dimensions and automatically changes them to a layer called FUDGED-DIMS.
;;;
;;;  By Jay Garnett
;;;  Bolingbrook, IL
;;;  
;;;  E-Mail jgarnett@enteract.com
;;;

(defun c:FUDGE(/ DIM-TXT E1 FUDGED IDX SS)
   (setq SS(ssget "x" '((0 . "DIMENSION")))
         IDX 0
   )
   (while (< IDX (sslength SS))
     (setq E1(entget( ssname ss IDX )))
     (setq DIM-TXT(cdr(assoc 1 E1)))
       (if (and(not(wcmatch DIM-TXT "*<>*"))(/= DIM-TXT ""))
         (if (not FUDGED)
           (setq FUDGED(ssadd (ssname SS IDX)))
           (setq FUDGED(ssadd (ssname SS IDX) FUDGED))
         )
       );end if
     (setq IDX (1+ IDX))
   );end while
   (if FUDGED
     (progn
       (if (not(tblsearch "layer" "FUDGED-DIMS"))
         (command ".layer" "M" "fudged-dims" "c" "magenta" "" "")
       );end if
       (command ".change" FUDGED "" "p" "la" "fudged-dims" "")
       (alert (strcat (itoa(sslength FUDGED)) " fudged dimensions changed \nto Layer FUDGED-DIMS"))
     );end progn
     (alert "No fudged dimensions found in this drawing")
   );endif
);end defun

[ccowgill]

I can't even begin to tell you how frustrating it is to come across a drawing with exploded dimensions. It is, by far, my biggest pet peeve about the CAD World...what are these people thinking?

Has anyone found a way to convert these objects back into dimensions?

I dont know how to convert them back either, but I do know how to prevent them from exploding them in the firstplace:

(command "undefine" "explode")
(defun c:explode ()
  ;;===============================================
  ;;		 L o c a l   F u n c t i o n s		 
  ;;===============================================
  ;; error function & Routine Exit
  (defun *error* (msg)
	(if
	  (not
 (member
   msg
   '("console break"
	 "Function cancelled"
	 "quit / exit abort"
	 ""
	);end list
 );end member
	  );end not
	   (princ (strcat "\nError: " msg))
	)	 ; endif
	(restore_sys_vars)   ; reset vars
  );end defun
  ;; Function to save system variables in global variable
  ;;  call to function
  ;;  (save_sys_vars '("CMDECHO" "FILEDIA"))
  (defun save_sys_vars (lst)
	(setq *sysvarlist* '())
	(repeat (length lst)
	  (setq *sysvarlist*
	  (append *sysvarlist*
	   (list (list (car lst) (getvar (car lst))))
	  );end append
	  );end setq
	  (setq lst (cdr lst))
	);end repeat
  );end defun
  ;; Function to reset system variables 
  (defun restore_sys_vars ()
	(repeat (length *sysvarlist*)
	  (setvar (caar *sysvarlist*) (cadar *sysvarlist*))
	  (setq *sysvarlist* (cdr *sysvarlist*))
	);end repeat
  );end defun
  (save_sys_vars '("CMDECHO" "qaflags"))
	 ;main program
  (setvar "cmdecho" 0)
  (setq ss (ssget '((-4 . "<NOT")
	  (-4 . "<OR")
	  (0 . "*DIMENSION,ACAD_TABLE")
	  (-4 . "OR>")
	  (-4 . "NOT>")
	 );end list
	);end ssget
  ); end setq
  (setvar "qaflags" 1)
  (command "_.explode" ss "")
  (setvar "qaflags" 2)
  (*error* "")	; reset sysvars
);end defun
	(princ)

it also prevents the exploding of an AutoCAD Table

[robert.1.hall72202]

Those are both good routines. I have to check all of my data for dimension overides, skewed lines, non parallel lines, non closed polylines, flat 2d objects, and exploded dimensions. Also throw in a spell check for good measure.

I can never be sure that the cad work is up to snuff.

[ccowgill]

the only problem with spell check, is in 2007, it doesnt work very well, I am still waiting for AutoDesk to fix it, it doesnt work very well with multiline text