lisp to draw multiple polylines

[stephen.coff]

Guys,
Can someone please assist me.
I want to use lisp to draw multiple polylines on a set layer and colour and line width ect.
I can make it do it for a polyline though how do I make it repeat without giving it a set number ?

below is the routine at present:

(defun c:APL (/ oldexpert oldfiledia oldclayer pln SJC)
  (setvar "cmdecho" 0)
  (setvar "orthomode" 1)
  (setq oldexpert  (getvar "expert")
	oldfiledia (getvar "filedia")
        oldclayer (getvar "clayer")
  )
 

;;loop to draw pline
(defun pln ()
  (command "plinewid" 100)  ;sets polyline width to 100
  (command "_pline")
  (while (= (getvar "cmdactive") 1 ) (command pause) )
  (command "plinewid" 0)  ;sets polyline width back to 0
) ;end defun


;;looks for SJC.lin linetype file and loads DASHED2 linetype file if found
  (setq SJC (findfile "SJC.lin"))  ;states the file to be looked for
  (if (= SJC (findfile "SJC.lin"))  ;looks for the file stated above
    (progn  ;says if the file is found do these things
      (setvar "expert" 3)
      (setvar "filedia" 0)
      (command "._-linetype" "l" "DASHED2" SJC "")
      (setvar "expert" oldexpert)
      (setvar "filedia" oldfiledia)
      (princ
	(strcat "\nlinetype DASHED2 in file SJC.lin was loaded.")  ;tells the user the file was found and loaded
      )
    )
    (princ (strcat "\nlinetype file SJC.lin was not found!"))  ;tells the user the file was not found or loaded
  )

;;set layer and draw polyline
  (command "-layer"   "m"	 "-M-AREA"  "C"	       "20"
	   "-M-AREA"  "Lt"	 "DASHED2"  "-M-AREA"  "p"
	   "n"	      "-M-AREA"	 ""
  )  ;creates new layer -M-AREA
  (pln)  ;runs polyline loop

  (setvar "clayer" oldclayer)
  (princ)  ;exit cleanly
)

[fixo]

Hi Stephen
You can use something like this

(defun C:TEST()
(alert "Use ESC to exit loop")
(command "plinewid" 100)
(while (not (vl-catch-all-error-p
                (vl-catch-all-apply
                    (function (lambda()
(progn                                  
(command "_pline")
(while (= (getvar "cmdactive") 1) (command pause)))))))))
(command "plinewid" 0)
(if (= (getvar "errno") 2)(princ "Interrupted by user"))  
)

[alaspher]

...something like this

...or like this (as variant):

(defun C:TEST1 (/ pt)
  (vl-cmdf "plinewid" 100)
  (while (setq pt (getpoint "\nPick first point or <Exit>"))
    (princ "\nDraw polyline")
    (vl-cmdf "_pline" pt)
    (while (= (getvar "cmdactive") 1) (vl-cmdf pause))
  )
  (vl-cmdf "plinewid" 0)
)

[stephen.coff]

Thank you both.
I will most likely use the later. Not that I am any good at Lisp, i atleast i have some idea what I am looking at ?

Stephen

[stephen.coff]

doooh,
What am I saying they are both in vlisp, I give up !

stephen

[stephen.coff]

Fixo,
That's great thank you very much. I like the whole idea of the esc to exit as I have a habbit of doing that.

Stephen

[stephen.coff]

Guys,
If I was to add this routine into another routine, what else could be used to stop the polyline function though allow the rest of the routine to then function ?

Stephen

[fixo]

Hi Stephen
In this case you need to use this as local
defun, e.g.

;;local defun to draw polylines multiply
(defun multipoly()
(alert "Use ESC to exit loop")
(command "plinewid" 100)
(while (not (vl-catch-all-error-p
                (vl-catch-all-apply
                    (function (lambda()
(progn                                  
(command "_pline")
(while (= (getvar "cmdactive") 1) (command pause)))))))))
(command "plinewid" 0)
(if (= (getvar "errno") 2)(princ "Interrupted by user"))  
);_eof
;;main part
(defunc C:main (/ )
<<your code goes here>>
(multipoly)
<<another code goes here>>
(princ)
);_ eof

[stephen.coff]

Thank you Fixo,
That works well.


Stephen