Unknown string

[stusic]

What does this mean:

  (setq SelSet (ssget "x" '((-4 . "<and" )(0 . "INSERT" )(2 . "MYBLOCK" )(-4 . "and>" ))) )

I'm trying to modify this to include more than one block (instead of "MYBLOCK"), but I'm not sure what the "-4 . ", "2 . ", and "0 . " represent. If I were to add more block names to this selection set, how/why/what would I change these beginning numbers to?

Thanks in advance,

-pUnkn

[stusic]

Okay, I see that these numbers are "Associative Codes" (thanks AfraLisp), so I can work from there, but is there a list of all these codes and what they do?

[.T.]

 (setq SelSet (ssget "x" '((-4 . "<and" )
	                     (0 . "INSERT" )
	                     (-4 . "<or")
	                          (2 . "MYBLOCK");change to suit
                                            (2 . "MYOTHERBLOCK");change to suit
	                     (-4 . "or>")
	                     (-4 . "and>")
                                    );end filter
                    );ssget
 );setq

Maybe this will help.

The numbers are dxf codes. 0 is for the entity type, 2, in this case is the block name, and -4 lets the interpreter know that you are useing a logical operator string. There is a list of dxf codes in the help file.

[CAB2k]

You must remember that AND is implied so this is all you need.

 (setq SelSet (ssget "x" '((0 . "INSERT" )(2 . "MYBLOCK,MYBLOCK2" ))))

[.T.]

You must remember that AND is implied so this is all you need.

 (setq SelSet (ssget "x" '((0 . "INSERT" )(2 . "MYBLOCK,MYBLOCK2" ))))

Yeah, we were going to get to that but... ~shrug~

Thanks, CAB

[stusic]

Thanks you guys!

Now that I've created my selection set, I need to extract the various attributes from them. I can't work on it right now, but I'll give it a shot tomorrow and update you all with my progress.

[stusic]

From what I've gathered from the help files in Vlisp, the way to extract attributes from a block is via:

RetVal = object.GetAttributes()

How do I add this to my code (below), and how do I define the selection set I've created and which attributes to extract?

If all the blocks listed aren't present, will that cause a problem? For that, should I add an "or" operator?

Btw, do I need this?:

(vl-load-com)

Routine so far:

(defun c:aavtest (/ SelSet )

 (vl-load-com)

 (setq SelSet (ssget "x" '((0 . "INSERT" )
               (2 . "BARREL_ANCHOR,SPRING_LOAD,LIVE_END,DEAD_END,EYEBOLT_ASSEMBLY,INT_ANGLE,TERM_ANGLE,TERM_TUBE,INT_POST" ))))



(princ)

)

Thanks for any advice!

[irneb]

From what I've gathered from the help files in Vlisp, the way to extract attributes from a block is via:

RetVal = object.GetAttributes()

Uhmmm ... no, that's how you do it in VBA.

How do I add this to my code (below), and how do I define the selection set I've created and which attributes to extract?

If you really want to use the ActiveX methods, then either do your method in VBA or use the VLisp ActiveX extension functions:

(setq n 0)
(vl-load-com)
(while (< n (sslength SelSet))
  (setq bname (ssname SelSet n))
  (setq bobj (vlax-ename->vla-object bname))
  (setq AttrCollection (vlax-invoke-method bobj 'GetAttributes))
  ;; Do whatever you do with the attributes, just remember to use the vlax methods
  (setq n (1+ n))
) ;_ end of while

Of course you'll have to look at the ActiveX methods as well as all those VLAX thingies for the Lisp interface thereto.

I'd rather suggest not using ActiveX mixed into Lisp if not needed. It's usually faster using the normal Lisp routines instead. The only time you should use the VLAX methods is if the normal Lisp stuff doesn't provide the needed functions.

(setq n 0)
(while (< n (sslength SelSet))
  (setq bname (ssname SelSet n))
  (setq battr (entnext bname))        ;Get the next entity after the nth block
  (while (and
       battr            ;Check if the entity is found
       (setq battrdata (entget battr)) ;Get its data
       (= "ATTRIB" (cdr (assoc 0 battrdata)))
                    ;Check if it's an attribute
     ) ;_ end of and
    ;; Do whatever you do with the current attribute, just remember to use the normal lisp methods
    ;; E.g. (cdr (assoc 1 battrdata)) gives the text value of the attribute
    ;;      (cdr (assoc 2 battrdata)) gives the attribute's tag name
    ;; Check the DXF code in the help file for other properties you can obtain this way
    (setq battr (entnext battr))    ;Get next entity after the attribute you've just found
  ) ;_ end of while

  (setq n (1+ n))
) ;_ end of while

If all the blocks listed aren't present, will that cause a problem? For that, should I add an "or" operator?

No, the commas in the name are analogous to OR. You could also use wildcard characters like * (asterisk) to match say BLK* to all of BLK1, BLK234, BLKwhatever, etc.

Btw, do I need this?: (vl-load-com)

Only if you're going to use ActiveX methods inside a Lisp function. This just ensures that the VLisp AxtiveX extension interface is loaded. Otherwise you might find "unknown function" errors.