LISP to Explode Dynamic Blocks Doesn't Work

[Coloradomrg]

Attached is what I've (used loosely as I've essentially used LM's code and edited a piece of sample code from his website) come up with. It works exactly as expected, but I'd like to figure out how to simply cancel the burst command if no blocks are found. I tried adding it to the if statement, but that makes autocad return an error for too many arguments. I'm probably putting it in the wrong spot. I also decided to use visiblity states instead of multiple blocks, simplifying my search parameter.

(defun c:ComboBreak (/ blk)
  (setq flag (getvar "qaflags"))
  (setvar "qaflags" 1)
  (setq blk "recep_combo")
  (if (tblsearch "BLOCK" blk)
    (sssetfirst nil (GetBlockSelection blk))
    (princ (strcat "\n" blk " doesn't exist."))
  )
  (command "explode")
  (setvar "qaflags" flag)
  (princ)
)

(defun GetBlockSelection (name)
  (ssget "_X"
	 (list
	   '(0 . "INSERT")
	   (cons 2
		 (apply	'strcat
			(cons name
			      (mapcar
				(function (lambda (x) (strcat ",`" x)))
				(LM:GetAnonymousReferences name)
			      )
			)
		 )
	   )
	 )
  )
)


;;--------------=={ Get Anonymous References }==--------------;;
;;                                                            ;;
;;  Returns the names of all anonymous references of a block. ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  name - block name for which to return anon. references    ;;
;;------------------------------------------------------------;;
;;  Returns:  List of Anonymous Block names, else nil if none ;;
;;------------------------------------------------------------;;

(defun LM:GetAnonymousReferences (name / ano def lst rec ref)
  (setq name (strcase name))
  (while (setq def (tblnext "BLOCK" (null def)))
    (if
      (and
	(= 1 (logand 1 (cdr (assoc 70 def))))
	(setq rec
	       (entget
		 (cdr
		   (assoc 330
			  (entget
			    (tblobjname
			      "BLOCK"
			      (setq ano (cdr (assoc 2 def)))
			    )
			  )
		   )
		 )
	       )
	)
      )
       (while
	 (and
	   (not (member ano lst))
	   (setq ref (assoc 331 rec))
	 )
	  (if
	    (and
	      (entget (cdr ref))
	      (eq name (strcase (LM:EffectiveName (cdr ref))))
	    )
	     (setq lst (cons ano lst))
	  )
	  (setq rec (cdr (member (assoc 331 rec) rec)))
       )
    )
  )
  (reverse lst)
)

;;----------------=={ Effective Block Name }==----------------;;
;;                                                            ;;
;;  Returns the effective name of a block.                    ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  blockentity - Block Reference Entity name                 ;;
;;------------------------------------------------------------;;
;;  Returns:  True block name as per the block definition     ;;
;;------------------------------------------------------------;;

(defun LM:EffectiveName	(blockentity / name repbtag)
  (if (wcmatch (setq name (cdr (assoc 2 (entget blockentity))))
	       "`**"
      )
    (if
      (and
	(setq repbtag
	       (cdadr
		 (assoc	-3
			(entget
			  (cdr
			    (assoc 330
				   (entget (tblobjname "BLOCK" name))
			    )
			  )
			  '("AcDbBlockRepBTag")
			)
		 )
	       )
	)
	(setq repbtag (handent (cdr (assoc 1005 repbtag))))
      )
       (setq name (cdr (assoc 2 (entget repbtag))))
    )
  )
  name
)

[BlackBox]

Based on the 'combobursttest.dwg' posted previously....

This will EXPLODE all instances of your Dynamic Block ("RECEP_DATA_DEMO_COMBO"):

(vl-load-com)

