How to mark/tag any element without changing its properties.

Hi!

Is it possible to add some tag/mark to an element in the drawing?

For example: there is a set of lines on the same layer in the drawing . Some of them are very important. I want to permanently tag them, so that i could easily identify these elements (using autolisp) with other opening session of the drawing. I want this tag to be invisible in the model space (it could be visible in the 'properties' panel). I do not want to change any properties of the elements (layers, lineweights etc.). I do not want to add any new elements to the drawing (notes, attributes etc.). I mean some kind of an attribute connected to element but without creating a block.

Adding some suffix to handle value could be perfect, but I think changing the handle value is impossible. Am I right?

Thank you for Your help in advance.

If you have Map or one of it's verticals you can. Otherwise you could group them or reference them in a field.

How about XDATA ?

Quote:

---

Originally Posted by marko_ribar

How about XDATA ?

---

Thank You! That's what I was looking for!

Quote:

---

Originally Posted by sanch3z

Thank You! That's what I was looking for!

---

Yes Xdata can be a good way, for exemple

Affect your application to object

Code:

---

((lambda ( / app_name js n ent dxf_ent x_data)
        (setq app_name "PERSONAL_ENTITIES")
        (regapp app_name)
        (princ "\nSelect objects")
        (setq js (ssget))
        (cond
                (js
                        (repeat (setq n (sslength js))
                                (setq ent (ssname js (setq n (1- n))) dxf_ent (entget ent))
                                (setq x_data (list -3 (list app_name (cons 1005 (cdr (assoc 5 dxf_ent))))))
                                (entmod (append dxf_ent (list x_data)))
                        )
                )
        )
))

---

Select only your entities and grip them

Code:

---

((lambda ( / app_name js)
        (setq app_name "PERSONAL_ENTITIES")
        (setq js (ssget "_X" (list (list -3 (list app_name)))))
        (sssetfirst nil js)
))

---

Remove your entities of one selection gripped or previous

Code:

---

((lambda ( / js js_app n ent)
        (setq app_name "PERSONAL_ENTITIES")
        (or (setq js (ssget "_I")) (setq js (ssget "_P")))
        (setq js_app (ssget "_X" (list (list -3 (list app_name)))))
        (cond
                ((and js js_app)
                        (repeat (setq n (sslength js_app))
                                (setq ent (ssname js_app (setq n (1- n))))
                                (ssdel ent js)
                        )
                        (sssetfirst nil nil)
                )
        )
        (sssetfirst nil js)
))

---