Updating Block Description Text

[Mr Turambar]

Hello,

I'm using the following program to extract block names and descriptions from a CSV file, and to insert the descriptions into the blocks:

(defun C:celldesc()
	(setq fname (getstring "Enter the filename of the report:"))
	(if (setq f(open fname "r"))
	  (while (setq fText(read-line f))
	    	(setq nameStart (+ 1 (vl-string-position (ascii ",") fText 0)))
	    	(setq descStart (+ 1 (vl-string-position (ascii ",") fText (+ 1 nameStart))))
	    	(setq bName (vl-string-trim ", " (substr fText nameStart (+ 1 (- descStart nameStart)))))
	    	(setq bDesc (vl-string-trim ", " (substr fText descStart (+ 1 (- (strlen ftext) descstart)))))
	    	(setq en (tblobjname "BLOCK" bName ))
	    	(setq ei (entget en))
		(entmod (append ei (list (cons 4 bDesc))))
	   )
	  (princ "\nFile Not Found")
	)
  (princ)
)

The program isn't updating the blocks. When I put a (princ) statement around the (entmod) call, the program would print 'null' repeatedly - once for each block.The program seems capable of getting block attributes, but it doesn't want to update description.

Any help would be appreciated.

Moderator Note:

How to use [ CODE ] tags...

[kpblc2000]

Try to use:

(defun c:celldesc (/           adoc        handle      *error*     file_name
                   str         blk_descr   block_name  block_descr block_def
                   )
  (defun *error* (msg)
    (vl-catch-all-apply '(lambda () (close handle)))
    (vla-endundomark adoc)
    (princ msg)
    (princ)
    ) ;_ end of defun

  (vla-startundomark
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    ) ;_ end of vla-startundomark
  (if (setq file_name (getfiled "Select a description file" "" "txt" 4))
    (progn
      (setq handle (open file_name "r"))
      (while (setq str (read-line file_name))
        (setq block_name  (1+ (vl-string-position (ascii ",") str 0))
              block_descr (1+ (vl-string-position (ascii ",") str (1+ block_name)))
              block_name  (vl-string-trim
                            ", "
                            (substr str block_name (+ 1 (- block_descr block_name)))
                            ) ;_ end of vl-string-trim
              block_descr (vl-string-trim
                            ", "
                            (substr str
                                    block_descr
                                    (+ 1 (- (strlen str) block_descr))
                                    ) ;_ end of substr
                            ) ;_ end of vl-string-trim
              ) ;_ end of setq
        (if (tblobjname "block" block_name)
          (progn
            (vl-catch-all-apply
              '(lambda ()
                 (vla-put-comments
                   (setq block_def (vla-item (vla-get-blocks adoc) block_name))
                   block_descr
                   ) ;_ end of vla-put-Comments
                 (vla-update block_def)
                 ) ;_ end of lambda
              ) ;_ end of vl-catch-all-apply
            ) ;_ end of progn
          ) ;_ end of if
        ) ;_ end of while
      ) ;_ end of progn
    ) ;_ end of if
  (vla-endundomark adoc)
  (princ)
  ) ;_ end of defun

[fixo]

Check this line, please:

 (vla-update block_def)

As I remember the Block object haven't "Update" method at all
Am I wrong?

~'J'~

[Mr Turambar]

Try to use:

(defun c:celldesc (/           adoc        handle      *error*     file_name
                   str         blk_descr   block_name  block_descr block_def
                   )
  (defun *error* (msg)
    (vl-catch-all-apply '(lambda () (close handle)))
    (vla-endundomark adoc)
    (princ msg)
    (princ)
    ) ;_ end of defun

  (vla-startundomark
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    ) ;_ end of vla-startundomark
  (if (setq file_name (getfiled "Select a description file" "" "txt" 4))
    (progn
      (setq handle (open file_name "r"))
      (while (setq str (read-line file_name))
        (setq block_name  (1+ (vl-string-position (ascii ",") str 0))
              block_descr (1+ (vl-string-position (ascii ",") str (1+ block_name)))
              block_name  (vl-string-trim
                            ", "
                            (substr str block_name (+ 1 (- block_descr block_name)))
                            ) ;_ end of vl-string-trim
              block_descr (vl-string-trim
                            ", "
                            (substr str
                                    block_descr
                                    (+ 1 (- (strlen str) block_descr))
                                    ) ;_ end of substr
                            ) ;_ end of vl-string-trim
              ) ;_ end of setq
        (if (tblobjname "block" block_name)
          (progn
            (vl-catch-all-apply
              '(lambda ()
                 (vla-put-comments
                   (setq block_def (vla-item (vla-get-blocks adoc) block_name))
                   block_descr
                   ) ;_ end of vla-put-Comments
                 (vla-update block_def)
                 ) ;_ end of lambda
              ) ;_ end of vl-catch-all-apply
            ) ;_ end of progn
          ) ;_ end of if
        ) ;_ end of while
      ) ;_ end of progn
    ) ;_ end of if
  (vla-endundomark adoc)
  (princ)
  ) ;_ end of defun

Thank you, this works perfectly, however:
(while (setq str (read-line file_name))
should read
(while (setq str (read-line handle))

because file_name is a string, not a FILE.

[kpblc2000]

Yes, that's right. Both of you are right. I'm terribly sorry for my mistakes