Converting All Fields To text

[mbrandt5]

Does anyone know of a command that converts all fields in a drawing to text?

[mbrandt5]

Nvm already found one

[Tom Beauford]

Nvm already found one

Please share a link to it.

[mbrandt5]

I have not tested the lisp yet but here is the link

http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/convert-field-to-text/td-p/1722015/page/2

[Tom Beauford]

I have not tested the lisp yet but here is the link

http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/convert-field-to-text/td-p/1722015/page/2

Try this modified from Convert Fields to Text in Paper Space by: Ian_Bryant:
;| Convert All Fields to Text in drawing modified from Convert Fields to Text in Paper Space by: Ian_Bryant
http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/convert-field-to-text/td-p/1722015 |;
(defun C:R-FIELDS-ALL ( / del-field ss1 index item)
(vl-load-com)
(defun del-field (ent / edic elist etype obj val)
(if
(and
(setq edic (cdr (assoc 360 (setq elist (entget ent)))))
(dictsearch edic "ACAD_FIELD")
)
(progn
(setq obj (vlax-ename->vla-object ent)
etype (cdr (assoc 0 elist))
)
(cond
((= etype "DIMENSION")
(setq val (vla-get-textoverride obj))
(dictremove edic "ACAD_FIELD")
(vla-put-textoverride obj val)
)
((= etype "MTEXT")
(setq val (vla-get-textstring obj))
(dictremove edic "ACAD_FIELD")
(vla-put-textstring obj val)
)
(T (dictremove edic "ACAD_FIELD"))
)
)
)
)
(if
(setq ss1
(ssget "X" '((0 . "TEXT,MTEXT,MULTILEADER,DIMENSION")))
)
(progn
(setq index 0)
(repeat (sslength ss1)
(setq item (ssname ss1 index))
(if (del-field item) (entupd item))
(setq index (+ 1 index))
)
)
)
(if
(setq ss1
(ssget "X" '((0 . "INSERT")))
)
(progn
(setq index 0)
(repeat (sslength ss1)
(setq item (ssname ss1 index))
(while (= (cdr (assoc 0 (entget (setq item (entnext item))))) "ATTRIB")
(if (del-field item) (entupd item))
)
(setq index (+ 1 index))
)
)
)
(princ)
)

another Convert Fields from selected objects to Text modified from Convert Fields to Text in Paper Space by: Ian_Bryant:
;| Convert Fields from selected objects to Text
modified from Convert Fields to Text in Paper Space by: Ian_Bryant
http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/convert-field-to-text/td-p/1722015 |;
(defun C:R-FIELDS ( / del-field ss1 index item)
(vl-load-com)
(defun del-field (ent / edic elist etype obj val)
(if
(and
(setq edic (cdr (assoc 360 (setq elist (entget ent)))))
(dictsearch edic "ACAD_FIELD")
)
(progn
(setq obj (vlax-ename->vla-object ent)
etype (cdr (assoc 0 elist))
)
(cond
((= etype "DIMENSION")
(setq val (vla-get-textoverride obj))
(dictremove edic "ACAD_FIELD")
(vla-put-textoverride obj val)
)
((= etype "MTEXT")
(setq val (vla-get-textstring obj))
(dictremove edic "ACAD_FIELD")
(vla-put-textstring obj val)
)
(T (dictremove edic "ACAD_FIELD"))
)
)
)
)
(if
(setq ss1
(ssget '((0 . "TEXT,MTEXT,MULTILEADER,DIMENSION,INSERT")))
)
(progn
(setq index 0)
(repeat (sslength ss1)
(setq item (ssname ss1 index))
(if(=(cdr(assoc 0(entget item))) "INSERT")
(while (= (cdr (assoc 0 (entget (setq item (entnext item))))) "ATTRIB")
(if (del-field item) (entupd item))
)
(if (del-field item) (entupd item))
)
(setq index (+ 1 index))
)
)
)
(princ)
)

[mbrandt5]

This does not work with a dynamic block bursted attribute with fields within it...The fields can still be converted to text after the burst occurs...

Though the code will not convert it to text only make it a value of nill any idea why this is occurring?

[mbrandt5]

Anybody please help...:?: