Select blocks with no entities except attributes

[Borgster]

I have drawings that have blocks that consist of nothing but attributes. Apparently, in the past, someone would just change the attribute values to null instead of erasing the block. So, in some cases, I have several blocks in a drawing that are invisible in unpurgeable. Also, I don't already know the names of said blocks. I need to write a routine to erase these. That's simple enough, but I'm stumped on how to create a selection set of blocks that contain only attributes and those attributes are all null. Can anyone help?

[dgorsman]

Work through the BLOCK table (or Blocks collection). That will give you the defining elements of each block ie. whether it has anything other than attributes, and by extension the blocks you need to search for. From there you can call (ssget ...) or iterate through the various layout collections to pick them off.

FYI: don't forget to check inside other block definitions. These types of blocks get *everywhere* from inserting drawings into blank drawings, WBLOCKING, and other drawing "fixes". Wouldn't happen to be similar in name to AF, AO, AI, AF-FLOW, etc. would they?

[pbejse]

....I have several blocks in a drawing that are invisible in unpurgeable. .

I guess what you meant by invisible is "not seen" on drawing screen and not "invisible mode" attribute definition.

...but I'm stumped on how to create a selection set of blocks that contain only attributes and those attributes are all null.

So the condition is IF and ONLY IF the block is all Attribute and the inserted block is "invisible" [meaning attributes with null value]

Try this

(defun c:Aab (/ blocks ss bnlsy e att bn) ;<--- Attribute And Blank
  (setq	Blocks (vla-get-blocks
		 (vla-get-ActiveDocument (vlax-get-acad-object))
	       )
  )
  (if (setq bnlst nil
	    ss	  (ssget "_X" '((0 . "INSERT") (66 . 1)))
      )
    (repeat (setq i (sslength ss))
      (setq e	(vlax-ename->vla-object (ssname ss (setq i (1- i))))
	    att	(vlax-invoke e 'Getattributes)
      )
      (and (cond
	     ((member (setq bn (vla-get-effectivename e)) bnlst))
	     ((= (vla-get-count
		   (vla-item blocks
			     (setq bn (vla-get-effectivename e))
		   )
		 )
		 (length att)
	      )
	      (setq bnlst (Cons bn bnlst))
	     )
	   )
	   (vl-every '(lambda (a)
			(eq (vla-get-textstring a) "")
		      )
		     att
	   )
	   (vla-delete e)
      )
    )
  )
  (princ)
)
(vl-load-com)

FYI: don't forget to check inside other block definitions. These types of blocks get *everywhere* from inserting drawings into blank drawings,

I guess we can incorporate that option on the routine as well.

[Borgster]

Thank you pbjese. That works swimmingly!

[pbejse]

Thank you pbjese. That works swimmingly!

Great, Happy to help.