The named selection set exists error

[cgerhardt]

I used:

Set gssetObjs = ThisDrawing.SelectionSets.Add("MainSelSet")

to create my selection set.

Unfortunately my project had crashed after creating this selection set.

Therefore the selection set object, gssetObjs, no longer exists obviously, but the Named selection set still seems to be in memory. Without restarting AutoCAD, how can delete my "MainSelSet" selection set.

--------------------------

Upon searching the internet I found a solution:

On Error Resume Next
ThisDrawing.SelectionSets("MainSelSet").Delete

Set gssetObjs = ThisDrawing.SelectionSets.Add("MainSelSet")

[Ed Jobe]

You don't need to worry about deleting it, just reuse it. Try this function.

Public Function AddSelectionSet(SetName As String) As AcadSelectionSet
' This routine does the error trapping neccessary for when you want to create a
' selectin set. It takes the set and the proposed name and either adds it to the selectionsets
' collection or sets it.
    On Error Resume Next
    Set AddSelectionSet = ThisDrawing.SelectionSets.Add(SetName)
    If Err.Number <> 0 Then
        Set AddSelectionSet = ThisDrawing.SelectionSets.Item(SetName)
    End If
End Function

You can then clear the ss if you wish.

Dim ss As AcadSelectionSet
Set ss = AddSelectionSet("MySS")
ss.Clear

[MikeJarosz]

You do have your immedite window open, don't you? You can type:


ThisDrawing.SelectionSets("MainSelSet").Delete

In the immediate window. While developing a program, the immediate window is your best friend.

[namus75]

Without deleting the existing same selectionset and adding may lead to error sometimes

Try the following:

Sub MySelectionSet()
Dim ss As AcadSelectionSet
On Error Resume Next
Set ss = ThisDrawing.SelectionSets.Add("Suman")
If Err.Number <> 0 Then
ThisDrawing.SelectionSets.Item("Suman").Delete
Set ss = ThisDrawing.SelectionSets.Add("Suman")
End If
ss.SelectOnScreen

MsgBox "Number of entities in the Selectionset is" & vbCrLf & ss.Count
End Sub