(defun c:ComboBreak (/ *error* _GetDynamicBlocks acDoc blocks)

  (defun *error* (msg)
    (if acDoc
      (vla-endundomark acDoc)
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (defun _GetDynamicBlocks (doc match / oBlocks blockName blocks)
    ;; Example:
    ;; (_GetDynamicBlocks acDoc "*MyBlockName*")
    (if (and (setq oBlocks (vla-get-blocks doc))
             (setq match (strcase match))
        )
      (foreach space
               (list (vla-get-modelspace doc) (vla-get-paperspace doc))
        (vlax-for x space
          (if
            (and
              (= "AcDbBlockReference" (vla-get-objectname x))
              (wcmatch
                (strcase (setq blockName (vla-get-effectivename x))
                )
                match
              )
              (= :vlax-true
                 (vla-get-isdynamicblock
                   (vla-item oBlocks blockName)
                 )
              )
            )
             (setq blocks (cons x blocks))
          )
        )
      )
    )
    blocks
  )

  (if (setq blocks
             (_GetDynamicBlocks
               (setq acDoc (vla-get-activedocument (vlax-get-acad-object))
               )
               (strcase "RECEP_DATA_DEMO_COMBO")
             )
      )
    (progn
      (vla-startundomark acDoc)
      (foreach block blocks
        (vla-explode block)
        (vla-delete block)
      )
    )
  )
  (*error* nil)
)

This will first EXPLODE all instances of your Dynamic Block ("RECEP_DATA_DEMO_COMBO"), and then BURST the resultant Dynamic Blocks ("RECEPTACAL-WALL", "DATA"):

(vl-load-com)

(defun c:ExplodeThenBurst (/ *error* _GetDynamicBlocks acDoc blocks ss)

  (defun *error* (msg)
    (if acDoc
      (vla-endundomark acDoc)
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (defun _GetDynamicBlocks (doc match / oBlocks blockName blocks)
    ;; Example:
    ;; (_GetDynamicBlocks acDoc "*MyBlockName*")
    (if (and (setq oBlocks (vla-get-blocks doc))
             (setq match (strcase match))
        )
      (foreach space
               (list (vla-get-modelspace doc) (vla-get-paperspace doc))
        (vlax-for x space
          (if
            (and
              (= "AcDbBlockReference" (vla-get-objectname x))
              (wcmatch
                (strcase (setq blockName (vla-get-effectivename x))
                )
                match
              )
              (= :vlax-true
                 (vla-get-isdynamicblock
                   (vla-item oBlocks blockName)
                 )
              )
            )
             (setq blocks (cons x blocks))
          )
        )
      )
    )
    blocks
  )

  (if (setq blocks
             (_GetDynamicBlocks
               (setq acDoc (vla-get-activedocument (vlax-get-acad-object))
               )
               (strcase "RECEP_DATA_DEMO_COMBO")
             )
      )
    (progn
      (vla-startundomark acDoc)
      (setq ss (ssadd))
      (foreach block blocks
        (foreach obj (vlax-invoke block 'explode)
          (setq ss (ssadd (vlax-vla-object->ename obj) ss))
        )
        (vla-delete block)
      )
      (sssetfirst nil ss)
      (c:burst)
    )
  )
  (*error* nil)
)

** Code assumes that BURST Express Tool is loaded.

[Coloradomrg]

Thanks Blackbox!

The first code (the one I would use) is doing something weird... I get an exploded block, but the dynamic 'container' block is still in it's place (kind of like it's copying the selection set and then exploding just the copy). So I have 3 blocks instead of 2 for each instance, with one being the original 'container' block and the other two being receptacle-wall and data. If I run it again I have 5 objects, and so on... Not sure what could be causing that. Over my head for sure!

[BlackBox]

Thanks Blackbox!

You're welcome.

The first code (the one I would use) is doing something weird... I get an exploded block, but the dynamic 'container' block is still in it's place (kind of like it's copying the selection set and then exploding just the copy). So I have 3 blocks instead of 2 for each instance, with one being the original 'container' block and the other two being receptacle-wall and data. If I run it again I have 5 objects, and so on... Not sure what could be causing that. Over my head for sure!

Hrrrmm... I wrote that code from memory, so perhaps I overlooked a behavior of calling the Explode Method... I know it returns a list/variant of the resultant Objects from an Explode, but now I'm recalling the need to still Delete the originating Object which might explain the observed behavior you note.

I've revised the code above accordingly... Give those two routines another go, and let me know what you find.

Cheers

[Coloradomrg]

Awesome! Works perfectly Thanks again.

[BlackBox]

Awesome! Works perfectly Thanks again.

I couldn't ask for a better response... That is kind of you to say, and you're welcome; I'm happy to help.