Results 1 to 4 of 4

Thread: layout tabs

  1. #1
    Member
    Join Date
    2004-03
    Location
    Jacksonville, FL
    Posts
    8
    0 Did you find this post helpful? Yes

    Question layout tabs

    Is there a shorthand command to switch between layout tabs for LD3 or Acad-2002;
    similar to the "ctrl page up-down" feature in 2004?
    -Joe Williams
    Jacksonville, FL

  2. #2
    AUGI Addict
    Join Date
    2001-10
    Location
    Arizona
    Posts
    2,337
    0 Did you find this post helpful? Yes

    Default Re: layout tabs

    Good question, I went and looked and found
    nothing helpful
    There is CTAB only you have to provide the tab name
    and LAYOUT>Set, same input format.
    Be your Best,


    Michael Farrell


    www.primeservicesglobal.com

  3. #3
    All AUGI, all the time
    Join Date
    2003-12
    Location
    Northern California
    Posts
    563
    0 Did you find this post helpful? Yes

    Default Re: layout tabs

    Quote Originally Posted by jwilliams.67235
    Is there a shorthand command to switch between layout tabs for LD3 or Acad-2002;
    similar to the "ctrl page up-down" feature in 2004?
    -Joe Williams
    Jacksonville, FL
    Here's a few little routines to do this. First, save these to a.mnl file name of your choosing (I tested this with "mymenu.mnl"). Then, in a matching name .mnu file (again, mine was mymenu.mnu) place these lines:
    Code:
    ***MENUGROUP=Mymenu //use the name of your file here
    
    ***ACCELERATORS
    [CONTROL + "LEFT"]^C^C(prev_tab)
    [CONTROL + "RIGHT"]^C^C(next_tab)
    This makes the CTRL + leftarrow go down in the tab order and CTRL + right arrow go up
    Code:
    (defun create_tab_list (/ layouts)
      (setq layouts (dictsearch (namedobjdict) "acad_layout"))
      (setq layouts (member (assoc 3 layouts) layouts)
    	*tab_list* nil)
      (while layouts
        (if (not (= (cdr (car layouts)) "Model"))
          (setq *tab_list* (cons (cons (cdr (assoc 71 (entget (cdr (car (cdr layouts)))))) (cdr (car layouts))) *tab_list*))
          )
        (setq layouts (cdr (cdr layouts)))
        )
      (setq *tab_list* (vl-sort *tab_list* '(lambda (x y)
    					 (< (car x) (car y))))
    	)
      )
    
    (defun next_tab (/ idx count)
      (create_tab_list)
      (setq count 0)
      (foreach x *tab_list*
        (if (= (cdr x) (getvar "ctab"))
          (setq idx count)
          )
        (setq count (1+ count))
        )
      (setq count idx)
      (if (= count (1- (length *tab_list*)))
        (setq count -1)
        )
      (setvar "ctab" (cdr (nth (1+ count) *tab_list*)))
      )
    
    (defun prev_tab (/ idx count)
      (create_tab_list)
      (setq count 0)
      (foreach x *tab_list*
        (if (= (cdr x) (getvar "ctab"))
          (setq idx count)
          )
        (setq count (1+ count))
        )
      (setq count idx)
      (if (= count 0)
        (setq count (length *tab_list*))
        )
      (setvar "ctab" (cdr (nth (1- count) *tab_list*)))
      )
    Enjoy!
    Jeff

  4. #4
    100 Club
    Join Date
    2004-12
    Posts
    153
    0 Did you find this post helpful? Yes

    Default Re: layout tabs

    what about something using ctl+ something??? Like being able to switch between drawings using ctl + tab?? I've seen that ctrl+r will do it, but it won't work for me...
    Last edited by tyeelaw13; 2006-09-13 at 08:04 PM.

Similar Threads

  1. Layout tabs names change when layout renamed in SSM
    By acadwishlist in forum AutoCAD Wish List
    Replies: 2
    Last Post: 2013-01-20, 04:07 AM
  2. Layout tabs
    By york in forum CAD Management - General
    Replies: 3
    Last Post: 2008-01-07, 11:43 AM
  3. How do others use Layout Tabs
    By mwilson in forum CAD Management - General
    Replies: 31
    Last Post: 2006-11-02, 06:12 PM
  4. Publish layout tabs and layout tab names to PDF
    By dfuehrer in forum AutoCAD Plotting
    Replies: 9
    Last Post: 2005-11-09, 01:49 PM
  5. layout tabs
    By jtravis.69666 in forum AutoCAD Customization
    Replies: 2
    Last Post: 2004-06-10, 09:22 PM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •