Layout tab background color variable?

[ss_66ss396]

Is there a system variable for layout tab background color? I have a lisp that switches the show plot styles and lwt on and off, but I want to change the background from black to white as well. I've had trouble finding it.

thank,
Josh

[andrea.andreetti]

r u looking for the BACKGROUNDPLOT variable ?

or maybe this can help..

(setq AcadPreference (vlax-get-property (vlax-get-acad-object) 'preferences))
(setq AcadPreferenceDisplay (vlax-get-property AcadPreference 'display))
(vlax-put-property AcadPreferenceDisplay 'GraphicsWinmodelBackgrndColor 1244);; <- put your color here..
(vlax-release-object AcadPreference)
(vlax-release-object AcadPreferenceDisplay)

[rkmcswain]

Is there a system variable for layout tab background color? I have a lisp that switches the show plot styles and lwt on and off, but I want to change the background from black to white as well. I've had trouble finding it.

thank,
Josh

There is no system variable, but you can change it with lisp. Here is some code that will toggle the MS and PS background color from white to black, and back to white.

http://cadpanacea.com/node/50

[ss_66ss396]

That changed the background in the model space. Its the paper space background I want to change. I changed some of your code.

GraphicsWinmodelBackgrndColor 255);; <- put your color here..

GraphicsWinlayoutBackgrndColor 255);; <- put your color here..

This now changes the layout tab, but 255 itself is red. I can't seem to enter the 3 combination color or a white. Black is easy as it is 0. white is 255, 255, 255. When I enter that in, it says there are too many actual parameters.

Any ideas on how to get "white"?

thanks, I think we are almost there.

Josh

[ss_66ss396]

rkmswain-that works beautifully to change the background. now if I can just insert it into the lisp that I have or find what works for white. Here is what I have currently: (Forgive me I don't know how to get it into a code box.) Btw, this changes the show plot styles variable to show or not show, turns on and off the lineweight display, and hopefully will change the background.

(defun C:PST (    ; No arguments.
       /
       acadDocument  ; Holds reference to the active AutoCAD drawing object.
       acadLayout  ; Holds reference to the active Layout object.
       acadObject  ; Holds reference to the AutoCAD object.
       showPStyles  ; Holds current status of PlotStyle display on the active Layout.
      ) ;_ End arguments & local variables.
  (cond     ; Cond A
    ((= (getvar "TILEMODE") 1)  ; Model tab is active, abort command.
      (alert
 (strcat
   "C:PST is meant for use on a Layout tab, not on the Model tab."
   "\nPlease change to a Layout tab and try again."
 ) ;_ End strcat.
      ) ;_ End alert.
    ) ;_ End condition A1.
    (T     ; Condition A2.
     (vl-load-com)   ; Load "vl" functions, if not already loaded.
     (setq
       acadObject     (vlax-get-acad-object)
       acadDocument   (vlax-get-property acadObject 'ActiveDocument)
       acadLayout     (vlax-get-property acadDocument 'ActiveLayout)
       showPStyles    (vlax-get-property acadLayout 'ShowPlotStyles)
     ) ;_ End setq.
     (if (= showPStyles :vlax-true)
       (progn
  (vlax-put-property acadLayout 'ShowPlotStyles :vlax-false)
  (setvar "lwdisplay" 0)
(setq AcadPreference (vlax-get-property (vlax-get-acad-object) 'preferences))
(setq AcadPreferenceDisplay (vlax-get-property AcadPreference 'display))
(vlax-put-property AcadPreferenceDisplay 'GraphicsWinlayoutBackgrndColor 0);; <- put your color here..
(vlax-release-object AcadPreference)
(vlax-release-object AcadPreferenceDisplay)
  (prompt "\nThe display of plot styles has been turned off. ")
       ) ;_ End progn.
       (progn
  (vlax-put-property acadLayout 'ShowPlotStyles :vlax-true)
  (setvar "lwdisplay" 1)
(setq AcadPreference (vlax-get-property (vlax-get-acad-object) 'preferences))
(setq AcadPreferenceDisplay (vlax-get-property AcadPreference 'display))
(vlax-put-property AcadPreferenceDisplay 'GraphicsWinlayoutBackgrndColor 16777215);; <- put your color here..
(vlax-release-object AcadPreference)
(vlax-release-object AcadPreferenceDisplay)
  (prompt "\nThe display of plot styles has been turned on. ")
       );_ End progn.
     ) ;_ End if.
     (vlax-release-object acadLayout)
     (vlax-release-object acadDocument)
     (vlax-release-object acadObject)
     (command "_.REGENALL")  ; Regenerate the screen graphics.
    ) ;_ End condition A2.
  ) ;_ End cond A.
  (prin1)
) ;_ End C:PST.

Moderator Note:

Please use [ CODE ] tags...

[rkmcswain]

Black is easy as it is 0. white is 255, 255, 255. When I enter that in, it says there are too many actual parameters.

Any ideas on how to get "white"?

White is 16777215. This is not a RGB, but rather hex converted to decimal (FFFFFF=16777215)

[ss_66ss396]

It works! I copied it in from your earlier post, but I must not have loaded it correctly. I attached the lisp if anyone is interested in it. Thanks for all of your help in getting this working!

Josh

[rkmcswain]

(Forgive me I don't know how to get it into a code box.)

Just surround your code with these tags, like this:


[code]
(defun c:foo ()
(blah blah blah)
)
[/code]

[Ed Jobe]

If you don't want to type the code tags, click on the "Go Advanced" button and use the # buttton.

[rkmcswain]

If you don't want to type the code tags, click on the "Go Advanced" button and use the # buttton.

Unless you are using the "Basic Editor", then there are no buttons...