Viewport layer states controled by LISP

[Kevin.Sturmer]

I have been having the Dickens of a time trying to piece meal together this routine to no avail.

For CAD2008, does anyone have an example of a LISP that would turn layers off/freeze them and turn on/thaw others only within a specific viewport without globally changing the layer states?

One use is to have radio buttons which would set the floor plan layers on in one VP, another to set the ceiling layers in another VP on the same sheet.

At present I can get it to globally toggle the layers... just can't get it down to only the VP level of control.

[Opie]

In your code, change your space to the desired viewport and adjust the vplayer there.

[Kevin.Sturmer]

Thanks for the fast reply.

I'm sure that is really straight forward... but I am not quite following. How do I identify the specific viewport(s)?

[Kevin.Sturmer]

I reread Opie's reply this morning after some fresh coffee... things are much more clear now. Thanks again.

[tedg]

I reread Opie's reply this morning after some fresh coffee... things are much more clear now. Thanks again.

Care to post an example of your final code for us lisp geeks to look at?

[CadDog]

Here is one I found...

It is a good start and some one add a few more things if they like:

(defun C:vpfreeze (/ myvp mylay)
  (vl-load-com)
  (setq myvp (car (entsel "\nSelect viewport: ")))
  (setq myvp (vlax-ename->vla-object myvp))
  (setq mylay (getstring "\nEnter layer name: "))
  (vpfreeze myvp mylay)
)

;; VPFREEZE
;; Freeze the layer in the viewport
;;
;; Arguments
;; vp : viewport (vla-object)
;; lay : layer name (string)

(defun vpfreeze	(vp lay / typ val)
  (vla-getXdata vp "ACAD" 'typ 'val)
  (setq	typ (reverse
	      (cons
		1002
		(cons 1002
		      (cons 1003 (cddr (reverse (vlax-safearray->list typ))))
		)
	      )
	    )
	val (reverse
	      (cons (vlax-make-variant "}")
		    (cons (vlax-make-variant "}")
			  (cons	(vlax-make-variant lay)
				(cddr (reverse (vlax-safearray->list val)))
			  )
		    )
	      )
	    )
  )
  (vla-setXData
    vp
    (vlax-safearray-fill
      (vlax-make-safearray
	vlax-vbInteger
	(cons 0 (1- (length typ)))
      )
      typ
    )
    (vlax-safearray-fill
      (vlax-make-safearray
	vlax-vbVariant
	(cons 0 (1- (length val)))
      )
      val
    )
  )
  ;; this is needed to display the change
  (vla-display vp :vlax-false)
  (vla-display vp :vlax-true)
)

[_gile]

Hi,

The code posted by CadDog can freeze a layer in PViewport by adding the layer to the viewport XDatas. But it seems to be impossible to thaw a layer in a PViewport using this way (removing from XDatas). So the only way using LISP seems to use the _VPLAYER command.
You can see this thread.

[CadDog]

Hi,

The code posted by CadDog can freeze a layer in PViewport by adding the layer to the viewport XDatas. But it seems to be impossible to thaw a layer in a PViewport using this way (removing from XDatas). So the only way using LISP seems to use the _VPLAYER command.
You can see this thread.

Thanks gile for that lead...

I even join and will be checking back from time to time there also...

[jsowinski]

Hi-
Here is a simple version of what I use in my office. All you need to do to update the routine is to add or delete the layer names from the list. (ex. "Layer1" = "A-ANNO-NOTE") Just keep the layer name in quotes. You can also use an asterisk as a wild card to look for xref layers or general groups of layers. The routine will freeze all layers in a view port and then thaw the layers you have listed in the selection set. You can select one or more view ports and the routine will cycle through all that you pick. Sorry I don't have any error code in there.

(defun c:vp-layers (/ sset num vprt laylist count)

(setq laylist '(
"0"
"Layer1"
"Layer2"
"Layer3"
  )
)

(if (> (getvar "cvport") 1)(command "pspace"))

(princ "\nSelect one or more view ports: ")

(setq sset(ssget '((0 . "viewport"))))

(setq num 0)
(repeat (sslength sset)
	(setq vprt(cdr(assoc 69 (entget(ssname sset num)))))

      (if (/= vprt 1)
	(progn
	  (command "mspace")
	  (command "cvport" vprt)
	  (command "vplayer" "f" "*" "c" "")

	  (setq count 0)
	  (foreach lay laylist
		  (setq count (1+ count))
		  (setq layers (append layers (list lay ",")))
	     (if (>= (strlen (apply 'strcat layers)) 2000)
	        (progn
		  (command "vplayer" "t" (apply 'strcat layers) "c" "")
		  (setq layers nil)
	        )
		     (if (= count (length laylist))
		        (progn
			  (command "vplayer" "t" (apply 'strcat layers) "c" "")
			  (setq layers nil)
		        )
		     )
	     )
	  );end foreach
	);end progn
      );end if
	(setq num (1+ num))
);end repeat

(command "pspace")
(command "zoom" "e" )

(princ)

);end defun

[agoretoy]

Guys, your routine is too elaborate,
Here is the simpliest way to freeze layer in a particular viewport. Works great with any AutoCAD version up to 2008.

This routine can be modified to do ANY other viewport layer state tasks if you know what uou need.
Just cut and paste to your notepad and save it to your LISP routines directory with .LSP extension (this info for rookies)
after APPLOAD, use VLF abbreviation to start routine.
Keep it simple - this will work allways!

;---------------------------------------------------------------------------------------
; To Freeze Layer of Picked Entity ONLY in current Viewport
;---------------------------------------------------------------------------------------
(defun c:vlf ()
  (prompt
     "\nPick entity on the layer you want freeze in this Viewport: ")
  (setq name (cdr (assoc 8 (entget (car (entsel))))))
  (command "_vplayer" "f" name "" "")
  (princ)
)

Moderator Note:

Please use [ CODE ] tags...