Attribute replacing

[Lee Mac]

Perhaps?

(defun c:bump ( / a g ) ;; Lee Mac 2011
  (cond
    ( (setq a (ssget "_+.:S:E:L" '((0 . "INSERT") (66 . 1))))
      (setq a (vlax-invoke (vlax-ename->vla-object (ssname a 0)) 'getattributes))
      (princ "\nPress [+/-] to Bump Attributes Up & Down. <Done>")
      (while (member (setq g (grread nil 10)) '((2 45) (2 95) (2 43) (2 61)))
        (mapcar 'vla-put-textstring a
          (mapcar 'vla-get-textstring
            (if (member g '((2 45) (2 95))) (cons (last a) a) (append (cdr a) (list (car a))))
          )
        )
      )
    )
  )
  (princ)
)
(vl-load-com) (princ)

Bump.gif

[pbejse]

[code]
(while (member (setq g (grread nil 10)) '((2 45) (2 95) (2 43) (2 61)))......

Brilliant

[Lee Mac]

Thanks pBe

[Tharwat]

Lee .

The routine stops at the princ function without a movement unless I cancel the process

Thanks.

[Lee Mac]

The routine stops at the princ function without a movement unless I cancel the process

Did you try to press '+' or '-' at the message? You can exit by pressing any key other than +/- or by clicking.

[Tharwat]

Did you try to press '+' or '-' at the message?

Of course I did and it is the place where it hangs.

You can exit by pressing any key other than +/- or by clicking.

It does not allow me unless I hit the Esc button from the Keyboard .

Could it be the cond function which cause this ?

[steveo]

Did you try to press '+' or '-' at the message? You can exit by pressing any key other than +/- or by clicking.

Sorry my friend, its not working for me either. + or - has no reaction.
Steve

[Lee Mac]

That's odd - everything worked well in my tests

Are you trying on blocks with more than 1 attrib?

[steveo]

Did you try to press '+' or '-' at the message? You can exit by pressing any key other than +/- or by clicking.

That's odd - everything worked well in my tests

Are you trying on blocks with more than 1 attrib?

No sir. a very simple block, circle with one attribute (number) inside.

[Lee Mac]

No sir. a very simple block, circle with one attribute (number) inside.

That explains the reason the code 'appears' to hang. The program is intended to shift the attribute values of multiple tags, hence when used on a block with one attribute, there would be no effect.